《自己动手写操作系统》第四章——摆脱dos引导:boot &&Loader
摘要：在开机过程中，从BIOS中取得第一条指令到内核加载，操作系统的开机运行过程是这样的：“引导---加载内核进入内存——跳入保护模式——开始执行内核”。也就是说，内核执行之前，需要先加载进入内存，然后准备进入保护模式。引导扇区（里面有一定的程序）的512B是不够的，我们在引导扇区和内核之间加入一个模块——Loader，负责完成上述过程。即“引导扇区——Loader——kernel”。在前三章中，我们是靠freedos来完成这个过程的，第四章，我们将写自己的boot和loader。
1.Fat12
首先，我们看一下fat12磁盘信息布局：
主要包括几个部分：引导扇区，fat表，根目录，数据区
1.1引导扇区：
现在问题来了：引导扇区如何将控制权转交给Loader？也就是说，引导扇区如何找到软盘上的loader并将它载入内存，并转交控制权。
首先，我们来看一下引导扇区的格式：
| 名称 | 开始字节 | 长度 | 内容 | 参考值 |
| BS_jmpBOOT | 0 | 3 | 一个短跳转指令 | jmp Label_07c00H nop |
| BS_OEMName | 3 | 8 | 厂商名 | 'QingFeng' |
| BPB_BytesPerSec | 11 | 2 | 每扇区字节数（Bytes/Sector） | 0x200 |
| BPB_SecPerClus | 13 | 1 | 每簇扇区数（Sector/Cluster） | 0x1 |
| BPB_ResvdSecCnt | 14 | 2 | Boot记录占用多少扇区 | ox1 |
| BPB_NumFATs | 16 | 1 | 共有多少FAT表 | 0x2 |
| BPB_RootEntCnt | 17 | 2 | 根目录区文件最大数 | 0xE0 |
| BPB_TotSec16 | 19 | 2 | 扇区总数 | 0xB40[2*80*18] |
| BPB_Media | 21 | 1 | 介质描述符 | 0xF0 |
| BPB_FATSz16 | 22 | 2 | 每个FAT表所占扇区数 | 0x9 |
| BPB_SecPerTrk | 24 | 2 | 每磁道扇区数（Sector/track） | 0x12 |
| BPB_NumHeads | 26 | 2 | 磁头数（面数） | 0x2 |
| BPB_HiddSec | 28 | 4 | 隐藏扇区数 | 0 |
| BPB_TotSec32 | 32 | 4 | 如果BPB_TotSec16=0,则由这里给出扇区数 | 0 |
| BS_DrvNum | 36 | 1 | INT 13H的驱动器号 | 0 |
| BS_Reserved1 | 37 | 1 | 保留，未使用 | 0 |
| BS_BootSig | 38 | 1 | 扩展引导标记(29h) | 0x29 |
| BS_VolID | 39 | 4 | 卷序列号 | 0 |
| BS_VolLab | 43 | 11 | 卷标 | 'QingFeng' |
| BS_FileSysType | 54 | 8 | 文件系统类型 | 'FAT12' |
| 引导代码及其他内容 | 62 | 448 | 引导代码及其他数据 | 引导代码（剩余空间用0填充） |
| 结束标志0xAA55 | 510 | 2 | 第510字节为0x55，第511字节为0xAA | 0xAA55 |
1.2根目录条目格式
根目录条目（32B）格式如下： 我们可以根据根目录条目，找到引导文件名称，然后索引对应的firstclust。由于我们已经通过BPB_RootEntCnt确定数据区的开始位置，所以可以定位对应文件的firstclust所在位置。1.3fat项格式
首先fat项有12b，每个项对应数据区的一个簇。计算一下，fat有9个sector，(9*512)/12=384簇？难道仅仅能够管理20K的空间？ 第N个fat项表示数据区的第几个簇，fat项目的值表示文件的下一个簇号：这是一个fat项包含的两种信息。 通过上述内容，我们已经大概知道如何通过软盘上的信息，找到一个文件的所有内容。下面，我们来修改boot.asm，让它完成寻找loader，并载入内存的任务。2.Dos可以识别的引导盘____boot.bin
我们都知道，在CPU通电以后，会初始化当前指令为CS:IP=0000:0x7c00，然后会从这个地方执行BIOS的指令，BIOS将进行一些列初始化，然后将本地磁盘的第一个扇区（引导扇区）加载到内存，并开始执行引导扇区。所以，我们现在需要执行引导扇区。下面，看看引导扇区是内容如何： 代码如下：
;%define _BOOT_DEBUG_ ; 做 Boot Sector 时一定将此行注释掉!将此行打开后用 nasm Boot.asm -o Boot.com 做成一个.COM文件易于调试 %ifdef _BOOT_DEBUG_ org 0100h ; 调试状态, 做成 .COM 文件, 可调试 %else org 07c00h ; Boot 状态, Bios 将把 Boot Sector 加载到 0:7C00 处并开始执行 %endif ;================================================================================================ %ifdef _BOOT_DEBUG_ BaseOfStack equ 0100h ; 调试状态下堆栈基地址(栈底, 从这个位置向低地址生长) %else BaseOfStack equ 07c00h ; Boot状态下堆栈基地址(栈底, 从这个位置向低地址生长) %endif BaseOfLoader equ 09000h ; LOADER.BIN 被加载到的位置 ---- 段地址 OffsetOfLoader equ 0100h ; LOADER.BIN 被加载到的位置 ---- 偏移地址 RootDirSectors equ 14 ; 根目录占用空间 SectorNoOfRootDirectory equ 19 ; Root Directory 的第一个扇区号 SectorNoOfFAT1 equ 1 ; FAT1 的第一个扇区号 = BPB_RsvdSecCnt DeltaSectorNo equ 17 ; DeltaSectorNo = BPB_RsvdSecCnt + (BPB_NumFATs * FATSz) - 2 ; 文件的开始Sector号 = DirEntry中的开始Sector号 + 根目录占用Sector数目 + DeltaSectorNo ;================================================================================================ jmp short LABEL_START ; Start to boot. nop ; 这个 nop 不可少 ; 下面是 FAT12 磁盘的头 BS_OEMName DB 'ForrestY' ; OEM String, 必须 8 个字节 BPB_BytsPerSec DW 512 ; 每扇区字节数 BPB_SecPerClus DB 1 ; 每簇多少扇区 BPB_RsvdSecCnt DW 1 ; Boot 记录占用多少扇区 BPB_NumFATs DB 2 ; 共有多少 FAT 表 BPB_RootEntCnt DW 224 ; 根目录文件数最大值 BPB_TotSec16 DW 2880 ; 逻辑扇区总数 BPB_Media DB 0xF0 ; 媒体描述符 BPB_FATSz16 DW 9 ; 每FAT扇区数 BPB_SecPerTrk DW 18 ; 每磁道扇区数 BPB_NumHeads DW 2 ; 磁头数(面数) BPB_HiddSec DD 0 ; 隐藏扇区数 BPB_TotSec32 DD 0 ; 如果 wTotalSectorCount 是 0 由这个值记录扇区数 BS_DrvNum DB 0 ; 中断 13 的驱动器号 BS_Reserved1 DB 0 ; 未使用 BS_BootSig DB 29h ; 扩展引导标记 (29h) BS_VolID DD 0 ; 卷序列号 BS_VolLab DB 'Tinix0.01 '; 卷标, 必须 11 个字节 BS_FileSysType DB 'FAT12 ' ; 文件系统类型, 必须 8个字节 LABEL_START: mov ax, cs mov ds, ax mov es, ax mov ss, ax mov sp, BaseOfStack ; 清屏 mov ax, 0600h ; AH = 6, AL = 0h mov bx, 0700h ; 黑底白字(BL = 07h) mov cx, 0 ; 左上角: (0, 0) mov dx, 0184fh ; 右下角: (80, 50) int 10h ; int 10h mov dh, 0 ; "Booting " call DispStr ; 显示字符串 xor ah, ah ; ┓ xor dl, dl ; ┣ 软驱复位 int 13h ; ┛
利用上述代码，生成boot.bin，然后写入磁盘引导扇区。
3.Loader____loader.bin
上面已经说过，我们需要写代码将loader加载到内存，所以，我们先来写一个小的loader——它仅仅实现了显示字符的功能。
4.加载loader进入内存_____带有读取软盘+寻找loader功能的boot
为了将文件读入内存，需要读取软盘。我们用BIOS的int 13中断来实现软盘读写，int 13h的用法如下：
BIOS磁盘操作 INT 13H 处理的记录都是一个扇区大小,以实际的磁道号和扇区号寻址.
AH |
执行操作 |
入口参数 |
返回参数 |
00H |
复位磁盘系统 |
DL=驱动器号 |
失败: AH=错误码 |
01H |
读磁盘状态 |
|
AH=状态字节 |
02H |
读磁盘 |
AL= 扇区数 (CL)6,7 (CH)0~7=柱面/磁道号 (CL)0~5= 扇区号 DH= 磁头号/盘面 DL= 驱动器号 ES:BX= 数据区中I/O缓冲区的地址 |
成功: AH=0, AL=读取的扇区数 失败: AH=错误码 |
03H |
写磁盘 |
成功: AH=0, AL=写入的扇区数 失败: AH=错误码 |
|
04H |
检验磁盘扇区 |
AL、CL、CH、DH、DL定义同上,无ES:BX |
成功: AH=0,AL=检验的扇区数 失败: AH=错误码 |
05H |
格式化盘磁道 |
AL、CL、CH、DH、DL定义同上 ES:BX= 格式化参数表指针 |
成功: AH=0 失败: AH=错误码 |
注: 驱动器号(软盘00H=A驱,01H=B驱..., 硬盘80H=C盘,81H=D盘...)
通过BIOS中断，我们知道，读写磁盘需要的参数不是从0开始的扇区号，而是柱面号、磁头号、当前柱面上的分区号。二者的转化关系如下（见书籍P110）：
4.1读扇区的代码如下：
输出：es:bx所指向的内存区域
输入：扇区的起始号码ax
;----------------------------------------------------------------------------
; 函数名: ReadSector
;----------------------------------------------------------------------------
; 作用:
; 从第 ax 个 Sector 开始, 将 cl 个 Sector 读入 es:bx 中
ReadSector:
; -----------------------------------------------------------------------
; 怎样由扇区号求扇区在磁盘中的位置 (扇区号 -> 柱面号, 起始扇区, 磁头号)
; -----------------------------------------------------------------------
; 设扇区号为 x
; ┌ 柱面号 = y >> 1
; x ┌ 商 y ┤
; -------------- => ┤ └ 磁头号 = y & 1
; 每磁道扇区数 │
; └ 余 z => 起始扇区号 = z + 1
push bp
mov bp, sp
sub esp, 2 ; 辟出两个字节的堆栈区域保存要读的扇区数: byte [bp-2]
mov byte [bp-2], cl
push bx ; 保存 bx
mov bl, [BPB_SecPerTrk] ; bl: 除数
div bl ; y 在 al 中, z 在 ah 中
inc ah ; z ++
mov cl, ah ; cl <- 起始扇区号
mov dh, al ; dh <- y
shr al, 1 ; y >> 1 (其实是 y/BPB_NumHeads, 这里BPB_NumHeads=2)
mov ch, al ; ch <- 柱面号
and dh, 1 ; dh & 1 = 磁头号
pop bx ; 恢复 bx
; 至此, "柱面号, 起始扇区, 磁头号" 全部得到 ^^^^^^^^^^^^^^^^^^^^^^^^
mov dl, [BS_DrvNum] ; 驱动器号 (0 表示 A 盘)
.GoOnReading:
mov ah, 2 ; 读
mov al, byte [bp-2] ; 读 al 个扇区
int 13h
jc .GoOnReading ; 如果读取错误 CF 会被置为 1, 这时就不停地读, 直到正确为止
add esp, 2
pop bp
ret
;----------------------------------------------------------------------------4.2读取扇区的代码写好之后，我们需要在软盘中寻找loader.bin,部分代码如下：
;-------------------------------------------------------------------------------
; 下面在 A 盘的根目录寻找 LOADER.BIN
; After we find the loader.bin, es:di pointer the first byte after the 'filename' of entry of dir for LOader.bin.
mov word [wSectorNo], SectorNoOfRootDirectory
LABEL_SEARCH_IN_ROOT_DIR_BEGIN:
cmp word [wRootDirSizeForLoop], 0 ; ┓
jz LABEL_NO_LOADERBIN ; ┣ 判断根目录区是不是已经读完
dec word [wRootDirSizeForLoop] ; ┛ 如果读完表示没有找到 LOADER.BIN
mov ax, BaseOfLoader
mov es, ax ; es <- BaseOfLoader
mov bx, OffsetOfLoader ; bx <- OffsetOfLoader 于是, es:bx = BaseOfLoader:OffsetOfLoader
mov ax, [wSectorNo] ; ax <- Root Directory 中的某 Sector 号
mov cl, 1
call ReadSector
mov si, LoaderFileName ; ds:si -> "LOADER BIN"
mov di, OffsetOfLoader ; es:di -> BaseOfLoader:0100 = BaseOfLoader*10h+100
cld
mov dx, 10h
LABEL_SEARCH_FOR_LOADERBIN:
cmp dx, 0 ; ┓循环次数控制,
jz LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR ; ┣如果已经读完了一个 Sector,
dec dx ; ┛就跳到下一个 Sector
mov cx, 11
LABEL_CMP_FILENAME:
cmp cx, 0
jz LABEL_FILENAME_FOUND ; 如果比较了 11 个字符都相等, 表示找到
dec cx
lodsb ; ds:si -> al
cmp al, byte [es:di]
jz LABEL_GO_ON
jmp LABEL_DIFFERENT ; 只要发现不一样的字符就表明本 DirectoryEntry 不是
; 我们要找的 LOADER.BIN
LABEL_GO_ON:
inc di
jmp LABEL_CMP_FILENAME ; 继续循环
LABEL_DIFFERENT:
and di, 0FFE0h ; else ┓ di &= E0 为了让它指向本条目开头
add di, 20h ; ┃
mov si, LoaderFileName ; ┣ di += 20h 下一个目录条目
jmp LABEL_SEARCH_FOR_LOADERBIN; ┛
LABEL_GOTO_NEXT_SECTOR_IN_ROOT_DIR:
add word [wSectorNo], 1
jmp LABEL_SEARCH_IN_ROOT_DIR_BEGIN
LABEL_NO_LOADERBIN:
mov dh, 2 ; "No LOADER."
call DispStr ; 显示字符串
%ifdef _BOOT_DEBUG_
mov ax, 4c00h ; ┓
int 21h ; ┛没有找到 LOADER.BIN, 回到 DOS
%else
jmp $ ; 没有找到 LOADER.BIN, 死循环在这里
%endif注意一些数据结构：需要提前获取根目录包含的扇区个数；一个扇区包含16个目录项；
4.3将开始扇区装载进入内存，并利用它找到的fat项，找到loader占用的其他扇区：
在这里，我们先调试一下这一部分代码，程序逻辑如下：
CPU上电复位,从0x7c00开始执行程序（BIOS中？）——BIOS将磁盘启动扇区，也就是第一扇区的512B数据加载进入内存，将控制权交给第一扇区——boot将在磁盘上搜寻loader文件的信息，知道找到loader——将loader文件加载到内存，然后将控制权转交给它。关于软驱复位（floopy reset）：Floppy-disk controller是用于控制软盘的控制器芯片，它和CPU的互联情况如下。软盘复位，也就是对芯片进行初始化，清楚错误信息等。FDC与CPU的逻辑关系如下：
4.4加载loader
在上面的程序中，我们已经找到了loader，有了loader.bin的起始扇区号，我们需要用这个扇区号做两件事——将起始扇区装载到内存；通过它找到fat项，从而找到loader占用的其他所有扇区。这里，我们将起始扇区装载到BaseOfLoader:OffsetOfLoader。我们现在需要一个函数：根据扇区号，找到对应fat项的值。输入与输出均为ax，其中输入是文件的开始簇号。
上面一个函数，让我们可以根据一个扇区号（簇号）索引到对应fat的条目，然后我们需要根据fat条目的内容，找到下一个fat条目的序号，也就是data区域的簇号。代码如下：
;-----------------------------------------------------above: search for LOADER BIN---------------------------------------
;es:di point to the name,so di/32*32 + 26 will point to the fstclus
;when we get fstclus,which is fst entry in FAT，we will get the content of the fat entry.
LABEL_FILENAME_FOUND: ; 找到 LOADER.BIN 后便来到这里继续
mov ax, RootDirSectors
and di, 0FFE0h ; di -> 当前条目的开始
add di, 01Ah ; di -> 首 Sector
;di point to the fst clus
mov cx, word [es:di]
push cx ; 保存此 Sector 在 FAT 中的序号
add cx, ax
add cx, DeltaSectorNo ; 这句完成时 cl 里面变成 LOADER.BIN 的起始扇区号 (从 0 开始数的序号)
mov ax, BaseOfLoader
mov es, ax ; es <- BaseOfLoader
mov bx, OffsetOfLoader ; bx <- OffsetOfLoader 于是, es:bx = BaseOfLoader:OffsetOfLoader = BaseOfLoader * 10h + OffsetOfLoader
mov ax, cx ; ax <- Sector 号
LABEL_GOON_LOADING_FILE:
push ax ; ┓
push bx ; ┃
mov ah, 0Eh ; ┃ 每读一个扇区就在 "Booting " 后面打一个点, 形成这样的效果:
mov al, '.' ; ┃
mov bl, 0Fh ; ┃ Booting ......
int 10h ; ┃
pop bx ; ┃
pop ax ; ┛
mov cl, 1
call ReadSector
pop ax ; 取出此 Sector 在 FAT 中的序号
call GetFATEntry
cmp ax, 0FFFh
jz LABEL_FILE_LOADED;loader is fully loaded into memory
push ax ; 保存 Sector 在 FAT 中的序号
mov dx, RootDirSectors
add ax, dx
add ax, DeltaSectorNo
add bx, [BPB_BytsPerSec]
jmp LABEL_GOON_LOADING_FILE
LABEL_FILE_LOADED:
mov dh, 1 ; "Ready."
call DispStr ; 显示字符串
; *****************************************************************************************************
jmp BaseOfLoader:OffsetOfLoader ; 这一句正式跳转到已加载到内存中的 LOADER.BIN 的开始处
; 开始执行 LOADER.BIN 的代码
; Boot Sector 的使命到此结束
; *****************************************************************************************************5.向loader交出控制权
上面的步骤中，我们已经成功将loader.bin载入内存，下面我们来一个跳转：jmp BaseOfLoader:OfssetOfLoader开始执行loader。我们可以先通过在dos环境下运行来调试程序，然后再将boot和loader写入磁盘。6.保护模式下的操作系统
好了，我们已经有boot和loader，那么可以直接把pmtest9编译一下，改名为loader bin，程序就可以马上执行。只要一个.com文件中不包含dos系统调用，我们都一把它当作loader来使用。但是，真正的内核是ELF格式，而且内核加载之前已经进入保护模式。所以，Loader还有两项工作没有完成：1）加载内核2）进入保护模式。7.回忆启动软盘的制作过程
1）生成虚拟软盘镜像，命名为hyk.img
2) 将其作为软盘b插入，运行dos，格式化hyk.img
3）使用dd命令，将boot.bin拷入软盘hyk.img第一个扇区
4）使用copy命令，将LOADER拷入hyk.img第四章：完