Windows 编程[11] - WM_SIZE 消息

本例效果图:

program Project1;

uses
  Windows, Messages;

{供 WM_SIZE 消息调用的自定义过程}
procedure OnSize(h: HWND);
var
  Rect: TRect;
  pt: TPoint;
  buf: array[0..255] of Char;
begin
  GetWindowRect(h, Rect);                  {获取窗口矩形}
  pt.X := Rect.Right - Rect.Left;          {提取宽度}
  pt.Y := Rect.Bottom - Rect.Top;          {提取高度}
  wvsprintf(buf, '宽度:%d, 高度:%d', @pt);  {格式化到缓冲区}
  SetWindowText(h, buf);                   {显示在标题}
end;

function WndProc(wnd: HWND; msg: UINT; wParam: Integer; lParam: Integer): Integer; stdcall;
begin
  Result := 0;
  case msg of
    WM_SIZE    : OnSize(wnd);       {改变窗口大小的消息}
    WM_DESTROY : PostQuitMessage(0);
  else
    Result := DefWindowProc(wnd, msg, wParam, lParam);
  end;
end;

function RegMyWndClass: Boolean;
var
  cls: TWndClass;
begin
  cls.style         := CS_HREDRAW or CS_VREDRAW;
  cls.lpfnWndProc   := @WndProc;
  cls.cbClsExtra    := 0;
  cls.cbWndExtra    := 0;
  cls.hInstance     := HInstance;
  cls.hIcon         := 0;
  cls.hCursor       := LoadCursor(0, IDC_ARROW);
  cls.hbrBackground := HBRUSH(COLOR_WINDOW + 1);
  cls.lpszMenuName  := nil;
  cls.lpszClassName := 'MyWnd';
  Result := RegisterClass(cls) <> 0;
end;

{程序入口}
const
  tit = 'New Form';
  ws = WS_OVERLAPPEDWINDOW;
  x = 100; y = 100; w = 300; h = 180;
var
  hWnd: THandle;
  Msg : TMsg;
begin
  RegMyWndClass;
  hWnd := CreateWindow('MyWnd', tit, ws, x, y, w, h, 0, 0, HInstance, nil);
  ShowWindow(hWnd, SW_SHOWNORMAL);
  UpdateWindow(hWnd);

  while(GetMessage(Msg, 0, 0, 0)) do
  begin
    TranslateMessage(Msg);
    DispatchMessage(Msg);
  end;
end.