基于开收盘价格间的相对关系变化进行判断，策略如下：
策略说明:
本策略计算指数移动平均(10个开盘价和10个收盘价, 然后后者减去前者得到柱状图)，通过柱状图上穿零轴还是下穿零轴来判断上升和下降趋势
系统要素:
1. 10个开盘价的指数移动平均与10个收盘价的指数移动平均之差若上穿零轴定义为上升趋势，上升趋势定义满足后将上穿K线的最高价加上10周期的ATR的一半作为多头入场触发价，同时将上穿K线的最低价减去10周期的ATR的一半作为多头平仓触发价；
2. 10个开盘价的指数移动平均与10个收盘价的指数移动平均之差若下穿零轴定义为下降趋势，下降趋势定义满足后将下穿K线的最低价减去10周期的ATR的一半作为空头入场触发价，同时将下穿K线的最高价加上10周期的ATR的一半作为空头平仓触发价；
入场条件:
1. 10个开盘价的指数移动平均大于10个收盘价的指数移动平均并且向上突破了多头触发价则进场做多；
2. 10个开盘价的指数移动平均小于10个收盘价的指数移动平均并且向下突破了空头触发价则进场做空；
出场条件:
1. 跌破多头平仓触发价或者转为下降趋势多头平仓；
2. 突破空头平仓触发价或者转为上升趋势空头平仓；
做多的代码解读如下：
Params
Numeric OpenLen(10); //声明数值参数OpenLeng，初值10，用于计算开盘价指数移动平均的周期。//
Numeric CloseLen(10); //声明数值参数CloseLen，初值10，用于计算收盘价指数移动平均的周期。//
Vars
NumericSeries Histogram(0); //声明数值序列变量Histogram，初值0，记录开盘价的指数移动平均与收盘价的指数移动平均之差。//
NumericSeries BuyPrice(0); //声明数值序列变量BuyPrice，初值0，多头触发价格。//
NumericSeries LongExitPrice(0); //声明数值序列变量LongExitPrice，初值0，多头平仓触发价格。//
BoolSeries con1; //声明布尔型序列变量con1，判断是否为上升趋势。//
BoolSeries con2; //声明布尔型序列变量con2，判断是否为下降趋势。//
NumericSeries ATR10(0); //声明数值序列变量ATR10，初值0.//
Begin
If(!CallAuctionFilter()) Return;// 集合竞价和小节休息过滤。//
//条件设置。//
Histogram = XAverage(Close,CloseLen) - XAverage(Open,OpenLen);//把收盘价指数均值减去开盘价指数均值，即可得变量Histogram值。//
con1=CrossOver(Histogram,0);//条件1，变量Histogram穿越0线。//
con2=CrossUnder(Histogram,0);//条件2，变量Histogram跌破0线。//
ATR10=Average(TrueRange,10);//求10周期的波动均值。//
//设置多头入场触发价与多头平仓触发价。//
If(con1)//假如条件1成立。//
{
BuyPrice = High + ATR10*0.5;//进场价的算法。//
LongExitPrice = Low - ATR10*0.5;//多头平仓价算法。//
}
//满足上升趋势且向上突破触发价则进场做多。//
If(Histogram[1]>0 And Vol > 0)//假如前一变量Histogram大于0，且成交量大于0.//
{
if(High>=BuyPrice) //假如当前最高价大于等于进场价。//
Buy(0,Max(Open,BuyPrice));//开仓买入，价格为当前开盘价与进场价的比较，取较大者。//
}
//转为下降趋势多头平仓出场。//
If(MarketPosition==1 And BarsSinceEntry>0 And con2[1] And Vol > 0) //假如持有多单，且建仓数位大于0，且前一个条件2成立，且成交量大于0.//
{
Sell(0,Open);//以开盘价平仓。//
}
//向下突破多头平仓触发价格则多头平仓出场。//
If(MarketPosition==1 And BarsSinceEntry>0 And low<=LongExitPrice And Vol > 0) //当前持有多单，建仓数位大于0，且当前最低价小于等于出场价，且成交量大于0 .//
{
Sell(0,Min(Open,LongExitPrice));//平仓，开盘价与出场价比较，取较小值。//
}
//在图表上显示多头进场触发价格与多头平仓触发价格。//
if(MarketPosition==0 and Histogram>0 and BuyPrice>0) PlotNumeric("BuyPrice",BuyPrice); //画线进场价。//
if(MarketPosition==1) PlotNumeric("LongExitPrice",LongExitPrice); //画线出场价。//
End
做空的代码及结果如下：
Params
Numeric OpenLen(10);
Numeric CloseLen(10);
Vars
NumericSeries Histogram(0);
NumericSeries SellPrice(0);
NumericSeries ShortExitPrice(0);
BoolSeries con1;
BoolSeries con2;
NumericSeries ATR10(0);
Begin
If(!CallAuctionFilter()) Return;
Histogram = XAverage(Close,CloseLen) - XAverage(Open,OpenLen);
con1=CrossOver(Histogram,0);
con2=CrossUnder(Histogram,0);
ATR10=Average(TrueRange,10);
if(con2)
{
SellPrice=Low-ATR10*0.5;
ShortExitPrice=High+ATR10*0.5;
}
if(Histogram[1]<0 And Vol > 0)
{
if(low<=SellPrice) SellShort(0,Min(Open,SellPrice));
}
if(MarketPosition==-1 and BarsSinceEntry>0 And con1[1] And Vol > 0)
{
BuyToCover(0,Open);
}
if(MarketPosition==-1 and BarsSinceEntry>0 And High>=ShortExitPrice And Vol > 0)
{
BuyToCover(0,Max(Open,ShortExitPrice));
}
if(MarketPosition==0 and histogram<0 and SellPrice>0) PlotNumeric("SellPrice",SellPrice);
if(MarketPosition==-1) PlotNumeric("ShortExitPrice",ShortExitPrice);
End