Unity Shader 逐顶点兰伯特漫反射光照（三）

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

逐顶点兰伯特漫反射光照效果：

逐顶点兰伯特漫反射光照.png

逐顶点兰伯特漫反射光照、逐像素兰伯特漫反射光照、逐像素半兰伯特漫反射光照效果：

逐顶点兰伯特漫反射光照、逐像素兰伯特漫反射光照、逐像素半兰伯特漫反射光照.png

兰伯特漫光照模型漫反射光公式：Id = Ip * Kd * N * L
Id：表面漫反射光颜色；
IP：入射光的光颜色；
Kd：漫反射系数 ( 0 ≤ Kd ≤ 1)；
N为该点的单位法向量；
L为光单位向量；

Shader代码：

// 逐顶点漫反射
Shader "Custom/Diffuse/DiffuseVertx"
{
    Properties
    {
        _Diffuse ("Diffuse", Color) = (1, 1, 1, 1) // 漫反射光颜色
    }
    SubShader
    {
        Tags { "RenderType" = "Opaque" }
        LOD 100
        
        Pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            // 引用Unity内置文件
            #include "Lighting.cginc"
            
            fixed4 _Diffuse;
            
            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION;
                float3 normal: NORMAL;
            };
            
            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION;
                fixed3 color: COLOR;
            };
            
            // 顶点着色器函数
            v2f vert(a2v v)
            {
                v2f o;
                
                // 将顶点坐标从模型空间转换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);
                
                // 将法线从模型空间转换到世界空间下，然后归一化
                // unity_WorldToObject将顶点方向矢量从世界空间变换到模型空间矩阵
                // 等价于fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
                fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);
                
                // _WorldSpaceLightPos0: 光源信息
                // _WorldSpaceLightPos0.w为0表示是平行光，则光方向为:_WorldSpaceLightPos0.xyz
                // _WorldSpaceLightPos0.w为1表示是点光源或者聚光灯光源，则光方向为_WorldSpaceLightPos0.xyz减去世界空间下顶点坐标位置
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);
                
                // 兰伯特漫光照模型漫反射光公式：Id = Ip * Kd * N * L
                // Id：表面漫反射光颜色；
                // IP：入射光的光颜色；
                // Kd：漫反射系数 ( 0 ≤ Kd ≤ 1)；
                // N为该点的单位法向量，L为光单位向量
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));
                
                // 获得Unity环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                o.color = diffuse + ambient;
                
                return o;
            }
            
            // 片元着色器函数
            fixed4 frag(v2f i): SV_TARGET
            {
                return fixed4(i.color, 1);
            }
            
            
            ENDCG
            
        }
    }
}