吃竹子的程序熊
吃竹子的程序熊

自定义groovy脚本在IDEA中为数据库生成PO实体类

自定义groovy脚本在IDEA中为数据库生成PO实体类

在文章底部有完整的代码实现

前言

我们可能会遇到下列这种问题:

公司的一个小项目,被拆分成了API和后台管理两个服务,但是因为二者共用一个数据库,所以存在着大量相同的数据库实体定义.

因此我们不得不在这两个服务中分别提供一样的实体定义,当我们的表结构发生变更时,我们可能会忘记修改某一个项目中对应的实体,久而久之,我们会发现,某个项目中的某个实体对象和数据库表定义相差甚远.

这时候,我们就可以考虑拆出一个common项目用来存放二者公共的代码,数据实体类作为一个不可变的对象,单独维护在common项目中,并保证common中的实体对象和数据库一一对应.

那么,我们需要手动的去为每个表建立相应的实体类吗?如果表结构发生变化,我们还要手动去更改相应的实体类吗?

答案当然是不,借助于IDEA的数据库插件Database,我们可以通过提供一个groovy脚本来批量生成数据表对应的实体类.

这样,不仅简化了代码编写,同时还能统一实体类的生成逻辑.

关于IDEA中脚本的使用方式参见文档:Generate Java entity classes for tables and views

IDEA中本身为提供了一个名为Generate POJOs.groovy的脚本,该脚本可以完成简单的代码生成工作,但是,在实际业务中,我们的实体类除了属性定义之外,往往还有一些其他的数据要定义在里面,比如:数据库描述相关的注解.

自定义脚本实现

这里,我提供了一个简单的自定义groovy脚本,通过该脚本,你可以完成包括自定义注解在内的代码生成工作.

基本属性定义

脚本的最开始,定义了几个开关用于控制脚本的行为,建议全部开启:

// ============= 常量区域 =================
useLogicDelete = true; /* 启用逻辑删除 */
useLombok = true;/*是否启用lombok*/
useSerializable = true;/*是否启用实体序列化*/

再定义两个Map集合,其中typeMapping负责将数据库类型转换为java类型,javaAliasMap则负责通过java类定义的简短名称获取其全限定名称:

/* 类型转换 ,负责将数据库类型转换为java类型,转换逻辑取自 mybatis */
typeMapping = [
        (~/(?i)real|decimal|numeric/)        : "BigDecimal",
        (~/(?i)bigint/)                      : "Long",
        (~/(?i)tinyint/)                     : "Byte", /* 根据自己的需求,可以考虑转换为Boolean*/
        (~/(?i)int/)                         : "Integer",
        (~/(?i)enum/)                        : "String", /* 枚举统一转换为字符串*/
        (~/(?i)float|double/)                : "Double", /* 根据自己的需求可以考虑其他类型*/
        (~/(?i)datetime|timestamp|date|time/): "Date",
        (~/(?i)/)                            : "String" /*其余的统一转成字符串*/
]


/* java 别名映射 ,负责导包*/
javaAliasMap = [
        "BigDecimal"  : "java.math.BigDecimal",
        "Date"        : "java.util.Date",
        "Getter"      : "lombok.Getter",
        "Setter"      : "lombok.Setter",
        "ToString"    : "lombok.ToString",
        "Serializable": "java.io.Serializable",
        "Table": "cn.jpanda.common.page.annotations.Table",
        "TableID": "cn.jpanda.common.page.annotations.TableID",
        "Column": "cn.jpanda.common.page.annotations.Column",
        "Logic": "cn.jpanda.common.page.annotations.Logic",
]

接着定义了三个生成实体类需要使用的属性,他们负责记录待生成实体类的部分关键信息:

// 代码生成路径,在脚本中通过弹出文件框进行选择,同时会转换为包名称
String packageName = ""
/* 待引入的java类*/
importClass = [];
/* 待使用的类注解 */
usesAnnotations = [];

属性比较简单,上面都有注释,这些属性都是在后面运行时被赋值的.

脚本执行入口

接下来就是脚本的真正入口:

/* 脚本入口 */
/* 选择文件目录 ,并执行生成代码操作 */
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}

该方法会弹出一个文件选择框,供用户选择一个用来存放生成代码的文件夹.

当用户完成选择文件夹后,用户选择的数据库表数据将会依次传入到generate()方法中,用来生成相应的实体对象.

为数据库表生成对应的实体类

通过一个table属性生成相应实体的逻辑比较简单,大概有七步:

def generate(table, dir) {
    // step1: 获取包名
    packageName = getPackageName(dir)
    // step2: 获取当前表名对应的类名称
    def className = javaName(table.getName(), true)
    // step3: 加载lombok注解
    if (useLombok) {
        ["Getter", "Setter", "ToString"].each() {
            convertAliasesAndImportClasses(it)
            usesAnnotations << it;
        };
    }
    // step4: 加载序列化
    if (useSerializable) {
        convertAliasesAndImportClasses("Serializable")
    }
    // step5: 加载自定义类注解
    loadCustomAnnotationToClass(table, className, dir);

    // step6: 处理所有数据列定义
    def properties = processDataColumnDefinition(table);

    // step7: 生成代码
    new File(dir as File, className + ".java").withPrintWriter("utf-8") {
        out ->
            generate(out, className, properties, table)
    }
}

1.根据用户选择的目录生成包名

 // step1: 获取包名
packageName = getPackageName(dir)

