SAS编程：输出SAS数据集(Listing)到EXCEL

临床试验SAS编程中，Listing的输出一般分为两类，一是输出到Excel中，二是输出到RTF中。这两类除了文本格式的区别外，展示也稍有不同。

除了Listing输出，日常数据信息的查询，也可能需要将SAS数据集输出到Excel中。通常，使用export过程步，进行简单的输出；使用ods excel语句以及report过程步，进行复杂的输出设置，例如，冻结标题、首行自动筛选等。

这篇文章介绍，后者的相关处理，以及如何输出多个数据集到同一Excel文件中。

1. 输出单个数据集到Excel中

输出设置

主体的输出程序是ods excel语句，数据用report过程步展示：

ods excel file = "E:\Test\class.xlsx";

proc report data = sashelp.class;
  column _all_;
run;

ods excel close;

Class

以上是默认输出内容，看起来挺美观，但有两点需要更新。第一，Sheet的名称；第二，Listing输出一般需要添加Title。.

实现这两点，需要使用ods excel语句的2个选项sheet_name=和embedd_titles=。

ods excel file = "E:\Test\class.xlsx" 
  options(sheet_name="Class" embedded_titles = "Yes");

title1 justify = center "Class students";
title2 j = c "Basic Information";

proc report data = sashelp.class;
  column _all_;
run;

ods excel close;

Class

ods excel语句还有一些其他常用选项，这些选项的应用会方便数据查询。

选项frozen_headers="Yes"，将Excel中Header以上内容进行冻结；选项autofilter="ALL"，首行自动筛选；选项absolute_column_width="number-list"，设置变量列宽。

ods excel file = "E:\Test\class.xlsx" 
  options(sheet_name="Class" embedded_titles = "Yes" frozen_headers="Yes"  autofilter="ALL"  absolute_column_width="10, 10, 10, 15, 15");

title1 justify = center "Class students";
title2 j = c "Basic Information";

proc report data = sashelp.class;
  column _all_;
run;

ods excel close;

关于ods excel语句的其他选项，参考SAS官方文档SAS Help Center: ODS EXCEL Statement。

单元格样式设置

如果想要对Header显示的内容、格式进行调整，具体在report过程步中进行整理。

proc report data = sashelp.class 
  style(header)={background=#ffffff font_size=10pt  font_weight=bold cellwidth=2in}
  style(column)={background=#ffddff font_size=10pt};
  column _all_;
run;

如果想要对具体变量显示内容进行调整，具体在report过程步的define语句中进行整理。

proc report data = sashelp.class;
  column _all_;
  define name/ display "Last Name" style=[cellwidth=1in];
run;

具体report过程步语法，参考官方文档SAS Help Center: REPORT Procedure。

Issue处理

如果遇到以下Warning，可以在ods excel语句前添加goptions device=png;语句，移除这个Warning。

WARNING: Unsupported device 'SVG' for EXCEL destination. Using default device 'PNG'.

如果输出时遇到以下Error，可以通过在proc report语句前面添加ods listing close;语句，移除这个Error。

ERROR: The width of is not between 1 and 256. Adjust the column width or linesize.

2. 输出多个数据集到EXCEL中

以上举例是输出一个数据集到Excel的文件中，通常还会输出多个数据集到Excel的不同Sheet中。这个需要在前一段代码后接上一个新的ods excel语句，此时需要省略file=选项，否则SAS会报错。

ods excel file = "E:\Test\sashelp.xlsx" 
 options(sheet_name="Class" embedded_titles = "Yes" frozen_headers="Yes");

title1 justify = center "Class students";
title2 j = c "Basic Information";

proc report data = sashelp.class;
 column _all_;
run;


ods excel 
 options(sheet_name="Cars" embedded_titles = "Yes" frozen_headers="Yes");

title1 justify = center "2004 Car Data";
title2 j = c "Basic Information";

proc report data = sashelp.cars;
 column _all_;
run;

ods excel close;

Cars

从结果看，两个数据集都输出到Excel中，位于不同的Sheet。两个以上数据集的输出，以此类推，这里不再举例演示。

总结

文章介绍了如何将SAS数据集到Excel中，一些常用的输出选项，以及常见Issue处理。同时，也介绍了如何输出多个数据集到Excel中。

感谢阅读， 欢迎关注：SAS茶谈！
若有疑问，欢迎评论交流！