puppet资源yumrepo详细介绍（附案例）

The client-side description of a yum repository. Repository configurations are found by parsing /etc/yum.conf and the files indicated by the reposdir option in that file (see yum.conf(5) for details).

Most parameters are identical to the ones documented in the yum.conf(5) man page.

Continuation lines that yum supports (for the baseurl, for example) are not supported. This type does not attempt to read or verify the exinstence of files listed in the include attribute.

yumrepo资源参数详解

Attributes
yumrepo { 'resource title':
  name            => # (namevar) The name of the repository.  This corresponds to 
  baseurl         => # The URL for this repository. Set this to...
  cost            => # Cost of this repository. Set this to `absent` to 
  descr           => # A human-readable description of the repository...
  enabled         => # Whether this repository is enabled, as...
  enablegroups    => # Whether yum will allow the use of package groups 
  exclude         => # List of shell globs. Matching packages will...
  failovermethod  => # The failover methode for this repository; should 
  gpgcheck        => # Whether to check the GPG signature on packages...
  gpgkey          => # The URL for the GPG key with which packages from 
  http_caching    => # What to cache from this repository. Set this to...
  include         => # The URL of a remote file containing additional...
  includepkgs     => # List of shell globs. If this is set, only...
  keepalive       => # Whether HTTP/1.1 keepalive should be used with...
  metadata_expire => # Number of seconds after which the metadata will...
  mirrorlist      => # The URL that holds the list of mirrors for this...
  priority        => # Priority of this repository from 1-99. Requires...
  protect         => # Enable or disable protection for this...
  proxy           => # URL to the proxy server for this repository. Set 
  proxy_password  => # Password for this proxy. Set this to `absent` to 
  proxy_username  => # Username for this proxy. Set this to `absent` to 
  s3_enabled      => # Access the repo via S3. Set this to `absent` to...
  sslcacert       => # Path to the directory containing the databases...
  sslclientcert   => # Path  to the SSL client certificate yum should...
  sslclientkey    => # Path to the SSL client key yum should use to...
  sslverify       => # Should yum verify SSL certificates/hosts at all. 
  timeout         => # Number of seconds to wait for a connection...
  # ...plus any applicable metaparameters.
}

备注：更多有关yumrepo资源的资料可以访问官网http://docs.puppetlabs.com/references/stable/type.html#yumrepo

举例说明：

一、yum模块的目录结构树

[root@linuxmaster1poc modules]# tree yum
yum
├── files
│   ├── etc
│   │   └── yum.conf
│   └── PM-GPG-KEY
│       ├── RPM-GPG-KEY-puppet-release
│       ├── RPM-GPG-KEY-redhat-release-rhel5
│       └── RPM-GPG-KEY-redhat-release-rhel6
├── manifests
│   ├── config.pp
│   ├── init.pp
│   ├── install.pp
│   └── params.pp
└── templates
5 directories, 8 files

二、yum模块source资源

[root@linuxmaster1poc modules]# cat yum/files/etc/yum.conf 
##---File Managed by Puppet---##
[main]
cachedir=/var/cache/yum
keepcache=0
debuglevel=2
logfile=/var/log/yum.log
distroverpkg=redhat-release
tolerant=1
exactarch=1
obsoletes=1
gpgcheck=1
plugins=1
# Note: yum-RHN-plugin doesn't honor this.
metadata_expire=1h
# installonly_limit = 3
# PUT YOUR REPOS HERE OR IN separate files named file.repo
# in /etc/yum.repos.d

三、yum模块pp文件

1、init.pp文件，包含模块其他类

[root@linuxmaster1poc modules]# cat yum/manifests/init.pp 
class yum{
  include yum::config,yum::install
}

2、install.pp文件，定义安装包的class

[root@linuxmaster1poc modules]# cat yum/manifests/install.pp 
class yum::install{
  package { 'yum':
    ensure => installed,
  }
}

3、config.pp文件，定义file、yumrepo资源