static def getPackageName(dir) {
return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

方法的实现并不复杂,默认通过src/main/java目录的子目录层级结构来生成包名称.

2.将表明转换为java类型名

 // step2: 获取当前表名对应的类名称
def className = javaName(table.getName(), true)

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

转换规则并不复杂:下划线转驼峰,首字母大写.

3.根据用户开关加载lombok注解

if (useLombok) {
    ["Getter", "Setter", "ToString"].each() {
        convertAliasesAndImportClasses(it)
        usesAnnotations << it;
    };
}

convertAliasesAndImportClasses()方法是一个负责完成导包配置的工具方法:

void convertAliasesAndImportClasses(className) {
    def entry = javaAliasMap.find { p, t -> p.equalsIgnoreCase(className) };
    if (entry == null) {
        return;
    }
    def fullName = entry.value
    if (isNotEmpty(fullName)) {
        doImportClass(fullName);
    }
}

这里只简单启用了最常见的三个lombok注解,可以根据自己的需求,调整所需的注解.

4.根据序列化开关选择是否启用序列化

// step4: 加载序列化
if (useSerializable) {
    convertAliasesAndImportClasses("Serializable")
}

5.[扩展点]加载自定义类注解

// step5: 加载自定义类注解
loadCustomAnnotationToClass(table, className, dir);

void loadCustomAnnotationToClass(table, className, dir) {
// 根据自己的需求实现,加载自定义的注解,比如JPA注解

}

loadCustomAnnotationToClass()方法定义在脚本底部,可以根据自己的需要来实现.

6.预处理所有数据列定义

// step6: 处理所有数据列定义
def properties = processDataColumnDefinition(table);

def processDataColumnDefinition(table) {
    // 加载当前数据库主键
    def primaryKey = ""
    def prKey = DasUtil.getPrimaryKey(table);
    if (prKey != null) {
        def keyRef = prKey.getColumnsRef();
        if (keyRef != null) {
            def it = keyRef.iterate();
            while (it.hasNext()) {
                // 默认只处理单主键
                primaryKey = it.next();
            }
            primaryKey = javaName(primaryKey, false);
        }
    }

    // 依次处理每一行数据列
    DasUtil.getColumns(table).reduce([]) { properties, col ->
        // 获取JDBC类型
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        // 将JDBC类型映射为JAVA类型
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        // 判断该类型是否需要导包
        convertAliasesAndImportClasses(typeStr);
        // 将列名称转换为字段名称
        def javaName = javaName(col.getName(), false);
        // 当前列是否为主键
        def isPrimaryKey = javaName.equals(primaryKey);
        // 是否为逻辑删除标记
        def isLogicDeleteFlag = isLogicDelete(javaName);

        def property = [
                name   : javaName,
                colName: col.getName(),
                type   : typeStr,
                comment: col.getComment(),
                isKey  : isPrimaryKey,
                isDel  : isLogicDeleteFlag,
                annos  : []
        ]
        loadCustomAnnotationsToProperty(property);
        properties << property;
    }
}

processDataColumnDefinition()方法看起来实现比较复杂,但是实际上只是负责将数据列定义解析为下列数据结构:

def property = [
        name   : javaName,  /* java属性名*/
        colName: col.getName(), /*jdbc列名*/
        type   : typeStr, /*java类型*/
        comment: col.getComment(),/*注释*/
        isKey  : isPrimaryKey, /*是否为数据表主键*/
        isDel  : isLogicDeleteFlag, /*是否是逻辑删除标志*/
        annos  : [] /*需要添加的属性注解*/
]

property有一个annos属性,他的值是通过loadCustomAnnotationsToProperty()获取的,这是另一个扩展点,用于加载自定义属性注解,比如,我的简单实现是:

void loadCustomAnnotationsToProperty(property) {
    // 根据自己的需求实现,加载自定义属性注解,比如这里,我使用了自定义的注解
    if (property.isDel) {
        convertAliasesAndImportClasses("Logic");
        property.annos << "Logic";
    }
    if (property.isKey) {
        convertAliasesAndImportClasses("TableID");
        property.annos << "TableID";
    }
    convertAliasesAndImportClasses("Column");
    property.annos << "Column";
}

7.生成代码

// step7: 生成代码
new File(dir as File, className + ".java").withPrintWriter("utf-8") {
    out ->
        generate(out, className, properties, table)
}

这一步是使用上面的数据来生成真正的代码,实现很长,但是基本上都是用来处理前面获取到的数据的:

// 生成实体类代码
def generate(out, className, properties, table) {
    // step 1: 输出包名
    out.println "package $packageName"
    out.println ""
    out.println ""
    // step2: 导入类
    importClass.each() {
        out.println "import ${it};"
    }
    out.println ""

    // 补充:生成注释
    generateClassComments(out, table)

    // step3: 生成类注解
    usesAnnotations.each() {
        out.println "@${it}"
    }
    // step4: 生成类名
    out.print "public class $className"
    if (useSerializable) {
        out.println(" implements Serializable {")
        out.println ""
        /* 生成序列化ID*/
        out.println genSerialID()
    } else {
        out.println "{"
    }
    out.println ""
    // step5: 处理每个属性定义
    properties.each() {
        // step5.1: 输出注释
        if (isNotEmpty(it.comment)) {
            out.println "\t/**"
            out.println "\t * ${it.comment}"
            out.println "\t */"
        }
        //step5.2: 输出注解
        it.annos.each() {
            out.println "\t@${it}"
        }
        /*step5.3: 输入字段内容*/
        out.println "\tprivate ${it.type} ${it.name};"
    }

    // step6: 生成getter/setter方法
    if (!useLombok) {
        // 在未启用lombok的情况下生成getter/setter方法
        properties.each() {
            out.println ""
            out.println "  public ${it.type} get${it.name.capitalize()}() {"
            out.println "    return ${it.name};"
            out.println "  }"
            out.println ""
            out.println "  public void set${it.name.capitalize()}(${it.type} ${it.name}) {"
            out.println "    this.${it.name} = ${it.name};"
            out.println "  }"
            out.println ""
        }
    }

    // step7: 结尾
    out.println "}"
}

generate()方法中,值得留意的是:

// 补充:生成注释
generateClassComments(out, table)

这是方法的第三个扩展点,用于加载自定义类注释,我的简单实现是:

void generateClassComments(out, table) {
    /* 生成类注释 */
    ["/**",
     " * ",
     " * ${table.getComment()}",
     " * @author Jpanda [[email protected]]",
     " * @version 1.0",
     " * @since " + new SimpleDateFormat("yyyy-MM-dd").format(new Date()),
     " */"
    ].each() {
        out.println "${it}"
    }
}

上面就是脚本的基本思路了,脚本比较简单,上面也有详细的注释,基本可以满足使用.

使用脚本

下面是一个简单的代码生成示例.

涉及到的表结构:

create table user
(
    id         int auto_increment primary key,
    iphone     varchar(50)  not null comment '手机号',
    password   varchar(50)  not null comment '密码',
    nikename   varchar(100) null comment '名字',
    group_flag int(1)       null comment '组标识 0 店长 1 组长 2管理员'
)
    comment '用户';

首先,我们把自定脚本放入IDEA的脚本执行目录下:

脚本执行目录

然后通过Database插件调用脚本:

使用脚本

选择目录:

选择目录

生成代码:

package cn.jpanda.common.pojos.test;


import lombok.Getter;
import lombok.Setter;
import lombok.ToString;
import java.io.Serializable;
import cn.jpanda.common.page.annotations.TableID;
import cn.jpanda.common.page.annotations.Column;

/**
 * 
 * 用户
 * @author Jpanda [[email protected]]
 * @version 1.0
 * @since 2020-04-22
 */
@Getter
@Setter
@ToString
public class User implements Serializable {

 private static final long serialVersionUID =  2598051958746997471L;

 @TableID
 @Column
 private Integer id;
 /**
  * 手机号
  */
 @Column
 private String iphone;
 /**
  * 密码
  */
 @Column
 private String password;
 /**
  * 名字
  */
 @Column
 private String nikename;
 /**
  * 组标识 0 店长 1 组长 2管理员
  */
 @Column
 private Integer groupFlag;
}

完整代码

下面给出完整的脚本代码,需要根据自己的需求,调节自定义注解相关的数据:

import com.intellij.database.model.DasTable
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.text.SimpleDateFormat

/*
 * Available context bindings:
 *   SELECTION   Iterable
 *   PROJECT     project
 *   FILES       files helper
 */

// ============= 常量区域 =================
useLogicDelete = true; /* 启用逻辑删除 */
useLombok = true;/*是否启用lombok*/
useSerializable = true;/*是否启用实体序列化*/

/* 类型转换 ,负责将数据库类型转换为java类型,转换逻辑取自 mybatis */
typeMapping = [
        (~/(?i)real|decimal|numeric/)        : "BigDecimal",
        (~/(?i)bigint/)                      : "Long",
        (~/(?i)tinyint/)                     : "Byte", /* 根据自己的需求,可以考虑转换为Boolean*/
        (~/(?i)int/)                         : "Integer",
        (~/(?i)enum/)                        : "String", /* 枚举统一转换为字符串*/
        (~/(?i)float|double/)                : "Double", /* 根据自己的需求可以考虑其他类型*/
        (~/(?i)datetime|timestamp|date|time/): "Date",
        (~/(?i)/)                            : "String" /*其余的统一转成字符串*/
]


/* java 别名映射 ,负责导包*/
javaAliasMap = [
        "BigDecimal"  : "java.math.BigDecimal",
        "Date"        : "java.util.Date",
        "Getter"      : "lombok.Getter",
        "Setter"      : "lombok.Setter",
        "ToString"    : "lombok.ToString",
        "Serializable": "java.io.Serializable",
        "Table"       : "cn.jpanda.common.page.annotations.Table",
        "TableID"     : "cn.jpanda.common.page.annotations.TableID",
        "Column"      : "cn.jpanda.common.page.annotations.Column",
        "Logic"       : "cn.jpanda.common.page.annotations.Logic",
]


/* =========  运行时属性定义 ============*/
// 代码生成路径,在脚本中通过弹出文件框进行选择
String packageName = ""
/* 待引入的java类*/
importClass = [];
/* 待使用注解 */
usesAnnotations = [];


/* 脚本入口 */
/* 选择文件目录 ,并执行生成代码操作 */
FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable }.each { generate(it, dir) }
}


