objc_msgSend流程分析(快速查找)

前言

• 在我們知道了cache寫入sel-imp流程後，接下來我們探討寫入之前的消息發送的流程

cache原理分析

• 本篇重點也就是上一篇流程圖中的cache reader 下的objc_msgSend

前情提要

知識拓展

• 編譯時

編譯時做了簡單的翻譯工作，可以理解為檢查語法有無錯誤，當我們按下bulid時，就開始進行編譯，如果有出現errors或是warning時為編譯檢查，這樣產生的錯誤叫做編譯時錯誤，而這個檢查的過程叫做編譯類型檢查 或是靜態類型檢查 (所以編譯時並沒有將程式碼放到記憶體中運行，只是把程式碼當作文本掃描下來)

• 運行時

運行時，程式碼被裝載到記憶體中，不同於編譯時做的類型檢查，而是在記憶體中進行操作及判斷

• Runtime 版本

早期版本Lagacy版本(早期版本)用於Objective-C 1.0，32位Mac OS X的平台上

現行版本Mondern版本(現行版本)用於iphone程序和MacOS X v10.5及以後的系統中的64位程序

• Runtime官方文檔

Introduction

• rumtime調用的三種途徑與底層關係

方法的本質

• 我們在isa與類的關聯原理，使用了clang編譯成.cpp文件，並且進一步的探索對象的本質

isa與類的關係

• 在這篇我們一樣使用clang編譯成.cpp文件並進一步探討方法的本質

//main.m中方法的調用
LGPerson *person = [LGPerson alloc];
[person sayNB];
[person sayHello];

//⬇️clang編譯底層實現
LGPerson *person = ((LGPerson *(*)(id, SEL))(void *)objc_msgSend)((id)objc_getClass("LGPerson"), sel_registerName("alloc"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayNB"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayHello"));

• 可以看到方法的本質其實底層是objc_msgSend消息發送

驗證

• 有了上述的推論，現在我們使用objc_msgSend 為person對象發送消息，與使用方法調用，來看看是否會打印一樣．

注意

• 調用objc_msgSend 時需要導入頭文件，#import

• 將嚴厲檢查機制關掉，路徑build setting →enable strict checking of obc_msgSend calls 改為no

• main中的調用

LGPerson *person = [LGPerson alloc];   
objc_msgSend(person,sel_registerName("sayNB"));
[person sayNB];

• 可以看到打印一樣
• [person sayNB]等價於objc_msgSend(person,sel_registerName("sayNB"))

打印結果

子類對象調用父類的方法

• 驗證了上述方法調用的本質後，我們來試試子類調用父類的方法
• 首先在創建兩個類

@interface LGTeacher : NSObject
- (void)sayHello;
@end

@implementation LGTeacher
- (void)sayHello{
    NSLog(@"666");
}
@end

@interface LGPerson : LGTeacher
- (void)sayHello;
- (void)sayNB;
@end

@implementation LGPerson
- (void)sayNB{
    NSLog(@"666");
}
@end

• main.m文件

LGPerson *person = [LGPerson alloc];
LGTeacher *teacher = [LGTeacher alloc];
//一般子類對象調用父類方法
[person sayHello];

struct objc_super lgsuper;
lgsuper.receiver = person; //消息的接收者还是person
lgsuper.super_class = [LGTeacher class]; //告诉父类是谁

//消息的接受者还是自己 - 父类 - 请你直接找我的父亲
objc_msgSendSuper(&lgsuper, sel_registerName("sayHello"));

• objc_msgSendSuper方法中有兩個參數（结构体，sel），其結構體類型是objc_super定義的結構體對象，並且需要指定receiver和super_class兩個屬性，子系統實現和定義如下
• objc_msgSendSuper 方法參數

objc_msgSendSuper源碼實現

• objc_super原始碼定義

objc_super原始碼定義

打印結果如下

打印結果

由上述測試我們可以知道不管是[person sayHello] 或是objc_msgSendSuper(&lgsuper, sel_registerName("sayHello")); 兩者都是執行父類的sayHello的實現，所以我們可以假設

對象調用會先到所屬的類中查找，如果類中沒有，就往父類找。

objc_msgSend快速查找流程分析