[root@linuxmaster1poc modules]# cat yum/manifests/config.pp 
class yum::config{
  include yum::params 
  include yum::config_file,yum::config_key,yum::config_repo
}
class yum::config_file{
  file { '/etc/yum.conf':
    ensure  => present,
    owner   => 'root',
    group   => 'root',
    mode    => '0644',
    backup  => main,
    source  => 'puppet:///modules/yum/etc/yum.conf',
    require => Class['yum::install'],
  }
  file { '/etc/yum.repos.d/rhel-base.repo':
     ensure  => present,
     owner   => 'root',
     group   => 'root',
     mode    => '0644',
     backup  => main,
     require => Class['yum::config_repo'],
  }
  file { '/etc/yum.repos.d/puppet.repo':
    ensure  => present,
    owner   => 'root',
    group   => 'root',
    mode    => '0644',
    backup  => main,
    require => Class['yum::config_repo'],
  }
}
class yum::config_key{
  file { $yum::params::yum_redhat_pki_name:
    ensure => present,
    owner  => 'root',
    group  => 'root',
    mode   => '0644',
    backup => main,
    source => $yum::params::yum_redhat_pki_download,
  }
}
class yum::config_repo{
  yumrepo { rhel-base:
    descr     => $yum::params::yum_redhat_descr,
    baseurl   => $yum::params::yum_redhat_baseurl,
    enabled   => 1,
    gpgcheck  => 1,
    gpgkey    => $yum::params::yum_redhat_pki,
    require   => Class['yum::config_key'],
    priority  => 1,
  }
  yumrepo { rhel-puppet:
    descr     => $yum::params::yum_puppet_descr,
    baseurl   => $yum::params::yum_puppet_baseurl,
    enabled   => 1,
    gpgcheck  => 0,
    priority  => 2,
  }
}

4、定义params.pp文件，定义各种操作系统环境的变量，方便其他class调用

[root@linuxmaster1poc modules]# cat yum/manifests/params.pp 
class yum::params {
  case $operatingsystemrelease{
    5.7: {
      $yum_redhat_descr = 'rhel base rpm packages'
      $yum_puppet_descr = 'puppet rpm packages for rhel'
      $yum_redhat_pki = 'file:///etc/pki/rpm-gpg/RPM-GPG-KEY-redhat-release-rhel5'
      $yum_redhat_baseurl = 'file:///media/cdrom/Server'
      $yum_puppet_baseurl = 'ftp://192.168.100.120/RHEL5U7'
      $yum_redhat_pki_name = '/etc/pki/rpm-gpg/RPM-GPG-KEY-redhat-release-rhel5'
      $yum_redhat_pki_download = 'puppet:///modules/yum/PM-GPG-KEY/RPM-GPG-KEY-redhat-release-rhel5' 
    }
    5.8: {
      $yum_redhat_descr = 'rhel base rpm packages'
      $yum_puppet_descr = 'puppet rpm packages for rhel'
      $yum_redhat_pki = 'file:///etc/pki/rpm-gpg/RPM-GPG-KEY-redhat-release-rhel5'
      $yum_redhat_baseurl = 'file:///media/cdrom/Server'
      $yum_puppet_baseurl = 'ftp://192.168.100.120/RHEL5U8'
      $yum_redhat_pki_name = '/etc/pki/rpm-gpg/RPM-GPG-KEY-redhat-release-rhel5'
      $yum_redhat_pki_download = 'puppet:///modules/yum/PM-GPG-KEY/RPM-GPG-KEY-redhat-release-rhel5'
    }
    6.4: {
      $yum_redhat_descr = 'rhel base rpm packages'
      $yum_puppet_descr = 'puppet rpm packages for rhel'
      $yum_redhat_pki = 'file:///etc/pki/rpm-gpg/RPM-GPG-KEY-redhat-release-rhel6'
      $yum_redhat_baseurl = 'file:///media/cdrom'
      $yum_puppet_baseurl = 'ftp://192.168.100.120/RHEL6U4'
      $yum_redhat_pki_name = '/etc/pki/rpm-gpg/RPM-GPG-KEY-redhat-release-rhel6'
      $yum_redhat_pki_download = 'puppet:///modules/yum/PM-GPG-KEY/RPM-GPG-KEY-redhat-release-rhel6'
    }
  }
}

PS: yumrepo资源可以通过file资源进行管理，这个可以根据实际情况而定！

原文链接：http://kisspuppet.com/2013/12/07/puppet_yum_repo/