def generate(table, dir) {
    // step1: 获取包名
    packageName = getPackageName(dir)
    // step2: 获取当前表名对应的类名称
    def className = javaName(table.getName(), true)
    // step3: 加载lombok注解
    if (useLombok) {
        ["Getter", "Setter", "ToString"].each() {
            convertAliasesAndImportClasses(it)
            usesAnnotations << it;
        };
    }
    // step4: 加载序列化
    if (useSerializable) {
        convertAliasesAndImportClasses("Serializable")
    }
    // step5: 加载自定义类注解
    loadCustomAnnotationToClass(table, className, dir);

    // step6: 处理所有数据列定义
    def properties = processDataColumnDefinition(table);

    // step7: 生成代码
    new File(dir as File, className + ".java").withPrintWriter("utf-8") {
        out ->
            generate(out, className, properties, table)
    }
}


// 生成实体类代码
def generate(out, className, properties, table) {
    // step 1: 输出包名
    out.println "package $packageName"
    out.println ""
    out.println ""
    // step2: 导入类
    importClass.each() {
        out.println "import ${it};"
    }
    out.println ""

    // 补充:生成注释
    generateClassComments(out, table)

    // step3: 生成类注解
    usesAnnotations.each() {
        out.println "@${it}"
    }
    // step4: 生成类名
    out.print "public class $className"
    if (useSerializable) {
        out.println(" implements Serializable {")
        out.println ""
        /* 生成序列化ID*/
        out.println genSerialID()
    } else {
        out.println "{"
    }
    out.println ""
    // step5: 处理每个属性定义
    properties.each() {
        // step5.1: 输出注释
        if (isNotEmpty(it.comment)) {
            out.println "\t/**"
            out.println "\t * ${it.comment}"
            out.println "\t */"
        }
        //step5.2: 输出注解
        it.annos.each() {
            out.println "\t@${it}"
        }
        /*step5.3: 输入字段内容*/
        out.println "\tprivate ${it.type} ${it.name};"
    }

    // step6: 生成getter/setter方法
    if (!useLombok) {
        // 在未启用lombok的情况下生成getter/setter方法
        properties.each() {
            out.println ""
            out.println "  public ${it.type} get${it.name.capitalize()}() {"
            out.println "    return ${it.name};"
            out.println "  }"
            out.println ""
            out.println "  public void set${it.name.capitalize()}(${it.type} ${it.name}) {"
            out.println "    this.${it.name} = ${it.name};"
            out.println "  }"
            out.println ""
        }
    }

    // step7: 结尾
    out.println "}"
}

