fields list of table

// Copyright (C), 2014, CEU Co., Ltd.
// USR Changed by 2014-10-14T12:27:59 Fandy Xie 谢宇帆
// Version       : 1.0
// Description   : 得到table/view的fields清单
// Return        :
static map getTableFieldsMap(tableId    _tableId)
{
    DictTable       dicTable;
    DictField       dictField, dfArray;
    set             setLabel    = new set(types::String);
    map             mapField    = new map(types::Integer, types::String);
    mapEnumerator   me;

    fieldId         fieldId;
    int             a, fieldCnt,m;
    name            fieldName, fieldLabel;
    container       con, fieldCon;
    identifiername  extend;
    types           type;
    ;

    dicTable    = new DictTable(_tableId);
    fieldCnt    = dicTable.fieldCnt();

    if(dicTable.isMap())// || dicTable.isSystemTable() || dicTable.isView())
        return mapField;
    for(m = 1;m <= fieldCnt; m++)
    {
        dictField   = new DictField(dicTable.id(),dicTable.fieldCnt2Id(m));
        fieldId     = dictField.id();
        fieldName   = dictField.name(dbBackend::Sql);
        fieldLabel  = dictField.label();
        type        = dictField.baseType();
        if(dictField.isSystem() && fieldName != "DATAAREAID")
            continue;
        if (!fieldName)
            continue;
        if (type == types::Container)
            continue;
        if (fieldName like "del_*")
            continue;

        extend = global::extendedTypeId2name(dictField.typeId());
        if (dictField.arraySize() > 1) // 数组 Dimension
        {
            for(a = 1; a <= dictField.arraySize(); a++)
            {
                dfArray     = new dictField(dicTable.id(), fieldId2Ext(dictField.id(), a));
                fieldId     = dfArray.id();
                fieldName   = dfArray.name(dbBackend::Sql);
                fieldLabel  = dfArray.label();
                if (!fieldLabel)
                    fieldLabel = fieldName;

                if (setLabel.in(fieldLabel))
                    continue;
                setLabel.add(fieldLabel);
                mapField.insert(fieldId, fieldName);
            }
        }
        else
        {
            if (!fieldLabel)
                fieldLabel = fieldName;
            if (setLabel.in(fieldLabel))
                continue;
            setLabel.add(fieldLabel);
            mapField.insert(fieldId, fieldName);
        }
    }

    return mapField;
}