【AD】WinXP Win7x64 自动加域脚本

http://bbs.51cto.com/thread-968398-1.html

受到链接中专家的启发，以及网上的一些资料。

自己写了一个win7x64 winxp加域退域脚本。测试DC是Server2008R2。

使用方法。

以win7x64为例

将AD文件夹整个放到C盘根目录下。

内部文件

将目标BAT内的Domain，DNS和帐号密码都换成你自己的。

然后右击其中的加域，运行。

界面大致如图

根据提示一步一步操作。

退域也类似。

这个和链接中的区别是不需要先更改名再重启再加域，而是可以先加域，然后直接改名，重启一次就够了。

xp的需要在管理员帐号下运行。

贴下win7x64的代码：

改DNS加域改电脑名：

@echo off

color 2f

title 请用系统管理员权限运行此加域脚本

set primarydns=192.168.1.100

set domain=xifan.sz.com

set admin=administrator

set password=12345

echo.

echo.

echo  运行前请检查脚本内的DNS,DOMAIN,ADMIN,PASSWORD

echo.

echo  在实机操作前请先于虚拟环境下测试过

:start

echo.

echo.                                      

echo  ****************************　是否更改DNS　****************************

echo.

Set /p DNS=[更改输入Y 不更改输入N 退出请输入 Q ]:  

IF "%dns%"=="y" GoTo dns

IF "%dns%"=="n" GoTo ad

if "%dns%"=="q" goto exit

echo 输入错误请重新输入 & goto start

:dns

netsh interface ip add dnsservers name=本地连接 address=%primarydns% index=1

:ad

echo.                                                           　

echo  ***********************　将计算机加入域并选择是否更改电脑名***********************

echo.                                      

C:\AD\Win7x64\netdom.exe join %computername% /domain:%domain% /UserD:%admin% /PasswordD:%password%

echo ****输入要更改的新的电脑名称或不更改直接退出****

set /p newname=输入新电脑名并重启 或 不改名直接退出请输入Q:

IF "%newname%"=="q" goto exit

echo 改名后5秒后重新启动

echo y|C:\AD\Win7x64\netdom.exe renamecomputer %computername% /newname:%newname% /UserD:%admin% /PasswordD:%password% /reboot:5

:exit

exit

-----------------------

退域

@echo off

color 2f

title 请以管理员权限执行此脚本

echo.

echo 使用前请确认Domain,Admin,Password

echo.

echo 实机测试前请劲量在虚拟机环境中测试

echo.

ping 127.0.0.1 -n 3 >nul

set dm=xifan.sz.com

set ad=administrator

set pd=12345

C:\AD\Win7x64\netdom.exe remove %computername% /domain:%dm% /UserD:%ad% /PasswordD:%pd%

ping 127.0.0.1 -n 3 >nul

echo.

echo.

echo 点击继续将在5s后重启 要关闭请直接点右上角X

echo.

echo.

pause

shutdown /r /t 5 /f

这个其实主要是用来在系统封装后自动加域。

下载链接：

http://pan.baidu.com/s/1ntu2Rnb

如有问题，欢迎讨论