def processDataColumnDefinition(table) {
    // 加载当前数据库主键
    def primaryKey = ""
    def prKey = DasUtil.getPrimaryKey(table);
    if (prKey != null) {
        def keyRef = prKey.getColumnsRef();
        if (keyRef != null) {
            def it = keyRef.iterate();
            while (it.hasNext()) {
                // 默认只处理单主键
                primaryKey = it.next();
            }
            primaryKey = javaName(primaryKey, false);
        }
    }

    // 依次处理每一行数据列
    DasUtil.getColumns(table).reduce([]) { properties, col ->
        // 获取JDBC类型
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())
        // 将JDBC类型映射为JAVA类型
        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        // 判断该类型是否需要导包
        convertAliasesAndImportClasses(typeStr);
        // 将列名称转换为字段名称
        def javaName = javaName(col.getName(), false);
        // 当前列是否为主键
        def isPrimaryKey = javaName.equals(primaryKey);
        // 是否为逻辑删除标记
        def isLogicDeleteFlag = isLogicDelete(javaName);

        def property = [
                name   : javaName,  /* java属性名*/
                colName: col.getName(), /*jdbc列名*/
                type   : typeStr, /*java类型*/
                comment: col.getComment(),/*注释*/
                isKey  : isPrimaryKey, /*是否为数据表主键*/
                isDel  : isLogicDeleteFlag, /*是否是逻辑删除标志*/
                annos  : [] /*需要添加的属性注解*/
        ]
        loadCustomAnnotationsToProperty(property);
        properties << property;
    }
}

def javaName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

static def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

static String genSerialID() {
    return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;"
}
// 生成包名
static def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

/**
 * 判断一个java属性是否为逻辑删除
 * [根据自己的需求重构该测试]
 * @param property 属性名称
 * @return
 */
boolean isLogicDelete(property) {
    return useLogicDelete && property.equalsIgnoreCase("DeleteFlag") || property.equalsIgnoreCase("DelFlag")
}

/**
 * 导入lombok的类
 */
void importLombokPackage() {
    if (useLombok) {
        ["lombok.Getter", "lombok.Setter", "lombok.ToString"].each() {
            doImportClass(it);
        };
    }
}

/**
 * 导入一个包名称
 * @param className
 */
void doImportClass(className) {
    if (importClass.count { it -> it.equalsIgnoreCase(className) } == 0) {
        importClass << className;
    }
}

void convertAliasesAndImportClasses(className) {
    def entry = javaAliasMap.find { p, t -> p.equalsIgnoreCase(className) };
    if (entry == null) {
        return;
    }
    def fullName = entry.value
    if (isNotEmpty(fullName)) {
        doImportClass(fullName);
    }
}

void loadCustomAnnotationToClass(table, className, dir) {
    // 根据自己的需求实现,加载自定义的注解,比如JPA注解

}

void loadCustomAnnotationsToProperty(property) {
    // 根据自己的需求实现,加载自定义属性注解,比如这里,我使用了自定义的注解
    if (property.isDel) {
        convertAliasesAndImportClasses("Logic");
        property.annos << "Logic";
    }
    if (property.isKey) {
        convertAliasesAndImportClasses("TableID");
        property.annos << "TableID";
    }
    convertAliasesAndImportClasses("Column");
    property.annos << "Column";
}

void generateClassComments(out, table) {
    /* 生成类注释 */
    ["/**",
     " * ",
     " * ${table.getComment()}",
     " * @author Jpanda [[email protected]]",
     " * @version 1.0",
     " * @since " + new SimpleDateFormat("yyyy-MM-dd").format(new Date()),
     " */"
    ].each() {
        out.println "${it}"
    }
}

