计算机启动

按下主机上的 power 键后，第一个运行的软件是 BIOS,BIOS 全称叫 Base Input & Output System，即基本输入输出系统。

（8086的1MB内存）

地址 0～0x9FFFF 处是 DRAM，顶部的 0xF0000～0xFFFFF，这 64KB 的内存是 ROM。

BIOS 本身是个程序，程序要执行，就要有个入口地址才行，此入口地址便是 0xFFFF0。

BIOS 的主要工作是检测、初始化硬件，怎么初始化的？硬件自己提供了一些初始化的功能调用，BIOS 直接调用就好了。BIOS 还做了一件伟大的事情，建立了中断向量表，这样就可以通过“int 中断号”来实现相关的硬件调用，当然 BIOS 建立的这些功能就是对硬件的 IO 操作，这就是 BIOS 称为基本输入输出系统的原因。

（1）它是由谁加载的。
（2）它被加载到哪里。
（3）它的 cs：ip 是谁来更改的。

在开机的一瞬间，也就是接电的一瞬间，CPU 的 cs：ip 寄存器被强制初始化为 0xF000：0xFFF0。

既然此处只有 16 字节的空间了，这只能说明 BIOS 真正的代码不在这，那此处的代码只能是个跳转
指令jmp far f000：e05b，即跳向了 0xfe05b 处，这是 BIOS 代码真正开始的地方。

接下来 BIOS 便马不停蹄地检测内存、显卡等外设信息，当检测通过，并初始化好硬件后，开始在内
存中 0x000～0x3FF 处建立数据结构，中断向量表 IVT 并填写中断例程。

BIOS 最后一项工作校验启动盘中位于 0 盘 0 道 1 扇区的内容，此扇区末尾的两个字节分别是魔数 0x55 和 0xaa，BIOS 便认为此程序便是主引导记录 MBR，便加载到物理地址 0x7c00。

为什么是0x7c00

按 DOS 1.0 要求的最小内存 32KB 来说，MBR 希望给它尽可能多的预留空间，这样也是保全自己
的作法，免得过早被覆盖。所以 MBR 只能放在 32KB 的末尾。
MBR 本身也是程序，是程序就要用到栈，栈也是在内存中的，MBR 虽然本身只有 512 字节，但还要为其
所用的栈分配点空间，所以其实际所用的内存空间要大于 512 字节，估计 1KB 内存够用了。
结合以上三点，选择 32KB 中的最后 1KB 最为合适，
那此地址是多少呢？32KB 换算为十六进制为 0x8000，减去 1KB(0x400)的话，等于 0x7c00。这就是倍受质疑的 0x7c00 的由来，这下清楚了。可见，加载 MBR 的位置取决于操作系统本身所占内存大小和内存布局。

MBR 的大小必须是 512 字节,mbr在8086实模式中运行，这在微机原理中学得很详细，这里不再赘述。

实模式的“实”体现在：程序中用到的地址都是真实的物理地址，“段基址：段内偏移”产生的逻辑地址就是物理地址。8086之前是程序加载到固定位置，也就是程序员看到的完全是真实的内存。开发人员等不及了，干脆把程序中的地址改成别的吧，重新编译后发现还是有某个地址被占用，还是没法上 CPU 运行，怎么办？再改地址……

;mbr.S
;主引导程序 
;
;LOADER_BASE_ADDR equ 0xA000 
;LOADER_START_SECTOR equ 0x2
;------------------------------------------------------------
SECTION MBR vstart=0x7c00         
   mov ax,cs      
   mov ds,ax
   mov es,ax
   mov ss,ax
   mov fs,ax
   mov sp,0x7c00
   mov ax,0xb800
   mov gs,ax

; 清屏
;利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10   功能号:0x06	   功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
   mov     ax, 0600h
   mov     bx, 0700h
   mov     cx, 0               ; 左上角: (0, 0)
   mov     dx, 184fh	       ; 右下角: (80,25),
			       ; 因为VGA文本模式中，一行只能容纳80个字符,共25行。
			       ; 下标从0开始，所以0x18=24,0x4f=79
   int     10h                 ; int 10h

   ; 输出背景色绿色，前景色红色，并且跳动的字符串"1 MBR"
   mov byte [gs:0x00],'1'
   mov byte [gs:0x01],0xA4     ; A表示绿色背景闪烁，4表示前景色为红色

   mov byte [gs:0x02],' '
   mov byte [gs:0x03],0xA4

   mov byte [gs:0x04],'M'
   mov byte [gs:0x05],0xA4   

   mov byte [gs:0x06],'B'
   mov byte [gs:0x07],0xA4

   mov byte [gs:0x08],'R'
   mov byte [gs:0x09],0xA4

   jmp $		       ; 通过死循环使程序悬停在此

   times 510-($-$$) db 0
   db 0x55,0xaa

运行结果：

：学习笔记，整理操作系统真象还原