oracle 导出csv文件

转载自：  http://luyongxin88.blog.163.com/blog/static/92558072011619115135111/

自己做了测试，原帖中贴出的存储过程，似乎由于字段间数据没有分割完全，导致在导出的csv文件中，字段和数据没有对应上（我测试的结果是：会有两列数据挤到一列中去）。

修改了存储过程后（代码中红色标示出的语句），完全分割了各字段的数据，实现了从oracle中把数据导出csv文件。

要实现这一功能，首先需要了解oracle的utl_file,directory知识。

普通用户还需要执行以下步骤：

1、以管理员用户登录，授给指定普通用户create directory权限，命令如下：

      GRANT   CREATE ANY DIRECTORY to bloodeyed;

      授权给指定用户执行utl_file，命令如下：

       GRANT    EXECUTE    ON    utl_file    TO    bloodeyed;

2、普通用户登录，执行命令：

      CREATE OR  REPLACE DIRECTORY  MYDIR AS 'd:\';

3、编写存储过程。

     以下仅供参考：

    CREATE OR REPLACE PROCEDURE SQL_TO_CSV

    (

        P_QUERY IN VARCHAR2,                        -- PLSQL文

        P_DIR IN VARCHAR2,                          -- 导出的文件放置目录

        P_FILENAME IN VARCHAR2                      -- CSV名

)

IS

        L_OUTPUT UTL_FILE.FILE_TYPE;

        L_THECURSOR INTEGER DEFAULT DBMS_SQL.OPEN_CURSOR;

        L_COLUMNVALUE VARCHAR2(4000);

        L_STATUS INTEGER;

        L_COLCNT NUMBER := 0;

        L_SEPARATOR VARCHAR2(1);
        L_SEPARATOR1 VARCHAR2(1);

        L_DESCTBL DBMS_SQL.DESC_TAB;

        P_MAX_LINESIZE NUMBER := 32000;

BEGIN

        --OPEN FILE

        L_OUTPUT := UTL_FILE.FOPEN(P_DIR, P_FILENAME, 'W', P_MAX_LINESIZE);

 

        --DEFINE DATE FORMAT

        EXECUTE IMMEDIATE 'ALTER SESSION SET NLS_DATE_FORMAT='' YYYY-MM-DD HH24:MI:SS''';

 

        --OPEN CURSOR

        DBMS_SQL.PARSE( L_THECURSOR, P_QUERY, DBMS_SQL.NATIVE );

        DBMS_SQL.DESCRIBE_COLUMNS( L_THECURSOR, L_COLCNT, L_DESCTBL );

 

        --DUMP TABLE COLUMN NAME

        FOR I IN 1 .. L_COLCNT LOOP

            UTL_FILE.PUT( L_OUTPUT, L_SEPARATOR || '"' || L_DESCTBL(I).COL_NAME || '"' );

            DBMS_SQL.DEFINE_COLUMN( L_THECURSOR, I, L_COLUMNVALUE, 4000 );

            L_SEPARATOR := ',';

        END LOOP;

        UTL_FILE.NEW_LINE( L_OUTPUT );

 

        --EXECUTE THE QUERY STATEMENT

        L_STATUS := DBMS_SQL.EXECUTE(L_THECURSOR);

 

        --DUMP TABLE COLUMN VALUE

       WHILE ( DBMS_SQL.FETCH_ROWS(L_THECURSOR) > 0 ) LOOP

           L_SEPARATOR := '';

            FOR I IN 1 .. L_COLCNT LOOP

                DBMS_SQL.COLUMN_VALUE( L_THECURSOR, I, L_COLUMNVALUE );

                UTL_FILE.PUT( L_OUTPUT, L_SEPARATOR || '"' ||

                TRIM(BOTH ' ' FROM REPLACE(L_COLUMNVALUE,'"','')) || '"');

                L_SEPARATOR := ',';

            END LOOP;

            UTL_FILE.NEW_LINE( L_OUTPUT );

        END LOOP;

 

        --CLOSE CURSOR

        DBMS_SQL.CLOSE_CURSOR(L_THECURSOR);

 

        --CLOSE FILE

        UTL_FILE.FCLOSE( L_OUTPUT );

EXCEPTION

        WHEN OTHERS THEN

        RAISE;

END;

 

4、测试存储过程，将查询结果导出到example.csv中：

declare

 fhandle utl_file.file_type;

 begin

    sql_to_csv('select * from newstable ','MYDIR','example.csv');

 end;