【雕爷学编程】Arduino动手做（88）---水流量传感器模块3
37款传感器与执行器的提法，在网络上广泛流传，其实Arduino能够兼容的传感器模块肯定是不止这37种的。鉴于本人手头积累了一些传感器和执行器模块，依照实践出真知（一定要动手做）的理念，以学习和交流为目的，这里准备逐一动手尝试系列实验，不管成功（程序走通）与否，都会记录下来—小小的进步或是搞不掂的问题，希望能够抛砖引玉。
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验八十八： 1号霍尔水流量传感器咖啡机直饮机流量监控模块
知识点：水流量传感器
是指通过对水流量的感应而输出脉冲信号或电流、电压等信号的水流量感应仪器，这种信号的输出和水流量成一定的线性比例，有相应的换算公式和比较曲线，因此可做水控方面的管理和流量计算，在热力方面配合换能器可测量一段时间介质能量的流失，如热能表。水流传感器主要和控制芯片、单片机，甚至PLC配合使用。水流传感器具有流量控制准确，可以循环设定动作流量，水流显示和流量累积计算的作用。
水流传感器基本原理1
水流量传感器是利用霍尔元件的霍尔效应来测量磁性物理量。在霍尔元件的正极串入负载电阻，同时通上5V的直流电压并使电流方向与磁场方向正交。当水通过涡轮开关壳推动磁性转子转动时，产生不同磁极的旋转磁场，切割磁感应线，产生高低脉冲电平。由于霍尔元件的输出脉冲信号频率与磁性转子的转速成正比，转子的转速又与水流量成正比，根据水流量的大小启动燃气热水器。其脉冲信号频率的经验公式见式（1）。
f=8.1q-3（1）
式中：f—脉冲信号频率，H2
q—水流量，L/min
由水流量传感器的反馈信号通过控制器判断水流量的值。根据燃气热水器机型的不同，选择最佳的启动流量，可实现超低压（0.02MPa以下）启动。
水流传感器工作原理2
水流传感器主要由铜阀体、水流转子组件、稳流组件和霍尔元件组成。它装在热水器的进水端用于测量进水流量。当水流过转子组件时，磁性转子转动，并且转速随着流量成线性变化。霍尔元件输出相应的脉冲信号反馈给控制器，由控制器判断水流量的大小，调节控制比例阀的电流，从而通过比例阀控制燃气气量，避免燃气热水器在使用过程中出现夏暖冬凉的现象。水流量传感器从根本上解决了压差式水气联动阀启动水压高以及翻板式水阀易误动作出现干烧等缺点。它具有反映灵敏、寿命长、动作迅速、安全可靠、连接方便利启动流量超低（1.5L/min）等优点，深受广大用户喜爱。
水流转子组件主要由涡轮开关壳、磁性转子、制动环组成。使用水流开关方式时，其性能优于机械式压差盘结构，且尺寸明显缩校当水流通过涡轮开关壳，推动磁性转子旋转，不同磁极靠近霍尔元件时霍尔元件导通，离开时霍尔元件断开。由此，可测量出转子转速。根据实测的水流量、转子转速和输出信号（电压）的曲线，便可确定出热水器的启动水压，以及启动水压相对应的启动水流量与转子的启动转速。由控制电路，便可实现当转子转速大于启动转速时热水器启动工作;在转速小于启动转速时，热水器停止工作。这样热水器启动水压一般设定在0.01MPa，启动水流量为3～5L/min（需满足热水器标准对最高温升的限制）。另外，由于水在永磁材料磁场切割下，变成磁化水，水中的含氧量增加，使人洗浴后感觉清爽。制动环的作用是停水时，制止高速旋转的磁性转子转动，终止脉冲信号输出。控制器接收不到脉冲信号，立即控制燃气比例阀关阀，切断气源，防止干烧。
水流量传感器的作用
1、通水通电，防干烧，有开关信号输出的和脉冲信号输出的水流量传感器（赛盛尔）；
2、线型比例输出脉冲信号，与流量成比例关系，从而实现加热功率的调整，达到恒温效果，大部分恒热热器和燃气势水器都采用这种方式，现在一些电势水龙头和洗手宝也有的用水流量传感器。
3、水流量传感器从根本上解决了压差式水气联动阀启动水压高以及翻板式水阀易误动作出现干烧等缺点。它具有反映灵敏、寿命长、动作迅速、安全可靠、连接方便利启动流量超低（1．5L/min）等优点，深受广大用户喜爱。
水流量传感器在运用中要注意的事项
1、当磁性资料或对传感器发生磁力的资料接近传感器时其特征能够有所改变。
2、为了防止颗粒、杂物进入传感器在传感器的入水口有必要装置过滤网。
3、水流量传感器的装置要避开有较强轰动和摇晃的环境防止影响传感器的丈量精度。
引出线方式：
1 红 IN 接正极
2 黄 OUT 信号输出线
3 黑 GND 接负极
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验八十八： 1号霍尔水流量传感器咖啡机直饮机流量监控模块
项目六：水流量指示灯（有流量时LED灯亮）
实验接线：Uno D2接流量传感器OUT，LED接D13
Arduino实验开源代码
/*
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验九十一： 1号霍尔水流量传感器 直饮机流量监控模块
项目六：水流量指示灯（有流量时LED灯亮）
实验接线：Uno D2接流量传感器OUT，LED接D13
*/
#define Holzer 2
#define LED 13
unsigned int holdtime; //霍尔停下的时间
int Holzer_Status;
void setup() {
holdtime = millis(); //读取当前时间
Serial.begin(9600);
pinMode(Holzer, INPUT);
pinMode(LED, OUTPUT);
Holzer_Status = digitalRead(Holzer); //读取霍尔初始状态
digitalWrite(LED, LOW); //将LED的初始状态设置为关闭
}
void loop() {
int Holzer_Status1 = digitalRead(Holzer); //读取霍尔状态
int nowtime;
if (Holzer_Status1 == (!Holzer_Status)) // 如果霍尔状态改变
{
Serial.println(Holzer_Status);
digitalWrite(LED, HIGH); // 点亮LED
Holzer_Status = Holzer_Status1; // 将霍尔状态重置为最新
holdtime = millis(); // 读取当前时间
}
else // 如果霍尔状态不变
{
nowtime = millis();
if (nowtime - holdtime > 300) // 如果没有变化持续 300
digitalWrite(LED,LOW);//关闭LED
}
}
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验八十八： 1号霍尔水流量传感器咖啡机直饮机流量监控模块
项目七：累计脉冲大于等于50则点亮LED灯
实验接线：Uno D2接流量传感器OUT，LED接D13
Arduino实验开源代码
/*
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验九十一： 1号霍尔水流量传感器 直饮机流量监控模块
项目七：累计脉冲大于等于50则点亮LED灯
实验接线：Uno D2接流量传感器OUT，LED接D13
*/
#define pin 2
#define led 13
volatile long count = 0;//变量count声明为volatile类型
void setup() {
pinMode(pin, INPUT);
pinMode(led, OUTPUT);
attachInterrupt(0, blinkA, FALLING);//当引脚电平由高电平变为低电平时触发中断服务程序
Serial.begin(9600);
Serial.println("准备就绪OK");
Serial.println("");
}
void loop() {
Serial.print("累计脉冲=");
Serial.println(count);
delay(1000);
if (count >= 50) {
digitalWrite(led, HIGH);
Serial.println("点亮LED灯");
}
else
digitalWrite(led, LOW);
}
void blinkA()
{
count++;
}
实验串口返回情况
Arduino实验场景图
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验八十八： 1号霍尔水流量传感器咖啡机直饮机流量监控模块
项目八：通过串口，监测实时流量与累计流量（有流量时LED亮）
实验接线：Uno D2接流量传感器OUT，LED接D13
实验说明：
float calibrationFactor = 7.5;
这个系数（及后面算法）仅为参考演示值，实际使用请自行专业校准
Arduino实验开源代码
/*
【Arduino】168种传感器模块系列实验（资料代码+仿真编程+图形编程）
实验九十一： 1号霍尔水流量传感器 直饮机流量监控模块
项目八：通过串口，监测实时流量与累计流量（有流量时LED亮）
实验接线：Uno D2接流量传感器OUT，LED接D13
*/
byte statusLed = 13;
byte sensorInterrupt = 0; // 0 = digital pin 2
byte sensorPin = 2;
// 霍尔效应流量传感器每秒输出大约 7.5 个脉冲
// 升/分钟的流量。
float calibrationFactor = 7.5; //这个系数（及后面算法）仅为参考演示值，实际使用请自行专业校准
volatile byte pulseCount;
float flowRate;
unsigned int flowMilliLitres;
unsigned long totalMilliLitres;
unsigned long oldTime;
void setup() {
// 初始化串行连接以向主机报告值
Serial.begin(38400);
// 将状态 LED 设置为输出
pinMode(statusLed, OUTPUT);
digitalWrite(statusLed, LOW); // 我们连接了一个高电平有效的 LED
pinMode(sensorPin, INPUT);
digitalWrite(sensorPin, HIGH); // 上拉霍尔效应流量传感器输出端为高电平
pulseCount = 0;
flowRate = 0.0;
flowMilliLitres = 0;
totalMilliLitres = 0;
oldTime = 0;
// 霍尔效应传感器连接到使用中断 0 的引脚 2。
// 配置为在下降状态变化时触发（从 HIGH 转换
// 状态到 LOW 状态）
attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
Serial.println("流量计准备就绪OK");
}
void loop() {
if ((millis() - oldTime) > 1000) // 每秒只处理一次计数器
{
// 在计算流量并将值发送给主机时禁用中断
detachInterrupt(sensorInterrupt);
// 因为这个循环可能不会在 1 秒的间隔内完成，我们计算
// 自上次执行和使用以来经过的毫秒数
// 缩放输出。 我们还应用了校准因子来缩放输出
// 基于每测量单位每秒的脉冲数（升/分钟
// 这种情况）来自传感器。
flowRate = ((1000.0 / (millis() - oldTime)) * pulseCount) / calibrationFactor;
// 请注意执行此处理过程的时间。 请注意，因为我们已经
// 禁用中断millis() 函数实际上不会正确递增
// 此时，它仍然会返回之前设置的值
// 中断消失了。
oldTime = millis();
// 将以升/分钟为单位的流速除以 60 以确定有多少升
// 在这 1 秒的间隔内通过传感器，然后乘以 1000 到
// 转换为毫升。
flowMilliLitres = (flowRate / 60) * 1000;
// 将这一秒传递的毫升数加到累计总数中
totalMilliLitres += flowMilliLitres;
unsigned int frac;
// 以升/分钟为单位打印这一秒的流量
Serial.print("流速: ");
Serial.print(int(flowRate)); // 打印变量的整数部分
Serial.print("."); // 打印小数点
//确定小数部分。 10 乘数给我们 1 个小数位。
frac = (flowRate - int(flowRate)) * 10;
Serial.print(frac, DEC) ; // 打印变量的小数部分
Serial.print("升/分钟");
// 打印这一秒流过的毫升数
Serial.print(" 当前流量: "); // 输出分隔符
Serial.print(flowMilliLitres);
Serial.print("毫升/秒");
// 打印自启动以来流过的累计升数
Serial.print(" 累计流量: "); // 输出分隔符
Serial.print(totalMilliLitres);
Serial.println("毫升");
if (flowMilliLitres > 10) {
digitalWrite(statusLed, HIGH); //有流量时点亮LED灯，否则熄灭
}
if (flowMilliLitres < 10) {
digitalWrite(statusLed, LOW);
}
//重置脉冲计数器，以便我们可以再次开始递增
pulseCount = 0;
//现在我们已完成发送输出，再次启用中断
attachInterrupt(sensorInterrupt, pulseCounter, FALLING);
}
}
// 中断服务程序
void pulseCounter() {
// 增加脉冲计数器
pulseCount++;
}
实验串口返回情况
Arduino实验接线示意图
水流量传感器工作原理
其结构很简单。主要部件是霍尔效应传感器、 涡轮叶轮 和 磁铁。水从入口流入，从出口流出。水流带动轮子转动，轮子上的磁铁也随之转动。磁场旋转触发霍尔传感器，输出高低电平方波（脉冲）。
轮子每转一圈，流过的水量都是一定的，输出的方波数也是如此。因此，我们可以通过计算方波（脉冲）的数量来计算水的流量。
最经典的水流量传感器 YF-S402 和 YF-S201就 依赖霍尔传感器。
关于实验代码
这里可以 digitalread() 在 LOOP 函数中使用来读取水流传感器的输出。每当读取到高电平时，计数加一。但是这种方式不是实时的，程序每次执行都需要一定的等待时间，在此期间不会检测到新的脉冲。
对于此类要求实时的应用程序，我们通常使用 中断。每当检测到脉冲的上升沿时，就会触发中断，计数加一。
有关中断的更多详细信息， 请查看 attachinterrupt()
官方链接：https://www.arduino.cc/reference/en/language/functions/external-interrupts/attachinterrupt/
应用场景决定了要使用的水流量传感器的类型
虽然您可以在我们的网络市场上找到十几个或更多的水流传感器，但通常它们可以分为两种类型：
大口径铜管
小口径塑料管
YF-B1～YF-B7属于大口径型，可以连续在工业，农业和畜牧业常用的，因此需要使用铜管其对压力的抗性和腐蚀更好的抗性。
而小直径的通常用于家用电器。其中最常见的是 YF-S201 和 YF-S402。YF-S201适用于卡片机、自动售货机，而YF-S402适用于饮水机、咖啡机等小口径家用电器。顺便说一下，YF-S402和YF-S201都是Arduino和Raspberry Pi水流传感器项目中常用的。
流量计YF-S402C规格书
