07 判断不同分支发布到不同的环境

根据不同的分支发布到不同的环境,整个Jenkinsfile实际也就涉及两个部分:

1. 判断分支,拉取不同分支代码
2. 执行不同的deploy部署步骤

判断分支如果是手动触发可以选择传递变量方式,即手动点击后选择要发布到那个环境.如果是自动的话,就得根据变量来自动判断了.

找了下Jenkins内置变量文档并没发现相关的内置变量,文档:使用Jenkins
想起配置触发器的时候过滤过gitlab提交内容,尝试了下pipeline中可以获取到,所以就用触发器的变量,也就是此处ref的值.

顺便修改了下取值方式和判断内容以及Jenkins.groovy文件,修改后内容如下:

ref取值改为:

project_name取值方式不变,过滤规则改为同时匹配main和test两个分支:

新建test分支提交代码测试触发.

这里不需要担心test分支没有Jenkins.groovy文件会执行失败,因为配置中指定了从main分支拉取Jenkinsfile而不是触发的当前分支.

Jenkins.groovy文件内容:

// 直接在文件中定义的 作用域为全局
def GITLAB_SSH_URL = "ssh://[email protected]:222/my_group/one_project.git"
def BUILD_IMAGE = "528909316/jenkins"

podTemplate(
  cloud: 'kubernetes',
  containers: [
    containerTemplate(name: 'build', image: "${BUILD_IMAGE}:pyinstaller_v1", command: "sleep 99d", ttyEnabled: true),
    containerTemplate(name: 'docker', image: "${BUILD_IMAGE}:rundocker_v1", command: "sleep 99d", ttyEnabled: true)],
  volumes: [hostPathVolume(hostPath: '/var/run/docker.sock', mountPath: '/var/run/docker.sock')]
) {
  // 当前函数下的每个stage中都可调用此函数
  def GITLAB_ID = "d17b1091-fa2d-4310-8a4d-0b1d7f823ea9"
  node(POD_LABEL) {
    // 新增了一个构建执行前的步骤
    stage('Before build execution'){
      // 更新gitlab状态为 running
      updateGitlabCommitStatus name: 'jenkins', state: 'running'
      // 打印一下取到的参数
      echo "${ref}"
      // 判断"${ref}"的值是否是 "refs/heads/main" 如果是则执行括号内内容 否则继续向下执行
      if ("${ref}" == "refs/heads/main") {
        echo "main branch update the code !"
      // 判断变量"${ref}"的内容是否是 "refs/heads/test" 如果是则执行括号内内容 否则继续向下
      } else if ("${ref}" == "refs/heads/test") {
        echo "test branch update the code !"
      // 如果经过上面的所有匹配都没有成功的 那么则执行此处的代码
      } else {
        echo "don't know which branch update the code ...."
      }
    }
    stage('pull code') {
      // 克隆代码 使用变量 GITLAB_ID
      git branch: 'main', credentialsId: "${GITLAB_ID}", url: "${GITLAB_SSH_URL}"
      echo "The first stage end"
    }
    stage('build code') {
      container('build') {
        stage('Build a python project') {
          // 编译为文件
          sh '''
          python -m pip install --upgrade pip -i https://pypi.tuna.tsinghua.edu.cn/simple
          pip install -i https://pypi.tuna.tsinghua.edu.cn/simple flask
          pyinstaller -F cpu.py
          '''
        }
      }
      echo "The second stage end."
    }
    stage("build image") {
      // 某个stage中定义的 作用域当前函数中,只能在当前stage中或者其子stage中调用
      def dockerImage = '528909316/jenkins:taskcpu_v1'
      container("docker") {
        stage("build image") {
          // 某个stage中定义的 作用域当前函数中,只能在当前stage中或者其子stage中调用
          def DOCKER_PASSWORD = "*******"
          sh "docker build -t ${dockerImage} ."
          sh "docker login -u 528909316 -p \'${DOCKER_PASSWORD}\'"
          sh "docker push ${dockerImage}"
        }
      }
      echo "push ${dockerImage} end."
    }
    stage("deploy image") {
      kubernetesDeploy configs: 'deploy.yml', kubeConfig: [path: ''], kubeconfigId: 'ae92d8dc-053e-409e-ae1b-f6e3f3bbb9f4', secretName: '', ssh: [sshCredentialsId: '*', sshServer: ''], textCredentials: [certificateAuthorityData: '', clientCertificateData: '', clientKeyData: '', serverUrl: 'https://']
    }
    // 返回给gitlab一个信号 表示流水线成功
    updateGitlabCommitStatus name: 'one_project', state: 'success'
  }
}

此处发现一个问题,即:ref变量的值为refs/heads/test,但是根据分支拉代码的时候使用此变量会找不到分支,要用test也就是分支的实际名字才能拉取到,所以需要根据ref变量值获取结尾的test.

修改部分代码:

    stage('pull code') {
      // split 为分割,将给出的字符串按照"/"符号分割后返回一个列表:["refs","heads","test"] [-1]为对应的下标值,直接取最后一个 然后赋值给 "tag"
      def tag = "${ref}".split("/")[-1]
      echo "${tag}"
      // 直接使用变量 tag 的值来拉取对应分支代码
      git branch: "${tag}", credentialsId: "${GITLAB_ID}", url: "${GITLAB_SSH_URL}"
      echo "The first stage end"
    }