bat快速设置Windows锁屏时间

        快速设置Windows的锁屏时间。

@echo off
title Windows定时锁定管理器
mode con cols=80 lines=30

%1 %2
ver|find "5.">nul&&goto :Admin
mshta vbscript:createobject("shell.application").shellexecute("%~s0","goto :Admin","","runas",1)(window.close)&goto :eof
:Admin

echo.
echo *============================注意事项============================*
echo ^|                                                                ^|
echo ^|  1.本设定指定分钟数锁屏,需要手动重启计算机以生效;             ^|
echo ^|                                                                ^|
echo ^|  2.注意杀毒软件提示,选择允许;                                 ^|
echo ^|                                                                ^|
echo *================================================================*
echo.

:input
set /p minutes=请输入锁屏的分钟数:
if "%minutes%"=="" goto input
if %minutes% leq 10080 (if %minutes% geq 1 (goto register) else (goto error)) else (goto error)

:register
set /a sec=%minutes%*60
reg add HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System /v InactivityTimeoutSecs /t REG_DWORD /d %sec% /f > nul
echo.
echo 操作成功完成,重启后生效,系统将在无活动状态%minutes%分钟后自动锁屏!
goto end

:error
echo 您输入的数值范围出错,请输入1到10080之间的数值。
goto input

:end
echo.
echo.
echo 请按任意键退出...
pause > nul

 

 

你可能感兴趣的:(bat,windows,运维)