ARM:作业1

实现3盏灯的流水 发布到CSDN 代码+截图

代码

.text
.global _start
_start: 
@1.RCC时钟使能GPIOE F  RCC_MP_AHB4ENSETR[4-5]->1
LDR R0,=0x50000a28
LDR R1,[R0]
ORR R1,R1,#(0x3<<4)
STR R1,[R0]
@2.设置PE10为输出模式  GPIOE_MODER[21:20]->01
@2.设置PE8为输出模式  GPIOE_MODER[17:16]->01
@先清0
LDR R0,=0x50006000
LDR R1,[R0]
BIC R1,R1,#(0x3<<20)
BIC R1,R1,#(0x3<<16)
@再置位
ORR R1,R1,#(0x1<<20)
ORR R1,R1,#(0x1<<16)
STR R1,[R0]
 
@2.设置PF10为输出模式  GPIOF_MODER[21:20]->01
@先清0
LDR R0,=0x50007000
LDR R1,[R0]
BIC R1,R1,#(0x3<<20)
@再置位
ORR R1,R1,#(0x1<<20)
STR R1,[R0]
 
@3.设置PE10为推挽输出  GPIOE_OTYPER[10]->0
@3.设置PE8为推挽输出  GPIOE_OTYPER[8]->0
LDR R0,=0x50006004
LDR R1,[R0]
BIC R1,R1,#(0x1<<10)
BIC R1,R1,#(0x1<<8)
STR R1,[R0]
@3.设置PF10为推挽输出  GPIOF_OTYPER[10]->0
LDR R0,=0x50007004
LDR R1,[R0]
BIC R1,R1,#(0x1<<10)
STR R1,[R0]
 
@4.设置PE10为低速输出  GPIOE_OSPEEDR[21:20]->00
@4.设置PE8为低速输出  GPIOE_OSPEEDR[17:16]->00
LDR R0,=0x50006008
LDR R1,[R0]
BIC R1,R1,#(0x3<<20)
BIC R1,R1,#(0x3<<16)
STR R1,[R0]
 
@4.设置PF10为低速输出  GPIOF_OSPEEDR[21:20]->00
LDR R0,=0x50007008
LDR R1,[R0]
BIC R1,R1,#(0x3<<20)
STR R1,[R0]
 
@5.设置PE10输出无上拉下拉 GPIOE_PUPDR[21:20]->00
@5.设置PE8输出无上拉下拉 GPIOE_PUPDR[17:16]->00
LDR R0,=0x5000600C
LDR R1,[R0]
BIC R1,R1,#(0x3<<20)
 
BIC R1,R1,#(0x3<<16)
STR R1,[R0]
 
@5.设置PF10输出无上拉下拉 GPIOF_PUPDR[21:20]->00
LDR R0,=0x5000700C
LDR R1,[R0]
BIC R1,R1,#(0x3<<20)
STR R1,[R0]
 
 
@LED1闪烁
loop:
@LED1亮
BL led1_on
bl delay
@LED1灭
BL led1_off
bl delay
 
@LED2闪烁
@LED1亮
BL led2_on
bl delay
@LED2灭
BL led2_off
bl delay
 
@LED3闪烁
@LED1亮
BL led3_on
bl delay
@LED2灭
BL led3_off
bl delay
b loop
 
 
@LED1亮
led1_on:
    LDR R0,=0x50006014
    LDR R1,[R0]
    ORR R1,R1,#(0x1<<10)
    STR R1,[R0] 
    mov pc,lr
@LED1灭
led1_off:
    LDR R0,=0x50006014
    LDR R1,[R0]
    BIC R1,R1,#(0x1<<10)
    STR R1,[R0] 
    mov pc,lr
 
@LED2亮
led2_on:
    LDR R0,=0x50007014
    LDR R1,[R0]
    ORR R1,R1,#(0x1<<10)
    STR R1,[R0] 
    mov pc,lr
@LED2灭
led2_off:
    LDR R0,=0x50007014
    LDR R1,[R0]
    BIC R1,R1,#(0x1<<10)
    STR R1,[R0] 
    mov pc,lr
 
@LED3亮
led3_on:
    LDR R0,=0x50006014
    LDR R1,[R0]
    ORR R1,R1,#(0x1<<8)
    STR R1,[R0] 
    mov pc,lr
@LED3灭
led3_off:
    LDR R0,=0x50006014
    LDR R1,[R0]
    BIC R1,R1,#(0x1<<8)
    STR R1,[R0] 
    mov pc,lr
 
 
 
@封装汇编的延时函数
delay:
    LDR R1,=0X10000000
mm:
    cmp R1,#0
    SUBNE R1,R1,#1
    BNE mm
    mov pc,lr

.end

运行结果：