用多媒体库 Bass.dll 播放 mp3 [13] - 混响(Reverb)效果

本例效果图:

---

代码文件:

---

unit Unit1;



interface



uses

  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,

  Dialogs, StdCtrls, ComCtrls;



type

  TForm1 = class(TForm)

    OpenDialog1: TOpenDialog;

    Button1: TButton;

    Button2: TButton;

    Button3: TButton;

    TrackBar1: TTrackBar;

    Label1: TLabel;

    procedure FormCreate(Sender: TObject);

    procedure Button1Click(Sender: TObject);

    procedure Button2Click(Sender: TObject);

    procedure Button3Click(Sender: TObject);

    procedure FormDestroy(Sender: TObject);

    procedure TrackBar1Change(Sender: TObject);

  end;



var

  Form1: TForm1;



implementation



{$R *.dfm}



uses Bass;



var

  hs: HSTREAM;  {流句柄}

  reverb: BASS_DX8_REVERB; {混响的参数结构, 不能是局部变量; 本例只测试了结构中的 fReverbTime 参数}

  fx: HFX; {DX 的效果句柄}



procedure TForm1.FormCreate(Sender: TObject);

begin

  {reverb.fReverbTime: 0.001 - 3000.0; 默认 1000}

  TrackBar1.Min := 1;

  TrackBar1.Max := 3000;

  TrackBar1.Position := 1000;



  if HiWord(BASS_GetVersion) <> BASSVERSION then

    MessageBox(0, '"Bass.dll" 文件版本不合适! ', nil, MB_ICONERROR);



  if not BASS_Init(-1, 44100, 0, 0, nil) then ShowMessage('初始化错误');

end;



{打开}

procedure TForm1.Button1Click(Sender: TObject);

var

  Mp3Path: AnsiString;

begin

  BASS_StreamFree(hs);



  OpenDialog1.Filter := 'Mp3 文件(*.mp3)|*.mp3|Wav 文件(*.wav)|*wav';

  if OpenDialog1.Execute then

    Mp3Path := AnsiString(OpenDialog1.FileName);



  {实现混响等效果, 需要指定 BASS_SAMPLE_FX 参数}

  hs := BASS_StreamCreateFile(False, PAnsiChar(Mp3Path), 0, 0, BASS_SAMPLE_FX);



  if hs < BASS_ERROR_ENDED then

    Text := '打开失败'

  else begin

    Text := string(Mp3Path);

    {设置并返回效果句柄}

    fx := BASS_ChannelSetFX(hs, BASS_FX_DX8_REVERB, 0);

  end;

end;



{播放}

procedure TForm1.Button2Click(Sender: TObject);

begin

  BASS_ChannelPlay(hs, False);

end;



{暂停}

procedure TForm1.Button3Click(Sender: TObject);

begin

  BASS_ChannelPause(hs);

end;



procedure TForm1.FormDestroy(Sender: TObject);

begin

  BASS_Free;

end;



procedure TForm1.TrackBar1Change(Sender: TObject);

begin

  reverb.fReverbTime := TrackBar1.Position;

  BASS_FXSetParameters(fx, @reverb);

  Label1.Caption := Format('混响时间: %f', [reverb.fReverbTime]);

end;



end.


 
   

窗体文件:

---

object Form1: TForm1

  Left = 222

  Top = 114

  Caption = 'Form1'

  ClientHeight = 119

  ClientWidth = 299

  Color = clBtnFace

  Font.Charset = DEFAULT_CHARSET

  Font.Color = clWindowText

  Font.Height = -11

  Font.Name = 'Tahoma'

  Font.Style = []

  OldCreateOrder = False

  Position = poDesigned

  OnCreate = FormCreate

  OnDestroy = FormDestroy

  PixelsPerInch = 96

  TextHeight = 13

  object Label1: TLabel

    Left = 40

    Top = 67

    Width = 52

    Height = 13

    Caption = #28151#21709#26102#38388':'

  end

  object Button1: TButton

    Left = 32

    Top = 25

    Width = 75

    Height = 25

    Caption = #25171#24320

    TabOrder = 0

    OnClick = Button1Click

  end

  object Button2: TButton

    Left = 113

    Top = 25

    Width = 75

    Height = 25

    Caption = #25773#25918

    TabOrder = 1

    OnClick = Button2Click

  end

  object Button3: TButton

    Left = 194

    Top = 25

    Width = 75

    Height = 25

    Caption = #26242#20572

    TabOrder = 2

    OnClick = Button3Click

  end

  object TrackBar1: TTrackBar

    Left = 26

    Top = 86

    Width = 243

    Height = 23

    ShowSelRange = False

    TabOrder = 3

    OnChange = TrackBar1Change

  end

  object OpenDialog1: TOpenDialog

  end

end