主要内容：objc_msgSend 的 方法查找流程
一、Runtime 介绍
二、探索方法的本质
三、objc_msgSend 快速查找流程分析
上一章cache_t 分析中主要分析了cache的写入流程，在写入流程之前还有cache的读取流程，即 objc_msgSend 和 cache_getImp
objc-cache.png
本章主要分析 objc_msgSend，在分析之前先了解什么是 Runtime
一、Runtime 介绍
编译时 是 将源代码翻译成机器能识别的代码 的过程
运行时 是 代码跑起来了.被装载到内存中 的过程
Runtime 官网文档
image.png
Runtime 被上层调用的途径，主要有三种：
- 通过
OC代码，例 [person sayHello] - 通过
接口，例 isKindOfClass - 通过
Runtime API, 例class_getInstanceSize
二、探索方法的本质
通过 clang 编译 main.cpp文件，来了解运行时
//main.m中方法的调用
LGPerson *person = [LGPerson alloc];
[person sayNB];
[person sayHello];
/** clang 编译后
LGPerson *person = ((LGPerson *(*)(id, SEL))(void *)objc_msgSend)((id)objc_getClass("LGPerson"), sel_registerName("alloc"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayNB"));
((void (*)(id, SEL))(void *)objc_msgSend)((id)person, sel_registerName("sayHello"));
*/
/* 方法调用，这三种方式相同
sel_registerName(const char * _Nonnull str)
NSSelectorFromString(NSString * _Nonnull aSelectorName)
@selector(selector)
*/
发现，并不是用OC的上层方法，而是用的objc_msgSend函数
- 验证普通方法调用，可以将 [person sayNB] 换为 objc_msgSend
// 导入头文件 #import
// 将 targets -> BuildSettings -> 搜索 msg -> Enable Strict Checking of objc_msgSend Calls 由 YES 改为 NO，把严厉的检查机制关掉。
// 方法: 消息 : (消息的接受者 . 消息主体)
LGPerson *person = [LGPerson alloc];
objc_msgSend(person,sel_registerName("sayNB"));
[person sayNB];
会发现 打印结果相同，所以两种调用是等价的
- 验证父类方法调用
@interface LGTeacher : NSObject
- (void)sayHello;
@end
@implementation LGTeacher
- (void)sayHello{
NSLog(@"666");
}
@end
@interface LGPerson : LGTeacher
- (void)sayHello;
- (void)sayNB;
@end
@implementation LGPerson
- (void)sayNB{
NSLog(@"666");
}
@end
int main(int argc, const char * argv[]) {
@autoreleasepool {
// 方法: 消息 : (消息的接受者 . 消息主体)
LGPerson *person = [LGPerson alloc];
LGTeacher *teacher = [LGTeacher alloc];
// 消息的接受者还是自己 - 父类 - 请你直接找我的父亲
[person sayHello];
//
// struct objc_super {
// /// Specifies an instance of a class.
// __unsafe_unretained _Nonnull id receiver;
//
// /// Specifies the particular superclass of the instance to message.
// #if !defined(__cplusplus) && !__OBJC2__
// For compatibility with old objc-runtime.h header */
// __unsafe_unretained _Nonnull Class class;
// #else
// __unsafe_unretained _Nonnull Class super_class;
// #endif
// /* super_class is the first class to search */
// };
// #endif
struct objc_super lgsuper;
lgsuper.receiver = person;
lgsuper.super_class = [LGTeacher class];
objc_msgSendSuper(&lgsuper, sel_registerName("sayHello"));
}
return 0;
}
输出结果：
2020-10-04 19:44:33.070216+0800 001-运行时感受[3006:128090] 666
2020-10-04 19:44:33.070282+0800 001-运行时感受[3006:128090] 666
总结：OC方法 - 消息(sel imp) sel -> imp -> 内容
思考问题：sel 怎么找到 imp？
三、objc_msgSend 快速查找流程分析
1.汇编执行流程图
汇编执行流程图.png
2.ENTRY _objc_msgSend
-
搜索 _objc_msgSend 源码
image.png
这里我们只看 arm64 版本
找到汇编方法入口：ENTRY _objc_msgSend
-
image.png
ENTRY _objc_msgSend 源码
// -- 消息发送 -- 汇编入口 -- _objc_msgSend 主要是拿到接收者的isa信息, 两个参数：消息接收者receiver 和 消息sel
ENTRY _objc_msgSend
// -- 无窗口
UNWIND _objc_msgSend, NoFrame
// -- 判断 p0是否为空，p0是第一个参数 - 消息接收者receiver
cmp p0, #0 // nil check and tagged pointer check
//-- le小于 --支持taggedpointer（小对象类型）的流程
#if SUPPORT_TAGGED_POINTERS
b.le LNilOrTagged // (MSB tagged pointer looks negative)
#else
//-- p0 等于 0 时，直接返回 空
b.eq LReturnZero
#endif
//-- 根据对象拿出isa ，即从x0寄存器指向的地址 取出 isa，存入 p13寄存器
//-- 拿isa，是因为不论是对象方法还是类方法，都需要在类或元类的缓存或者方法列表中查找。
ldr p13, [x0] // p13 = isa
//-- 在64位架构下通过 p16 = isa（p13） & ISA_MASK，拿出shiftcls信息，得到class信息
GetClassFromIsa_p16 p13 // p16 = class
LGetIsaDone:
// calls imp or objc_msgSend_uncached
//-- 如果有isa，走到CacheLookup 即查找方法缓存，也就是所谓的sel imp快速查找流程
CacheLookup NORMAL, _objc_msgSend
#if SUPPORT_TAGGED_POINTERS
LNilOrTagged:
//-- 返回空
b.eq LReturnZero // nil check
// tagged
adrp x10, _objc_debug_taggedpointer_classes@PAGE
add x10, x10, _objc_debug_taggedpointer_classes@PAGEOFF
ubfx x11, x0, #60, #4
ldr x16, [x10, x11, LSL #3]
adrp x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGE
add x10, x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGEOFF
cmp x10, x16
b.ne LGetIsaDone
// ext tagged
adrp x10, _objc_debug_taggedpointer_ext_classes@PAGE
add x10, x10, _objc_debug_taggedpointer_ext_classes@PAGEOFF
ubfx x11, x0, #52, #8
ldr x16, [x10, x11, LSL #3]
b LGetIsaDone
// SUPPORT_TAGGED_POINTERS
#endif
LReturnZero:
// x0 is already zero
mov x1, #0
movi d0, #0
movi d1, #0
movi d2, #0
movi d3, #0
ret
END_ENTRY _objc_msgSend
3. GetClassFromIsa_p16 获取isa
.macro GetClassFromIsa_p16 /* src */
#if SUPPORT_INDEXED_ISA
// Indexed isa
//-- 将 isa 存入p16寄存器
mov p16, $0 // optimistically set dst = src
//-- 判断是否是 not nonapointer
tbz p16, #ISA_INDEX_IS_NPI_BIT, 1f // done if not non-pointer isa
// isa in p16 is indexed
//-- 将_objc_indexed_classes所在的页的基址 读入x10寄存器
adrp x10, _objc_indexed_classes@PAGE
//-- x10 = x10 + _objc_indexed_classes(page中的偏移量) --x10基址 根据 偏移量 进行 内存偏移
add x10, x10, _objc_indexed_classes@PAGEOFF
//-- 从p16的第ISA_INDEX_SHIFT位开始，提取 ISA_INDEX_BITS 位 到 p16寄存器，剩余的高位用0补充
ubfx p16, p16, #ISA_INDEX_SHIFT, #ISA_INDEX_BITS // extract index
ldr p16, [x10, p16, UXTP #PTRSHIFT] // load class from array
1:
//--用于64位系统
#elif __LP64__
// 64-bit packed isa
//-- p16 = class = isa & ISA_MASK(位运算 & 即获取isa中的shiftcls信息)
and p16, $0, #ISA_MASK
#else
//-- 用于32位系统
// 32-bit raw isa
mov p16, $0
#endif
.endmacro
4. CacheLookup 缓存查找汇编源码
.macro CacheLookup
//
// Restart protocol:
//
// As soon as we're past the LLookupStart$1 label we may have loaded
// an invalid cache pointer or mask.
//
// When task_restartable_ranges_synchronize() is called,
// (or when a signal hits us) before we're past LLookupEnd$1,
// then our PC will be reset to LLookupRecover$1 which forcefully
// jumps to the cache-miss codepath which have the following
// requirements:
//
// GETIMP:
// The cache-miss is just returning NULL (setting x0 to 0)
//
// NORMAL and LOOKUP:
// - x0 contains the receiver
// - x1 contains the selector
// - x16 contains the isa
// - other registers are set as per calling conventions
//
LLookupStart$1:
// p1 = SEL, p16 = isa
//-- #define CACHE (2 * __SIZEOF_POINTER__)，其中 __SIZEOF_POINTER__表示pointer的大小 ，即 2*8 = 16
//-- p11 = _maskAndBuckets -- 从x16（即isa）中平移16字节，取出cache 存入p11寄存器 -- isa距离cache 正好16字节：isa（8字节）-superClass（8字节）-cache（mask高16位 + buckets低48位）
ldr p11, [x16, #CACHE] // p11 = mask|buckets
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16 //64位真机
//-- 将_maskAndBuckets & 0x0000ffffffffffff，高16位抹零，相当于去掉 mask, 得到buckets,并存放 p10
and p10, p11, #0x0000ffffffffffff // p10 = buckets
//-- LSR:逻辑右移。将_maskAndBuckets 右移 48位，得到 mask, p1(参数sel) & mask，得到下标，即搜索下标 ，存入 p12(cache::insert中cache_hash函数中哈希下标的计算是 sel & mask，读取时也需要如此)
and p12, p1, p11, LSR #48 // x12 = _cmd & mask
//-- 非64位
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
and p10, p11, #~0xf // p10 = buckets
and p11, p11, #0xf // p11 = maskShift
mov p12, #0xffff
lsr p11, p12, p11 // p11 = mask = 0xffff >> p11
and p12, p1, p11 // x12 = _cmd & mask
#else
#error Unsupported cache mask storage for ARM64.
#endif
//-- LSL:逻辑左移。p12:index(哈希下标)。 p10:buckets数组首地址(bucket: 8字节sel + 8字节imp),每个 bucket是16字节。 PTRSHIFT:3
//-- p12 = buckets + (index << 4) --> p12:下标对应的要查找的bucket的地址
add p12, p10, p12, LSL #(1+PTRSHIFT)
// p12 = buckets + ((_cmd & mask) << (1+PTRSHIFT))
//-- x12即p12， 从x12存的bucket中 取出 imp 和 sel，分别存入 p17(存imp) 和 p9(存sel)
ldp p17, p9, [x12] // {imp, sel} = *bucket
//-- 将获取到的 sel 与 传入的sel 进行比较。 p1(传入的参数sel)
1: cmp p9, p1 // if (bucket->sel != _cmd)
//-- 不相等，跳转到 2f
b.ne 2f // scan more
//-- 相等，CacheHit缓存命中，直接返回 imp
CacheHit $0 // call or return imp
2: // not hit: p12 = not-hit bucket
//-- 如果找不到， 跳转 CheckMiss
CheckMiss $0 // miss if bucket->sel == 0
//-- 判断p12(bucket) 是否等于 p10(buckets数组首地址)
cmp p12, p10 // wrap if bucket == buckets
//-- p12是第一个元素，跳转到 3f
b.eq 3f
//-- 不相等，p12向前平移一个BUCKET_SIZE的内存地址，即向前查找，找前一个bucket元素，分别取出 imp 和 sel 存入 p17 和 p9中
ldp p17, p9, [x12, #-BUCKET_SIZE]! // {imp, sel} = *--bucket
//-- 跳转至 第一步，继续对比 sel 和 p1(传入的sel)
b 1b // loop
3: // wrap: p12 = first bucket, w11 = mask
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
//-- 设置到最后一个元素
//-- p12 = buckets + (p11(mask|buckets) >> (48-4))) ,p12指向buckets的最后一个元素，缓存查找顺序是向前查找
//-- p11 >> 44 == (p11 >> 48) << 4; p11 >> 48 -> mask
add p12, p12, p11, LSR #(48 - (1+PTRSHIFT))
// p12 = buckets + (mask << 1+PTRSHIFT)
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
add p12, p12, p11, LSL #(1+PTRSHIFT)
// p12 = buckets + (mask << 1+PTRSHIFT)
#else
#error Unsupported cache mask storage for ARM64.
#endif
// Clone scanning loop to miss instead of hang when cache is corrupt.
// The slow path may detect any corruption and halt later.
//-- 拿的出p12指向的bucket中的 imp和sel 分别存入 p17 和 p9
ldp p17, p9, [x12] // {imp, sel} = *bucket
//-- 将获取到的 sel 与 传入的sel 进行比较。 p1(传入的参数sel)
1: cmp p9, p1 // if (bucket->sel != _cmd)
//-- 不相等，跳转到 2f
b.ne 2f // scan more
//-- 相等，CacheHit缓存命中，直接返回 imp
CacheHit $0 // call or return imp
2: // not hit: p12 = not-hit bucket
//-- 如果找不到， 跳转 CheckMiss
CheckMiss $0 // miss if bucket->sel == 0
//-- 判断p12(bucket) 是否等于 p10(buckets数组首地址)
cmp p12, p10 // wrap if bucket == buckets
//-- p12是第一个元素，跳转到 3f
b.eq 3f
//-- 不相等，p12向前平移一个BUCKET_SIZE的内存地址，即向前查找，找前一个bucket元素，分别取出 imp 和 sel 存入 p17 和 p9中
ldp p17, p9, [x12, #-BUCKET_SIZE]! // {imp, sel} = *--bucket
//-- 跳转至 第一步，继续对比 sel 和 p1(传入的sel)
b 1b // loop
LLookupEnd$1:
LLookupRecover$1:
3: // double wrap
//--- 跳转至JumpMiss 因为是normal ，跳转至__objc_msgSend_uncached
JumpMiss $0
.endmacro
5.CacheHit 缓存命中
// CacheHit: x17 = cached IMP, x12 = address of cached IMP, x1 = SEL, x16 = isa
.macro CacheHit
.if $0 == NORMAL
TailCallCachedImp x17, x12, x1, x16 // authenticate and call imp
.elseif $0 == GETIMP
mov p0, p17
cbz p0, 9f // don't ptrauth a nil imp
AuthAndResignAsIMP x0, x12, x1, x16 // authenticate imp and re-sign as IMP
9: ret // return IMP
.elseif $0 == LOOKUP
// No nil check for ptrauth: the caller would crash anyway when they
// jump to a nil IMP. We don't care if that jump also fails ptrauth.
AuthAndResignAsIMP x17, x12, x1, x16 // authenticate imp and re-sign as IMP
ret // return imp via x17
.else
.abort oops
.endif
.endmacro
6. CheckMiss 没有找到
.macro CheckMiss
// miss if bucket->sel == 0
.if $0 == GETIMP
//-- 如果为GETIMP ，则跳转至 LGetImpMiss
cbz p9, LGetImpMiss
.elseif $0 == NORMAL
//-- 如果为NORMAL ，则跳转至 __objc_msgSend_uncached
cbz p9, __objc_msgSend_uncached
.elseif $0 == LOOKUP
//-- 如果为LOOKUP ，则跳转至 __objc_msgLookup_uncached
cbz p9, __objc_msgLookup_uncached
.else
.abort oops
.endif
.endmacro
7. JumpMiss实现
.macro JumpMiss
.if $0 == GETIMP
b LGetImpMiss
.elseif $0 == NORMAL
b __objc_msgSend_uncached
.elseif $0 == LOOKUP
b __objc_msgLookup_uncached
.else
.abort oops
.endif
.endmacro