Stata中的数值型变量分类神器--recode

本文作者：陈丹慧，中南财经政法大学金融学院
文字编辑：崔赵雯
技术总编：余术玲

导读

​  初识recode命令，我以为它就是个改缺失值的小能手。我们常常看见它是这样出现的：

recode a (.=0)

​  它的作用等效如下：

replace a=0 if a=.

​  再识recode，才发现这个小命令没那么简单！掌握了recode，处理起数值型变量不是一般地溜！好东西就要分享，接下来，我就给大家全面解析recode命令。

一、语法

​  recode命令的完整语法如下：

recode varlist (erule) [(erule) . . .] [if] [in] [, options]

​  其中，varlist是指我们想改变的一到多个变量；erule是我们指定的改变规则，形式为新值=旧值。可以同时指定多个规则，每个规则用小括号括起来，用空格分隔；if和in是条件和范围筛选语句，可以根据目的自由添加；最后是一些重要的options选项，后面会具体介绍。

（1）一般的规则形式

recode x (3=1) //将变量x观测值中的3全部改为1
recode x y (8=1) (7=2) (6=3)  //将变量x和y的观测值中的8改为1，7改为2，6改为3
recode x (2 .=0) //将变量x观测值中的2和缺失值改为0
recode x (1/5=4) //将变量x观测值为1到5闭区间内的实数都改为4

​  注意：在recode命令中的1/5和Stata数列表示中的1/5不同。数列表示中1/5指1，2，3，4，5这5个整数，但在recode命令中1/5包括1到5闭区间内全部实数。 ​
  此外，我们还可以用min和max来代表数值，且在等号左边和右边均可。

recode x (min/3=max) //将最小值到3这个区间内的值都改为最大值

（2）含关键词的规则形式：

​  为了更好说明含关键词的规则形式，我们先用input命令输入一些变量与数值：

clear
input v
1
2.1
3.2
.
5
6
7
8
end

​  并且为了更好展示效果，插播一下，介绍两个简单但十分重要的选项：
  首先是generate()选项，用于生成新变量的变量名。其次是prefix()选项，用于添加新变量前缀。如果不使用这两个选项，我们使用recode命令时就会使初始数据产生改变，带来很多不方便，因此强烈推荐在使用recode命令时添加这两个选项之一。 ​
  例如：将原始数据中的1到5改为0，并将改变后的数值储存在一个由原变量名称添加前缀"new_"的新变量中。

recode v (1/5=0),prefix(new_)

​  此时，数据集如图所示：

image1.png

​  观察新变量，我们注意到，规则指定外的数值都保持不变。此时，我们可以继续指定一般规则，也可以指定含关键词的规则。含关键词的规则是针对没被之前规则改变的数值而设定的，它必须放在一般规则的后面。主要的关键词有以下四个：nonmissing、missing、else和*****。

recode v (1/5=0) (nonmissing=1),generate(v1) //将未被前面规则改变的非缺失值改为1
recode v (1/5=0) (missing=2),generate(v2) //将未被前面规则改变的缺失值改为2
recode v (1/5=0) (else=1),generate(v3) //将未被前面规则改变的所有值改为1
recode v (1/5=0) (*=1),generate(v4) //*和else作用完全一样
recode v (1/5=0) (nonmissing=1) (missing=2),generate(v5)

​  再次观察数值集，相信大家此时对关键词规则基本了解了。

image2.png

  此外，重点提示一下，else/*不能与nonmissing或missing同时使用，否则会出现如下报错:

image3.png

二、其他选项与案例

（1）test()选项

​  recode命令中的规则指定是有序的。从左到右的规则中，一旦一个值在前面已经被指定做出某种改变了，在后面的规则中如果再次指定这个值，会被忽视。以刚刚的数据为例：

recode v (1/5=0) (5=1),generate(v6)

​  在这里，对数值5先后做出了两次指定：第一次要求将5变为0；第二次要求将5变为1。观察数值集可以发现，5变为0了，而将5变为1的指令被忽视了：

image4.png

​  但结果界面没有给出明显提示：

image5.png

​  如果碰上大数据，出现这样的操作失误很难被发现。加上一个test()选项，在结果界面就会有提示规则重复了：

image6.png

  此外，test()选项还能测试recode命令是否应用了所有规则，如果有规则没有被使用，将会显示警示。如下：数据集中并没有10这个数值，因此这个规则指定一定是无效的，加上text()选项就会提示有至少一条规则没有生效：

image7.png

（2）copyrest()选项

​  在recode命令中，如果添加if或in语句限定了观测值改变范围，在产生的新变量中，范围外的数值将会变为缺失值。例如，指定前三行的数值进行相应改变：

recode v (1/5=0) in 1/3,gen(v9)

​  观察数据集可发现，前三行外的数值全部变成了缺失值。这时加上copyrset选项，就会将范围外的观测值原样复制到新变量中。

recode v (1/5=0) in 1/3,gen(v10) copyrest

image8.png

（3）label()选项

​​  label()选项可以说是recode命令的灵魂，正是因为有label()选项，recode才可无愧于分类神器这个称号。在之前的推文让你的数据一目了然--label命令介绍中，我们介绍过如何使用label命令来给值贴标签。一般分为两步走，先用label define 定义值标签，再用label value 贴标签。而recode命令中，简单一行命令就可以搞定这两步！ ​
​  下面我们以Stata提供的网络数据集来介绍一下recode命令中的label()选项：

webuse fullauto, clear

​​  观察变量窗口，我们可以发现rep77，rep78两个变量共享值标签repair。

image9.png

​  查看repair这个值标签的内容。

label list repair

​​  我们发现repair这个值标签有5项内容：

image10.png

​​  现在，我们觉得分成5类太多了，想改为3类，且对相应数据重新分组赋值，即实现如下操作：

image12.png

​  直接在每个规则指定后面用双引号添加新标签内容，并且在最后添加label()选项为新标签命名即可：

recode rep77 rep78 (1 2=1 "Below average") (3=2 "Average") (4 5=3 "Above average"),prefix(new) label(newrep)
list *rep* in 1/5,nolabel
label list repair newrep

​​  此时，新的标签内容和部分数据集情况如下：

image13.png

​​  今天对recode命令的介绍就到这里了，快去动手试试分类你的数值型变量吧！