（转）SAP内存/ABAP内存/共享内存区别

本文转：https://blog.csdn.net/amaryh/article/details/7533282

(1)、读取和使用方法不同
SAP内存使用SET/GET parameters方法；
SET PARAMETER ID 'MAT' field p_matnr.
GET PARAMETER ID 'MAT' field p_matnr.
ABAP内存使用EXPORT 和IMPORT 方法；
export p_matnr = p_matnr to memory id 'ZTESTMAT'.
import p_matnr = p_matnr from memory id 'ZTESTMAT'
(2)、共享范围不同
SAP内存可以被所有的主session访问，内存数据可以在同一个session中不同程序之间，或者不同session之间共享数据；
ABAP内存只能在同个session的不同程序之间共享数据；
(3)、作用范围不同
SAP内存在整个终端session时间内都有效；
ABAP内存只能在一个session时间内有效；
(4)、使用一般原则
SAP内存用于屏幕默认值输入；
ABAP内存用于模块之间传替数据
--------------以上是SAP内存和ABAP内存的区别------------------------
ABAP提供了IMPORT/EXPORT 和 SET/GET PARAMETER语句，可对用户内存/服务器内存/数据库进行存储和访问。不过可能很多人对此还不是很了解，下面我们通过实例来测试它们的区别和联系。

1. ABAP Memory
   用户登陆后，最多一个系统可以开6个窗口，这在SAP中称为External Mode。
   而同一个窗口中，运行某程序后，可以通过CALL TRANSACTION/SUBMIT或其他代码跳转到其他程序，这个称为Internal Mode。Internal Mode的调用栈最多为9层。
   那么ABAP Memory，它是属于Internal Mode间可以共享的数据，而External Mode间无法共享。

例子. 创建程序A，输入：
DATA matnr TYPE matnr.
IMPORT matnr FROM MEMORY ID 'YTEST_MATNR'.
WRITE matnr.
创建程序B，输入：
DATA matnr TYPE matnr.
matnr = '000000000000001234'.
EXPORT matnr TO MEMORY ID 'YTEST_MATNR'.
SUBMIT y_program_a. "调用程序A
直接运行B，发现程序A从ABAP Memory读到了值并输出到LIST.

说明：
(1)调试运行B到EXPORT语句后面，Goto-System Area-ABAP Memory，可以查看到名为YTEST_MATNR的一片内存。
(2)如果B和A运行在不同的窗口，则A将访问不到数据；当用户输入/N退出当前程序时，内存值也将被清空。
(3)该语句适用于CALL TRANSACTION/SUBMIT过程中的数据共享，也常用于User Exit，类似于定义全局变量的效果。

2. SAP Memory
   上面说了External Mode，那么它们之间共享数据必须通过SET/GET PARAMETER语句，不再是EXPORT/IMPORT的模式。

例子. 创建程序A，输入：
DATA matnr TYPE matnr.
GET PARAMETER ID 'YTEST' FIELD matnr.
WRITE matnr.
创建程序B，输入：
DATA: matnr TYPE matnr.
matnr = '000000000000012345'.
SET PARAMETER ID 'YTEST' FIELD matnr.
在窗口1运行程序B并关闭后，在窗口2运行程序A，发现程序A仍然读到了SAP Memory的值。

说明：
(1)调试时，可通过Goto-System Area-SAP Memory，查看到YTEST及其对应的值。
(2)SET/GET PARAMETER的值与本次登陆有关，当用户注销后才失效。在用户登陆的时候，系统会根据每个用户User Profile-Own Data-Parameter下的设置，载入到SAP Memory。
(3)Data Element中可以看到Further Characteristics下可定义PARAMETER ID，代表该字段作为屏幕元素时，可读取该PARAMETER ID作为默认值。比如VA03会自动显示刚刚创建的订单号。

3. SHARED MEMORY/SHARED BUFFER
   前面介绍的都是用户内存，那么不同用户间如何实现数据共享呢？可以用SHARED MEMORY或SHARED BUFFER，它们是服务器上的某片所有用户共享的内存。关于SHARED MEMORY和SHARED BUFFER的区别，可以F1查看帮助。如果EXPORT SHARED BUFFER，则必须IMPORT SHARED BUFFER才能读到，用IMPORT SHARED MEMORY是读不到的。反过来也是。

例子. 创建程序A，输入：
DATA matnr TYPE matnr.
IMPORT matnr FROM SHARED BUFFER indx(aa) ID 'YTEST_MATNR'.
WRITE matnr.
创建程序B，输入：
DATA: matnr TYPE matnr.
matnr = '000000000000123456'.
EXPORT matnr TO SHARED BUFFER indx(aa) ID 'YTEST_MATNR'.
先在用户1的电脑上运行程序B，然后在用户2的电脑上运行程序A，发现用户2可以读取到值。

说明：
(1)既然是服务器上的所有用户共享空间，那么该值将保存到服务器关机重启为止，除非用户用DELETE语句清除它。其实这个跟ENQUEUE/DEQUEUE有点相似之处。
(2)数据库也可共享数据，不过服务器共享肯定速度快些，理论上适合网络游戏，呵呵。
(3)INDX是系统中存在的符合特定格式要求的表。但这不代表该EXPORT/IMPORT语句将在表INDX中增加记录，仅仅代表服务器借用了INDX的结构来管理该片共享内存。

4. DATABASE
   上面说了SHARED BUFFER并不访问数据库，而要访问数据库就应该用DATABASE。

创建一个程序，录入代码：
DATA: matnr TYPE matnr.
matnr = '000000000000004321'.
EXPORT matnr TO DATABASE indx(aa) ID 'YTEST_MATNR'.

执行程序，然后SE16查看表INDX，发现新增了一条RELID = AA, SRTFD = YTEST_MATNR的记录。如果EXPORT的数据量比较大，则新增的将是多条，这些条目的字段值SRTF2从0递增。所以EXPORT DATABASE与普通数据库操作的不同之处是，它适合大数据量的操作，系统自动将其拆分成多条记录并存储到数据库中，比如图片或文档。而用IMPORT DATABASE的过程则相反，系统将把这些条相关记录又自动组合起来成为一个整体。

参考这里，有更多资料
http://www.zhsap.com/?fromuid=5774