• 在objc4-781原始代碼中，搜索objc_msgSend，由於我們日常開發的都是架構是arm64，所以需要在arm64.s後綴的文件中查找原始代碼objc_msgSend實現，發現是彙編實現，其目的為提高效率。

objc_msgSend彙編源碼

objc_msgSend是消息發送的源碼入口，其使用彙編實現的，源碼實現如下

//----消息發送的入口--
ENTRY _objc_msgSend 
//---- 無窗口
    UNWIND _objc_msgSend, NoFrame 
//---- p0 和空對比，即判斷接收者是否存在，
//---- cmp其實是做減法運算。
//---- p0是objc_msgSend的第一個参数-消息接收者receiver
    cmp p0, #0          // nil check and tagged pointer check 
//---- le(less than or equl to) 即小於等於 --支持taggedpointer（小對象類型）的流程
#if SUPPORT_TAGGED_POINTERS
    b.le    LNilOrTagged        //  (MSB tagged pointer looks negative) 
#else
//---- p0 eq(equal to)等於 0 時，直接返回 空
    b.eq    LReturnZero 
//---- 判定p0 - #0 小於等於 0 跳轉LNilOrTagged
//---- 判定p0 - #0 等於 0 跳轉LNilOrTagged

#endif 
//---- p0即receiver 肯定存在的流程
//---- 根據對象拿出isa，x0寄存器(存放)指向的地址 讀取出 isa，存入 p13寄存器
    ldr p13, [x0]       // p13 = isa 
//---- 在64位架構下通過 p16 = isa（p13） & ISA_MASK，拿出shiftcls信息，得到class信息
    GetClassFromIsa_p16 p13     // p16 = class  
LGetIsaDone:
    // calls imp or objc_msgSend_uncached 
//---- 如果有isa，走到CacheLookup 即缓存查找流程，也就是所谓的sel-imp快速查找流程
    CacheLookup NORMAL, _objc_msgSend