你可能感兴趣的:(自定义groovy脚本在IDEA中为数据库生成PO实体类)

  • 斤斤计较的婚姻到底有多难？ 白心之岂必有为
    很多人私聊我会问到在哪个人群当中斤斤计较的人最多？我都会回答他，一般婚姻出现问题的斤斤计较的人士会非常多，以我多年经验，在婚姻落的一塌糊涂的人当中，斤斤计较的人数占比在20～30%以上，也就是说10个婚姻出现问题的斤斤计较的人有2-3个有多不减。在婚姻出问题当中，有大量的心理不平衡的、尖酸刻薄的怨妇。在婚姻中仅斤斤计较有两种类型：第一种是物质上的，另一种是精神上的。在物质与精神上抠门已经严重的影响
  • 芦花鞋一四 许叶晗
    又是在一个寒冷的夏日里，青铜和葵花决定今天一起去卖芦花鞋，奶奶亲手给他们做了一碗热乎乎的粥对他们说:“就靠你们两挣生活费了这碗粥赶紧趁热喝了吧！”于是青铜和葵花喝完了奶奶给她们做的粥，就准备去镇上卖卢花鞋，这回青铜和葵花穿着新的芦花鞋来到了镇上。青铜这回看到了很多人都在卖，用手势表达对葵花说:“这回有好多人在抢我们生意呢！我们必须得吆喝起来。”葵花点了点头。可是谁知他们也大声的叫，卖芦花喽！卖芦花
  • android系统selinux中添加新属性property 辉色投像
    1.定位/android/system/sepolicy/private/property_contexts声明属性开头：persist.charge声明属性类型：u:object_r:system_prop:s0图12.定位到android/system/sepolicy/public/domain.te删除neverallow{domain-init}default_prop:property
  • 2020-01-25 晴岚85
    郑海燕坚持分享590天2020.1.24在生活中只存在两个问题。一个问题是：你知道想要达成的目标是什么，但却不知道如何才能达成；另一个问题是：你不知道你的目标是什么。前一个是行动的问题，后一个是结果的问题。通过制定具体的下一步行动，可以解决不知道如何开始行动的问题。而通过去想象结果，对结果做预估，可以解决找不着目标的问题。对于所有吸引我们注意力，想要完成的任务，你可以先想象一下，预期的结果究竟是什
  • 随笔 | 仙一般的灵气 海思沧海
    仙岛今天，我看了你全部，似乎已经进入你的世界我不知道，这是否是梦幻，还是你仙一般的灵气吸引了我也许每一个人都要有一份属于自己的追求，这样才能够符合人生的梦想，生活才能够充满着阳光与快乐我不知道，我为什么会这样的感叹，是在感叹自己的人生，还是感叹自己一直没有孜孜不倦的追求只感觉虚度了光阴，每天活在自己的梦中，活在一个不真实的世界是在逃避自己，还是在逃避周围的一切有时候我嘲笑自己，嘲笑自己如此的虚无，
  • OC语言多界面传值五大方式 Magnetic_h iosui学习objective-c开发语言
    前言在完成暑假仿写项目时，遇到了许多需要用到多界面传值的地方，这篇博客来总结一下比较常用的五种多界面传值的方式。属性传值属性传值一般用前一个界面向后一个界面传值，简单地说就是通过访问后一个视图控制器的属性来为它赋值，通过这个属性来做到从前一个界面向后一个界面传值。首先在后一个界面中定义属性@interfaceBViewController:UIViewController@propertyNSSt
  • UI学习——cell的复用和自定义cell Magnetic_h ui学习
    目录cell的复用手动（非注册）自动（注册）自定义cellcell的复用在iOS开发中，单元格复用是一种提高表格（UITableView）和集合视图（UICollectionView）滚动性能的技术。当一个UITableViewCell或UICollectionViewCell首次需要显示时，如果没有可复用的单元格，则视图会创建一个新的单元格。一旦这个单元格滚动出屏幕，它就不会被销毁。相反，它被添
  • element实现动态路由+面包屑 软件技术NINI vue案例vue.js前端
    el-breadcrumb是ElementUI组件库中的一个面包屑导航组件，它用于显示当前页面的路径，帮助用户快速理解和导航到应用的各个部分。在Vue.js项目中，如果你已经安装了ElementUI，就可以很方便地使用el-breadcrumb组件。以下是一个基本的使用示例：安装ElementUI（如果你还没有安装的话）:你可以通过npm或yarn来安装ElementUI。bash复制代码npmi
  • C语言宏函数 南林yan C语言c语言
    一、什么是宏函数？通过宏定义的函数是宏函数。如下，编译器在预处理阶段会将Add(x,y)替换为((x)*(y))#defineAdd(x,y)((x)*(y))#defineAdd(x,y)((x)*(y))intmain(){inta=10;intb=20;intd=10;intc=Add(a+d,b)*2;cout<
  • 地推话术，如何应对地推过程中家长的拒绝 校师学
    相信校长们在做地推的时候经常遇到这种情况：市场专员反馈家长不接单，咨询师反馈难以邀约这些家长上门，校区地推疲软，招生难。为什么？仅从地推层面分析，一方面因为家长受到的信息轰炸越来越多，对信息越来越“免疫”；而另一方面地推人员的专业能力和营销话术没有提高，无法应对家长的拒绝，对有意向的家长也不知如何跟进，眼睁睁看着家长走远；对于家长的疑问，更不知道如何有技巧地回答，机会白白流失。由于回答没技巧和专业
  • C语言如何定义宏函数？ 小九格物 c语言
    在C语言中，宏函数是通过预处理器定义的，它在编译之前替换代码中的宏调用。宏函数可以模拟函数的行为，但它们不是真正的函数，因为它们在编译时不会进行类型检查，也不会分配存储空间。宏函数的定义通常使用#define指令，后面跟着宏的名称和参数列表，以及宏展开后的代码。宏函数的定义方式：1.基本宏函数：这是最简单的宏函数形式，它直接定义一个表达式。#defineSQUARE(x)((x)*(x))2.带参
  • 微服务下功能权限与数据权限的设计与实现 nbsaas-boot 微服务java架构
    在微服务架构下，系统的功能权限和数据权限控制显得尤为重要。随着系统规模的扩大和微服务数量的增加，如何保证不同用户和服务之间的访问权限准确、细粒度地控制，成为设计安全策略的关键。本文将讨论如何在微服务体系中设计和实现功能权限与数据权限控制。1.功能权限与数据权限的定义功能权限：指用户或系统角色对特定功能的访问权限。通常是某个用户角色能否执行某个操作，比如查看订单、创建订单、修改用户资料等。数据权限：
  • 理解Gunicorn：Python WSGI服务器的基石 范范0825 ipythonlinux运维
    理解Gunicorn：PythonWSGI服务器的基石介绍Gunicorn，全称GreenUnicorn，是一个为PythonWSGI（WebServerGatewayInterface）应用设计的高效、轻量级HTTP服务器。作为PythonWeb应用部署的常用工具，Gunicorn以其高性能和易用性著称。本文将介绍Gunicorn的基本概念、安装和配置，帮助初学者快速上手。1.什么是Gunico
  • 小丽成长记（四十三） 玲玲54321
    小丽发现，即使她好不容易调整好自己的心态下一秒总会有不确定的伤脑筋的事出现，一个接一个的问题，人生就没有停下的时候，小问题不断出现。不过她今天看的书，她接受了人生就是不确定的，厉害的人就是不断创造确定性，在Ta的领域比别人多的确定性就能让自己脱颖而出，显示价值从而获得的比别人多的利益。正是这样的原因，因为从前修炼自己太少，使得她现在在人生道路上打怪起来困难重重，她似乎永远摆脱不了那种无力感，有种习
  • 2021年12月19日，春蕾教育集团团建活动感受——黄晓丹 黄错错加油
    感受:1.从陌生到熟悉的过程。游戏环节让我们在轻松的氛围中得到了锻炼，也增长了不少知识。2.游戏过程中，我们贡献的是个人力量，展现的是团队的力量。它磨合的往往不止是工作的熟悉，更是观念上契合度的贴近。3.这和工作是一样的道理。在各自的岗位上，每个人摆正自己的位置、各司其职充分发挥才能，并团结一致劲往一处使，才能实现最大的成功。新知:1.团队精神需要不断地创新。过去，人们把创新看作是冒风险，现在人们
  • c++ 的iostream 和 c++的stdio的区别和联系 黄卷青灯77 c++算法开发语言iostreamstdio
    在C++中，iostream和C语言的stdio.h都是用于处理输入输出的库，但它们在设计、用法和功能上有许多不同。以下是两者的区别和联系：区别1.编程风格iostream（C++风格）：C++标准库中的输入输出流类库，支持面向对象的输入输出操作。典型用法是cin（输入）和cout（输出），使用>操作符来处理数据。更加类型安全，支持用户自定义类型的输入输出。#includeintmain(){in
  • 爬山后遗症 璃绛
    爬山，攀登，一步一步走向制高点，是一种挑战。成功抵达是一种无法言语的快乐，在山顶吹吹风，看看风景，这是从未有过的体验。然而，爬山一时爽，下山腿打颤，颠簸的路，一路向下走，腿部力量不够，走起来抖到不行，停不下来了！第二天必定腿疼，浑身酸痛，坐立难安！
  • 《投行人生》读书笔记 小蘑菇的树洞
    《投行人生》----作者詹姆斯-A-朗德摩根斯坦利副主席40年的职业洞见-很短小精悍的篇幅，比较适合初入职场的新人。第一部分成功的职业生涯需要规划1.情商归为适应能力分享与协作同理心适应能力，更多的是自我意识，你有能力识别自己的情并分辨这些情绪如何影响你的思想和行为。2.对于初入职场的人的建议，细节，截止日期和数据很重要截止日期，一种有效的方法是请老板为你所有的任务进行优先级排序。和老板喝咖啡的好
  • Long类型前后端数据不一致 igotyback 前端
    响应给前端的数据浏览器控制台中response中看到的Long类型的数据是正常的到前端数据不一致前后端数据类型不匹配是一个常见问题，尤其是当后端使用Java的Long类型（64位）与前端JavaScript的Number类型（最大安全整数为2^53-1，即16位）进行数据交互时，很容易出现精度丢失的问题。这是因为JavaScript中的Number类型无法安全地表示超过16位的整数。为了解决这个问
  • LocalDateTime 转 String igotyback java开发语言
    importjava.time.LocalDateTime;importjava.time.format.DateTimeFormatter;publicclassMain{publicstaticvoidmain(String[]args){//获取当前时间LocalDateTimenow=LocalDateTime.now();//定义日期格式化器DateTimeFormatterformat
  • swagger访问路径 igotyback swagger
    Swagger2.x版本访问地址：http://{ip}:{port}/{context-path}/swagger-ui.html{ip}是你的服务器IP地址。{port}是你的应用服务端口，通常为8080。{context-path}是你的应用上下文路径，如果应用部署在根路径下，则为空。Swagger3.x版本对于Swagger3.x版本（也称为OpenAPI3）访问地址：http://{ip
  • 如何在 Fork 的 GitHub 项目中保留自己的修改并同步上游更新？github_fork_update iBaoxing github
    如何在Fork的GitHub项目中保留自己的修改并同步上游更新？在GitHub上Fork了一个项目后，你可能会对项目进行一些修改，同时原作者也在不断更新。如果想要在保留自己修改的基础上，同步原作者的最新更新，很多人会不知所措。本文将详细讲解如何在不丢失自己改动的情况下，将上游仓库的更新合并到自己的仓库中。问题描述假设你在GitHub上Fork了一个项目，并基于该项目做了一些修改，随后你发现原作者对
  • Linux下QT开发的动态库界面弹出操作（SDL2） 13jjyao QT类qt开发语言sdl2linux
    需求：操作系统为linux，开发框架为qt，做成需带界面的qt动态库，调用方为java等非qt程序难点：调用方为java等非qt程序，也就是说调用方肯定不带QApplication::exec()，缺少了这个，QTimer等事件和QT创建的窗口将不能弹出(包括opencv也是不能弹出)；这与qt调用本身qt库是有本质的区别的思路：1.调用方缺QApplication::exec()，那么我们在接口
  • 绘本讲师训练营【24期】8/21阅读原创《独生小孩》 1784e22615e0
    24016-孟娟《独生小孩》图片发自App今天我想分享一个蛮特别的绘本，讲的是一个特殊的群体，我也是属于这个群体，80后的独生小孩。这是一本中国绘本，作者郭婧，也是一个80厚。全书一百多页，均为铅笔绘制，虽然为黑白色调，但并不显得沉闷。全书没有文字，犹如“默片”，但并不影响读者对该作品的理解，反而显得神秘，梦幻，給读者留下想象的空间。作者在前蝴蝶页这样写到：“我更希望父母和孩子一起分享这本书，使他
  • 30天风格练习-DAY2 黄希夷
    Day2（重义）在一个周日/一周的最后一天，我来到位于市中心/市区繁华地带的一家购物中心/商场，中心内人很多/熙熙攘攘。我注意到/看见一个独行/孤身一人的年轻女孩/，留着一头引人注目/长过腰际的头发，上身穿一件暗红色/比正红色更深的衣服/穿在身体上的东西。走下扶梯的时候，她摔倒了/跌向地面，在她正要站起来/让身体离开地面的时候，过长/超过一般人长度的头发被支撑身体/躯干的手掌压/按在下面，她赶紧用
  • 店群合一模式下的社区团购新发展——结合链动 2+1 模式、AI 智能名片与 S2B2C 商城小程序源码 说私域 人工智能小程序
    摘要：本文探讨了店群合一的社区团购平台在当今商业环境中的重要性和优势。通过分析店群合一模式如何将互联网社群与线下终端紧密结合，阐述了链动2+1模式、AI智能名片和S2B2C商城小程序源码在这一模式中的应用价值。这些创新元素的结合为社区团购带来了新的机遇，提升了用户信任感、拓展了营销渠道，并实现了线上线下的完美融合。一、引言随着互联网技术的不断发展，社区团购作为一种新兴的商业模式，在满足消费者日常需
  • 我校举行新老教师师徒结对仪式暨名师专业工作室工作交流活动 李蕾1229
    为促进我校教师专业发展，发挥骨干教师的引领带头作用，11月6日下午，我校举行新老教师师徒结对仪式暨名师专业工作室工作交流活动。图片发自App会议由教师发展处李蕾主任主持，首先，由范校长宣读新老教师结对名单及双方承担职责。随后，两位新调入教师陈玉萍、莫正杰分别和他们的师傅鲍元美、刘召彬老师签订了师徒结对协议书。图片发自App图片发自App师徒拥抱、握手。有了师傅就有了目标有了方向，相信两位新教师在师
  • 2021-08-26 影幽
    在生活中，女人与男人的感悟往往有所不同。人生最大的舞台就是生活，大幕随时都可能拉开，关键是你愿不愿意表演都无法躲避。在生活中，遇事不要急躁，不要急于下结论，尤其生气时不要做决断，要学会换位思考，大事化小小事化了，把复杂的事情尽量简单处理，千万不要把简单的事情复杂化。永远不要扭曲，别人善意，无药可救。昨天是张过期的支票，明天是张信用卡，只有今天才是现金，要善加利用！执着的攀登者不必去与别人比较自己的
  • 消息中间件有哪些常见类型 xmh-sxh-1314 java
    消息中间件根据其设计理念和用途，可以大致分为以下几种常见类型：点对点消息队列（Point-to-PointMessagingQueues）：在这种模型中，消息被发送到特定的队列中，消费者从队列中取出并处理消息。队列中的消息只能被一个消费者消费，消费后即被删除。常见的实现包括IBM的MQSeries、RabbitMQ的部分使用场景等。适用于任务分发、负载均衡等场景。发布/订阅消息模型（Pub/Sub
  • html 中如何使用 uniapp 的部分方法 某公司摸鱼前端 htmluni-app前端
    示例代码：Documentconsole.log(window);效果展示：好了，现在就可以uni.使用相关的方法了
  • github中多个平台共存 jackyrong github
    在个人电脑上，如何分别链接比如oschina,github等库呢，一般教程之列的，默认 ssh链接一个托管的而已，下面讲解如何放两个文件 1） 设置用户名和邮件地址 $ git config --global user.name "xx" $ git config --global user.email "[email protected]"
  • ip地址与整数的相互转换(javascript) alxw4616 JavaScript
    //IP转成整型 function ip2int(ip){ var num = 0; ip = ip.split("."); num = Number(ip[0]) * 256 * 256 * 256 + Number(ip[1]) * 256 * 256 + Number(ip[2]) * 256 + Number(ip[3]); n
  • 读书笔记-jquey+数据库+css chengxuyuancsdn htmljqueryoracle
    1、grouping ,group by rollup, GROUP BY GROUPING SETS区别 2、$("#totalTable tbody>tr td:nth-child(" + i + ")").css({"width":tdWidth, "margin":"0px", &q
  • javaSE javaEE javaME == API下载 Array_06 java
    oracle下载各种API文档： http://www.oracle.com/technetwork/java/embedded/javame/embed-me/documentation/javame-embedded-apis-2181154.html JavaSE文档： http://docs.oracle.com/javase/8/docs/api/ JavaEE文档： ht
  • shiro入门学习 cugfy javaWeb框架
    声明本文只适合初学者，本人也是刚接触而已，经过一段时间的研究小有收获，特来分享下希望和大家互相交流学习。 首先配置我们的web.xml代码如下，固定格式，记死就成 <filter>         <filter-name>shiroFilter</filter-name> &nbs
  • Array添加删除方法 357029540 js
         刚才做项目前台删除数组的固定下标值时，删除得不是很完整，所以在网上查了下，发现一个不错的方法，也提供给需要的同学。 //给数组添加删除             Array.prototype.del = function(n){
  • navigation bar 更改颜色 张亚雄 IO
    今天郁闷了一下午，就因为objective-c默认语言是英文，我写的中文全是一些乱七八糟的样子，到不是乱码，但是，前两个自字是粗体，后两个字正常体，这可郁闷死我了，问了问大牛，人家告诉我说更改一下字体就好啦，比如改成黑体，哇塞，茅塞顿开。       翻书看，发现，书上有介绍怎么更改表格中文字字体的，代码如下    
  • unicode转换成中文 adminjun unicode编码转换
      在Java程序中总会出现\u6b22\u8fce\u63d0\u4ea4\u5fae\u535a\u641c\u7d22\u4f7f\u7528\u53cd\u9988\uff0c\u8bf7\u76f4\u63a5这个的字符，这是unicode编码，使用时有时候不会自动转换成中文就需要自己转换了使用下面的方法转换一下即可。 /** * unicode 转换成 中文
  • 一站式 Java Web 框架 firefly aijuans Java Web
    Firefly是一个高性能一站式Web框架。 涵盖了web开发的主要技术栈。 包含Template engine、IOC、MVC framework、HTTP Server、Common tools、Log、Json parser等模块。 firefly-2.0_07修复了模版压缩对javascript单行注释的影响，并新增了自定义错误页面功能。 更新日志： 增加自定义系统错误页面功能
  • 设计模式——单例模式 ayaoxinchao 设计模式
    定义          Java中单例模式定义：“一个类有且仅有一个实例，并且自行实例化向整个系统提供。”   分析          从定义中可以看出单例的要点有三个：一是某个类只能有一个实例；二是必须自行创建这个实例；三是必须自行向系统提供这个实例。   &nb
  • Javascript 多浏览器兼容性问题及解决方案 BigBird2012 JavaScript
    不论是网站应用还是学习js,大家很注重ie与firefox等浏览器的兼容性问题，毕竟这两中浏览器是占了绝大多数。 一、document.formName.item(”itemName”) 问题 问题说明：IE下，可以使用 document.formName.item(”itemName”) 或 document.formName.elements ["elementName&quo
  • JUnit-4.11使用报java.lang.NoClassDefFoundError: org/hamcrest/SelfDescribing错误 bijian1013 junit4.11单元测试
            下载了最新的JUnit版本，是4.11，结果尝试使用发现总是报java.lang.NoClassDefFoundError: org/hamcrest/SelfDescribing这样的错误，上网查了一下，一般的解决方案是，换一个低一点的版本就好了。还有人说，是缺少hamcrest的包。去官网看了一下，如下发现：    
  • [Zookeeper学习笔记之二]Zookeeper部署脚本 bit1129 zookeeper
    Zookeeper伪分布式安装脚本(此脚本在一台机器上创建Zookeeper三个进程，即创建具有三个节点的Zookeeper集群。这个脚本和zookeeper的tar包放在同一个目录下，脚本中指定的名字是zookeeper的3.4.6版本，需要根据实际情况修改)：   #!/bin/bash #!!!Change the name!!! #The zookeepe
  • 【Spark八十】Spark RDD API二 bit1129 spark
    coGroup package spark.examples.rddapi import org.apache.spark.{SparkConf, SparkContext} import org.apache.spark.SparkContext._ object CoGroupTest_05 { def main(args: Array[String]) { v
  • Linux中编译apache服务器modules文件夹缺少模块(.so)的问题 ronin47 modules
    在modules目录中只有httpd.exp，那些so文件呢？ 我尝试在fedora core 3中安装apache 2. 当我解压了apache 2.0.54后使用configure工具并且加入了 --enable-so 或者 --enable-modules=so (两个我都试过了) 去make并且make install了。我希望在/apache2/modules/目录里有各种模块，
  • Java基础-克隆 BrokenDreams java基础
            Java中怎么拷贝一个对象呢？可以通过调用这个对象类型的构造器构造一个新对象，然后将要拷贝对象的属性设置到新对象里面。Java中也有另一种不通过构造器来拷贝对象的方式，这种方式称为 克隆。         Java提供了java.lang.
  • 读《研磨设计模式》-代码笔记-适配器模式-Adapter bylijinnan java设计模式
    声明： 本文只为方便我个人查阅和理解，详细的分析以及源代码请移步 原作者的博客http://chjavach.iteye.com/ package design.pattern; /* * 适配器模式解决的主要问题是，现有的方法接口与客户要求的方法接口不一致 * 可以这样想，我们要写这样一个类（Adapter）: * 1.这个类要符合客户的要求 ---> 那显然要
  • HDR图像PS教程集锦&心得 cherishLC PS
    HDR是指高动态范围的图像，主要原理为提高图像的局部对比度。 软件有photomatix和nik hdr efex。 一、教程 叶明在知乎上的回答： http://www.zhihu.com/question/27418267/answer/37317792 大意是修完后直方图最好是等值直方图，方法是HDR软件调一遍，再结合不透明度和蒙版细调。 二、心得 1、去除阴影部分的
  • maven-3.3.3 mvn archetype 列表 crabdave ArcheType
    maven-3.3.3 mvn archetype 列表 可以参考最新的：http://repo1.maven.org/maven2/archetype-catalog.xml   [INFO] Scanning for projects... [INFO]                
  • linux shell 中文件编码查看及转换方法 daizj shell中文乱码vim文件编码
    一、查看文件编码。     在打开文件的时候输入:set fileencoding     即可显示文件编码格式。 二、文件编码转换     1、在Vim中直接进行转换文件编码,比如将一个文件转换成utf-8格式       &
  • MySQL--binlog日志恢复数据 dcj3sjt126com binlog
    恢复数据的重要命令如下 mysql> flush logs; 默认的日志是mysql-bin.000001，现在刷新了重新开启一个就多了一个mysql-bin.000002                  
  • 数据库中数据表数据迁移方法 dcj3sjt126com sql
    刚开始想想好像挺麻烦的，后来找到一种方法了，就SQL中的 INSERT 语句，不过内容是现从另外的表中查出来的，其实就是 MySQL中INSERT INTO SELECT的使用   下面看看如何使用   语法：MySQL中INSERT INTO SELECT的使用 1. 语法介绍       有三张表a、b、c，现在需要从表b
  • Java反转字符串 dyy_gusi java反转字符串
           前几天看见一篇文章，说使用Java能用几种方式反转一个字符串。首先要明白什么叫反转字符串，就是将一个字符串到过来啦，比如"倒过来念的是小狗"反转过来就是”狗小是的念来过倒“。接下来就把自己能想到的所有方式记录下来了。 1、第一个念头就是直接使用String类的反转方法，对不起，这样是不行的，因为Stri
  • UI设计中我们为什么需要设计动效 gcq511120594 UIlinux
    随着国际大品牌苹果和谷歌的引领，最近越来越多的国内公司开始关注动效设计了，越来越多的团队已经意识到动效在产品用户体验中的重要性了，更多的UI设计师们也开始投身动效设计领域。 但是说到底，我们到底为什么需要动效设计？或者说我们到底需要什么样的动效？做动效设计也有段时间了，于是尝试用一些案例，从产品本身出发来说说我所思考的动效设计。 一、加强体验舒适度 嗯，就是让用户更加爽更加爽的用
  • JBOSS服务部署端口冲突问题 HogwartsRow java应用服务器jbossserverEJB3
    服务端口冲突问题的解决方法，一般修改如下三个文件中的部分端口就可以了。   1、jboss5/server/default/conf/bindingservice.beans/META-INF/bindings-jboss-beans.xml   2、./server/default/deploy/jbossweb.sar/server.xml   3、.
  • 第三章 Redis/SSDB+Twemproxy安装与使用 jinnianshilongnian ssdbreidstwemproxy
    目前对于互联网公司不使用Redis的很少，Redis不仅仅可以作为key-value缓存，而且提供了丰富的数据结果如set、list、map等，可以实现很多复杂的功能；但是Redis本身主要用作内存缓存，不适合做持久化存储，因此目前有如SSDB、ARDB等，还有如京东的JIMDB，它们都支持Redis协议，可以支持Redis客户端直接访问；而这些持久化存储大多数使用了如LevelDB、RocksD
  • ZooKeeper原理及使用 liyonghui160com
               ZooKeeper是Hadoop Ecosystem中非常重要的组件，它的主要功能是为分布式系统提供一致性协调(Coordination)服务，与之对应的Google的类似服务叫Chubby。今天这篇文章分为三个部分来介绍ZooKeeper，第一部分介绍ZooKeeper的基本原理，第二部分介绍ZooKeeper
  • 程序员解决问题的60个策略 pda158 框架工作单元测试
    根本的指导方针 1. 首先写代码的时候最好不要有缺陷。最好的修复方法就是让 bug 胎死腹中。 良好的单元测试 强制数据库约束 使用输入验证框架 避免未实现的“else”条件 在应用到主程序之前知道如何在孤立的情况下使用   日志 2. print 语句。往往额外输出个一两行将有助于隔离问题。 3. 切换至详细的日志记录。详细的日
  • Create the Google Play Account sillycat Google
    Create the Google Play Account Having a Google account, pay 25$, then you get your google developer account. References: http://developer.android.com/distribute/googleplay/start.html https://p
  • JSP三大指令 vikingwei jsp
    JSP三大指令   一个jsp页面中，可以有0~N个指令的定义！ 1. page --> 最复杂：<%@page language="java" info="xxx"...%>   * pageEncoding和contentType：     > pageEncoding：它
按字母分类： ABCDEFGHIJKLMNOPQRSTUVWXYZ其他