#if SUPPORT_TAGGED_POINTERS
LNilOrTagged:
//---- 等於空，返回空
    b.eq    LReturnZero     // nil check 

    // tagged
    adrp    x10, _objc_debug_taggedpointer_classes@PAGE
    add x10, x10, _objc_debug_taggedpointer_classes@PAGEOFF
    ubfx    x11, x0, #60, #4
    ldr x16, [x10, x11, LSL #3]
    adrp    x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGE
    add x10, x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGEOFF
    cmp x10, x16
    b.ne    LGetIsaDone

    // ext tagged
    adrp    x10, _objc_debug_taggedpointer_ext_classes@PAGE
    add x10, x10, _objc_debug_taggedpointer_ext_classes@PAGEOFF
    ubfx    x11, x0, #52, #8
    ldr x16, [x10, x11, LSL #3]
    b   LGetIsaDone
// SUPPORT_TAGGED_POINTERS
#endif

LReturnZero:
    // x0 is already zero
    mov x1, #0
    movi    d0, #0
    movi    d1, #0
    movi    d2, #0
    movi    d3, #0
    ret

    END_ENTRY _objc_msgSend

第一步

• 判斷objc_msgSend方法的第一個參數receiver是否為空

  • 如果支持tagged pointer 跳轉至LNilOrTagged
  • 如果小對象 為空，則直接返回空 即LReturnZero
  • 如果小對象不為空，則處理小對象的isa 即到第二步

• 不為小對象 且receivier也不為空

  • 從receivier 取出isa存入p13寄存器
  • 通過GetClassFromIsa_p16 中,arm架構下通過 isa & Mask 獲取到shiftcls位域的類信息，即class，GetClassFromIsa_p16 的彙編實現如下，然後走到第二步

  .macro GetClassFromIsa_p16 /* src */
  //用於watchOS
  #if SUPPORT_INDEXED_ISA
      // Indexed isa
    // 將isa的值存入p16寄存器
      mov p16, $0         // optimistically set dst = src
      tbz p16, #ISA_INDEX_IS_NPI_BIT, 1f  // done if not non-pointer isa
    // 判斷是否是non-pointer
      // isa in p16 is indexed
    // 將 _objc_indexed_classes 所在的基地址，讀入x10寄存器
      adrp    x10, _objc_indexed_classes@PAGE
    // 將 x10 = x10 + _objc_indexed_classes(page中的偏移量)-- x10基址 根據偏移量進行內存偏移
      add x10, x10, _objc_indexed_classes@PAGEOFF
    // 從p16的第ISA_INDEX_SHIFT位開始，提取ISA_INDEX_BITS位 到 p16寄存器 剩餘的高位用0補充
      ubfx    p16, p16, #ISA_INDEX_SHIFT, #ISA_INDEX_BITS  // extract index
      ldr p16, [x10, p16, UXTP #PTRSHIFT] // load class from array
  1:
  // 用於64位系統
  #elif __LP64__
      // 64-bit packed isa
      and p16, $0, #ISA_MASK
  
  #else
        // 用於32位系統 
      // 32-bit raw isa
      mov p16, $0
  
  #endif
  
  .endmacro
  
  

  第二步

  • 獲取isa完畢，進入慢速查找流程CacheLookup Normal

  CacheLookup 緩存查找

  • 彙編源碼
  • 接下來查找CacheLookup Normal 搜尋 找到 .macro CacheLookup的彙編開頭，相當於是CacheLookup的宏(define)定義

  //！！！！！！！！！重点！！！！！！！！！！！！
  .macro CacheLookup 
      //
      // Restart protocol:
      //
      //   As soon as we're past the LLookupStart$1 label we may have loaded
      //   an invalid cache pointer or mask.
      //
      //   When task_restartable_ranges_synchronize() is called,
      //   (or when a signal hits us) before we're past LLookupEnd$1,
      //   then our PC will be reset to LLookupRecover$1 which forcefully
      //   jumps to the cache-miss codepath which have the following
      //   requirements:
      //
      //   GETIMP:
      //     The cache-miss is just returning NULL (setting x0 to 0)
      //
      //   NORMAL and LOOKUP:
      //   - x0 contains the receiver
      //   - x1 contains the selector
      //   - x16 contains the isa
      //   - other registers are set as per calling conventions
      //
  LLookupStart$1:
  
  //---- p1 = SEL, p16 = isa --- #define CACHE (2 * __SIZEOF_POINTER__)，其中 __SIZEOF_POINTER__表示pointer的大小 ，即 2*8 = 16
  //---- p11 = mask|buckets -- 从x16（即isa）中平移16字节，取出cache 存入p11寄存器 -- isa距离cache 正好16字节：isa（8字节）-superClass（8字节）-cache（mask高16位 + buckets低48位）
      ldr p11, [x16, #CACHE]              
  //---- 64位真机
  #if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16 
  //--- p11(cache) & 0x0000ffffffffffff ，mask高16位抹零，得到buckets 存入p10寄存器-- 即去掉mask，留下buckets
      and p10, p11, #0x0000ffffffffffff   // p10 = buckets 
  
  //--- p11(cache)右移48位，得到mask（即p11 存储mask），mask & p1(msgSend的第二个参数 cmd-sel) ，得到sel-imp的下标index（即搜索下标） 存入p12（cache insert写入时的哈希下标计算是 通过 sel & mask，读取时也需要通过这种方式）
      and p12, p1, p11, LSR #48       // x12 = _cmd & mask 
  
  //--- 非64位真机
  #elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4 
      and p10, p11, #~0xf         // p10 = buckets
      and p11, p11, #0xf          // p11 = maskShift
      mov p12, #0xffff
      lsr p11, p12, p11               // p11 = mask = 0xffff >> p11
      and p12, p1, p11                // x12 = _cmd & mask
  #else
  #error Unsupported cache mask storage for ARM64.
  #endif
  
  //--- p12是下标 p10是buckets数组首地址，下标 * 1<<4(即16) 得到实际内存的偏移量，通过buckets的首地址偏移，获取bucket存入p12寄存器
  //--- LSL #(1+PTRSHIFT)-- 实际含义就是得到一个bucket占用的内存大小 -- 相当于mask = occupied -1-- _cmd & mask -- 取余数
      add p12, p10, p12, LSL #(1+PTRSHIFT)   
                       // p12 = buckets + ((_cmd & mask) << (1+PTRSHIFT)) -- PTRSHIFT是3      
  
  //--- 从x12（即p12）中取出 bucket 分别将imp和sel 存入 p17（存储imp） 和 p9（存储sel）
      ldp p17, p9, [x12]      // {imp, sel} = *bucket 
  
  //--- 比较 sel 与 p1（传入的参数cmd）
  1:  cmp p9, p1          // if (bucket->sel != _cmd) 
  //--- 如果不相等，即没有找到，请跳转至 2f
      b.ne    2f          //     scan more 
  //--- 如果相等 即cacheHit 缓存命中，直接返回imp
      CacheHit $0         // call or return imp 
  
  2:  // not hit: p12 = not-hit bucket
  //--- 如果一直都找不到， 因为是normal ，跳转至__objc_msgSend_uncached
      CheckMiss $0            // miss if bucket->sel == 0 
  //--- 判断p12（下标对应的bucket） 是否 等于 p10（buckets数组第一个元素，），如果等于，则跳转至第3步
      cmp p12, p10        // wrap if bucket == buckets 
  //--- 定位到最后一个元素（即第一个bucket）
      b.eq    3f 
  //--- 从x12（即p12 buckets首地址）- 实际需要平移的内存大小BUCKET_SIZE，得到得到第二个bucket元素，imp-sel分别存入p17-p9，即向前查找
      ldp p17, p9, [x12, #-BUCKET_SIZE]!  // {imp, sel} = *--bucket 
  //--- 跳转至第1步，继续对比 sel 与 cmd
      b   1b          // loop 
  
  3:  // wrap: p12 = first bucket, w11 = mask
  #if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
  //--- 人为设置到最后一个元素
  //--- p11（mask）右移44位 相当于mask左移4位，直接定位到buckets的最后一个元素，缓存查找顺序是向前查找
      add p12, p12, p11, LSR #(48 - (1+PTRSHIFT)) 
                      // p12 = buckets + (mask << 1+PTRSHIFT) 
  #elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
      add p12, p12, p11, LSL #(1+PTRSHIFT)
                      // p12 = buckets + (mask << 1+PTRSHIFT)
  #else
  #error Unsupported cache mask storage for ARM64.
  #endif
  
      // Clone scanning loop to miss instead of hang when cache is corrupt.
      // The slow path may detect any corruption and halt later.
  //--- 再查找一遍缓存()
  //--- 拿到x12（即p12）bucket中的 imp-sel 分别存入 p17-p9
      ldp p17, p9, [x12]      // {imp, sel} = *bucket 
  
  //--- 比较 sel 与 p1（传入的参数cmd）
  1:  cmp p9, p1          // if (bucket->sel != _cmd) 
  //--- 如果不相等，即走到第二步
      b.ne    2f          //     scan more 
  //--- 如果相等 即命中，直接返回imp
      CacheHit $0         // call or return imp  
  
  2:  // not hit: p12 = not-hit bucket
  //--- 如果一直找不到，则CheckMiss
      CheckMiss $0            // miss if bucket->sel == 0 
  //--- 判断p12（下标对应的bucket） 是否 等于 p10（buckets数组第一个元素）-- 表示前面已经没有了，但是还是没有找到
      cmp p12, p10        // wrap if bucket == buckets 
      b.eq    3f //如果等于，跳转至第3步
  //--- 从x12（即p12 buckets首地址）- 实际需要平移的内存大小BUCKET_SIZE，得到得到第二个bucket元素，imp-sel分别存入p17-p9，即向前查找
      ldp p17, p9, [x12, #-BUCKET_SIZE]!  // {imp, sel} = *--bucket 
  //--- 跳转至第1步，继续对比 sel 与 cmd
      b   1b          // loop 
  
  LLookupEnd$1:
  LLookupRecover$1:
  3:  // double wrap
  //--- 跳转至JumpMiss 因为是normal ，跳转至__objc_msgSend_uncached
  
      JumpMiss $0 
  .endmacro
  
  //以下是最后跳转的汇编函数
  .macro CacheHit
  .if $0 == NORMAL
      TailCallCachedImp x17, x12, x1, x16 // authenticate and call imp
  .elseif $0 == GETIMP
      mov p0, p17
      cbz p0, 9f          // don't ptrauth a nil imp
      AuthAndResignAsIMP x0, x12, x1, x16 // authenticate imp and re-sign as IMP
  9:  ret             // return IMP
  .elseif $0 == LOOKUP
      // No nil check for ptrauth: the caller would crash anyway when they
      // jump to a nil IMP. We don't care if that jump also fails ptrauth.
      AuthAndResignAsIMP x17, x12, x1, x16    // authenticate imp and re-sign as IMP
      ret             // return imp via x17
  .else
  .abort oops
  .endif
  .endmacro
  
  .macro CheckMiss
      // miss if bucket->sel == 0
  .if $0 == GETIMP 
  //--- 如果为GETIMP ，则跳转至 LGetImpMiss
      cbz p9, LGetImpMiss
  .elseif $0 == NORMAL 
  //--- 如果为NORMAL ，则跳转至 __objc_msgSend_uncached
      cbz p9, __objc_msgSend_uncached
  .elseif $0 == LOOKUP 
  //--- 如果为LOOKUP ，则跳转至 __objc_msgLookup_uncached
      cbz p9, __objc_msgLookup_uncached
  .else
  .abort oops
  .endif
  .endmacro
  
  .macro JumpMiss
  .if $0 == GETIMP
      b   LGetImpMiss
  .elseif $0 == NORMAL
      b   __objc_msgSend_uncached
  .elseif $0 == LOOKUP
      b   __objc_msgLookup_uncached
  .else
  .abort oops
  .endif
  .endmacro
  
  

  第一步:獲取cache地址

  • 通過isa即首地址平移16字節(objc_class中，首地址距離cache為16字節，即isa首地址 占8字節，superclass占8字節)，獲取cache，cache中高16位儲存mask，低48位存buckets，即p11 = cache。

  第二步:從cache中分別取出buckets和mask，並由mask根據哈希算法計算出哈希下標

  • 通過cache與掩碼(0x0000ffffffffffff)的＆運算，將高16位清零得到bucket指針地址，p10 = buckets

  • 將cache右移48位，得到mask，即p11 = mask

  • 將objc_msgSend的參數p1(即第二個參數_cmd)&mask，通過哈希算法，得到需要查找存儲sel-imp的bucket下標index，即p12 = index = _cmd&mask，為什麼通過這種方式呢？因為在存儲sel-imp時，也是通過同樣哈希算法計算哈希下標進行儲存，所以讀取也是需要通過同樣的方式讀取，如下所示

cache_t存储sel-imp时计算哈希下标的哈希算法源码

第三步：根據所得的哈希下標index和bucket首地址，取出哈希下標對應bucket

• 其中PTRSHIFT等於3，左移4位(即2^4=16字節)的目的是計算出一個bucket實際佔用的大小，結構體bucket_t 中sel佔8字節，imp佔８字節。
• 根據計算的哈希下標index乘以單個bucket佔用的內存大小，得到buckets首地址在實際內存中的偏移量。
• 通過首地址+實際偏移量，獲取哈希下標index對應的bucket

第四步：取出sel-imp

• 根據獲取的bucket取出其中的imp存入p17 即p17 = imp ，取出sel存入p9 即p9= sel

第五步：第一次遞歸循環

• 比較獲取的bucket中sel與objc_msgSend 的第二個參數的_cmd(即p1)是否相等
• 如果相等，則直接跳轉至cacheHit，即緩存命中，返回imp
• 如果不相等，會有以下兩種情況
• 如果一直找不到，直接跳轉至CheckMiss，因為$0是normal，會跳轉至__objc_msgSend_uncached ，即進入慢速查找流程
• 如果根據index獲取的bucket等於buckets的第一個元素，則人為的將當前bucket設置buckets的最後一個元素(通過buckets首地址+mask右移44位(等同於左移4位)直接定位到bucket的最後一個元素 )，然後繼續進行遞歸循環(第一個遞歸循環嵌套第二個遞歸循環)，即第六步
• 如果當前bucket不等於buckets第一個元素，則繼續向前查找，進入第一次遞歸循環

第六步：第二次遞歸循環

• 重複第五步，不同的是當前的bucket還是等於buckets的第一個元素，則直接跳轉至JumpMiss，此時是$0是normal，也是直接跳轉至__objc_msgSend_uncached，即進入慢速查找流程。
• 以下是整個快速查找過程流程

快速查找流程