u-boot.lds分析（u-boot-1.3.4 nandflash启动 引导linux内核）

     u-boot.lds决定了u-boot可执行映像的连接方式，以及各个段的装载地址（装载域）和执行地址（运行域）。

GNU官方网站上对.lds文件形式的完整描述：

SECTIONS {
...
secname start BLOCK(align) (NOLOAD) : AT ( ldadr )
{ contents } >region :phdr =fill
...
}
secname和contents是必须的，前者用来命名这个段，后者用来确定代码中的什么部分放在这个段，以下是对这个描述中的一些关键字的解释。
secname：段名
contents：决定哪些内容放在本段，可以是整个目标文件，也可以是目标文件中的某段（代码段、数据段等）
start：是段的重定位地址，本段连接（运行）的地址，如果代码中有位置无关指令，程序运行时这个段必须放在这个地址上。start可以用任意一种描述地址的符号来描述。
AT（ldadr）：定义本段存储（加载）的地址，如果不使用这个选项，则加载地址等于运行地址，通过这个选项可以控制各段分别保存于输出文件中不同的位置。
例：

/* nand.lds */
SECTIONS {
firtst 0x00000000 : { head.o init.o }
second 0x30000000 : AT(4096) { main.o }
}
以上，head.o放在0x00000000地址开始处，init.o放在head.o后面，他们的运行地址也是0x00000000，即连接和存储地址相同（没有AT指定）；

main.o放在4096（0x1000，是AT指定的，存储地址）开始处，但它的运行地址在0x30000000，运行之前需要从0x1000（加载地址处）复制到0x30000000（运行地址处），此过程也就需要读取 flash，把程序拷贝到相应位置才能运行。这就是存储地址和运行地址的不同，称为加载时域和运行时域，可以在.lds连接脚本文件中分别指定。

装载地址－－－》运行之前各段的地址

运行地址－－－》运行时各段的地址

编写好的.lds文件，在用arm-linux-ld连接命令时带-Tfilename来调用执行，如
arm-linux-ld -Tnand.lds x.o y.o -o xy.o。也用-Ttext参数直接指定连接地址，如
arm-linux-ld -Ttext 0x30000000 x.o y.o -o xy.o。
既然程序有了两种地址，就涉及到一些跳转指令的区别。
ARM汇编中，常有两种跳转方法：b跳转指令、ldr指令向PC赋值。
要特别注意这两条指令的意思：
（1） b step：b跳转指令是相对跳转，依赖当前PC的值，偏移量是通过该指令本身的 bit[23:0]算出来的，这使得使用b指令的程序不依赖于要跳到的代码的位置，只看指令本身。
（2） ldr pc, =step ：该指令是一个伪指令编译后会生成以下代码：
ldr pc, 0x30008000
<0x30008000>
step是从内存中的某个位置（step）读出数据并赋给PC，同样依赖当前PC的值，但是偏移量是step的连接地址（运行时的地址），所以可以用它实现从Flash到RAM的程序跳转。
（3） 此外，有必要回味一下adr伪指令，U-boot中那段relocate代码就是通过adr实现当前程序是在RAM中还是flash中：
relocate: /* 把U-Boot重新定位到RAM */
adr r0, _start /* r0是代码的当前位置 */
/* adr伪指令，汇编器自动通过当前PC的值算出这条指令中"_start"的值，执行到_start时PC的值放到r0中：
当此段在flash中执行时r0 = _start = 0；当此段在RAM中执行时_start = _TEXT_BASE(在board/smdk2410/config.mk中指定的值为0x33F80000，即u-boot在把代码拷贝到RAM中去执行的代码段的开始) */
ldr r1, _TEXT_BASE /* 测试判断是从Flash启动，还是RAM */
/* 此句执行的结果r1始终是0x33FF80000，因为此值是链接指定的 */
cmp r0, r1 /* 比较r0和r1，调试的时候不要执行重定位 */

 

下面是u-boot-1.3.4的u-boot.lds连接脚本，简单分析如下：

O UTPUT_FORMAT("elf32-littlearm" , "elf32-littlearm", "elf32-littlearm")
/* 指定输出可执行文件是elf格式,32位ARM指令,小端   */
/*OUTPUT_FORMAT("elf32-arm", "elf32-arm", "elf32-arm")*/
OUTPUT_ARCH(arm)   /* 指定输出文件的平台体系是 ARM  */
ENTRY(_start)   /*  指定可执行映像文件的起始段的段名是_start */
SECTIONS
{
    /* 指定可执行image文件的全局入口点，通常这个地址都放在ROM(flash)0x0位置。必须使编译器知道这个地址，通常都是修改此处来完成 */
    . = 0x00000000;   /* 起始地址为0x00000000  */

    . = ALIGN(4);     /* 字对齐，即就是4字节对齐 */
    .text      :      /* 代码段 */
    {
      cpu/arm920t/start.o    (.text)   /*  代码段第一部分代码*/
      board/fs2410/lowlevel_init.o  (.text)   /*  代码段第二部分 ，这段由自己添加，由于在编译连接时发现，lowlevel_init.o代码段总是被连接在4kB之后，导致start.s执行到该段代码时，总是无法找到这段代码（注明：从nandflash启动才会存在这个问题）。*/
      *(.text)   /*其余代码段*/
    }

    . = ALIGN(4);
    .rodata : { *(.rodata) }   /*  只读数据段 ，所有的只读数据段都放在这个位置*/

    . = ALIGN(4);
    .data : { *(.data) }      /* 可读写数据段，所有的可读写数据段都放在这里 */

    . = ALIGN(4);
    .got : { *(.got) }       /*指定got段, got段式是uboot自定义的一个段, 非标准段*/

    . = .;
    __u_boot_cmd_start = .;    /*把__u_boot_cmd_start赋值为当前位置, 即起始位置*/
    .u_boot_cmd : { *(.u_boot_cmd) }  /*  u_boot_cmd段，所有的u-boot命令相关的定义都放在这个位置，因为每个命令定义等长，所以只要以__u_boot_cmd_start为起始地址 进行查找就可以很快查找到某一个命令的定义，并依据定义的命令指针调用相应的函数进行处理用户的任务*/
    __u_boot_cmd_end = .;     /* u_boot_cmd段结束位置，由此可以看出，这段空间的长度并没有严格限制，用户可以添加一些u-boot的命令，最终都会在连接是存放在这个位置。*/

    . = ALIGN(4);
    __bss_start = .;               /*把__bss_start赋值为当前位置,即bss段的开始位置*/
    .bss (NOLOAD) : { *(.bss) }    /*指定bss段，这里NOLOAD的意思是这段不需装载，仅在执行域中才会有这段*/
    _end = .;                      /*把_end赋值为当前位置,即bss段的结束位置*/
} 上面start.o中的代码装载地址和运行地址都为0x00000000,但是在start.o中会有一个u-boot自拷贝及重定位过程，start.o执行到最后时，整个u-boot已经被复制到了内存的TEXT_BASE(0x33f80000)位置，开始执行下面的跳转语句：
    ldr    pc, _start_armboot   /* 将标号_start_armboot的值传给pc，实际上是将start_armboot函数的首地址传给pc 但是此时的start_armboot应该是在内存中，因为start_armboot一定是在4kB之后，而nand flash 4kB之后的代码是无法直接访问的，必须先读入内存。而这时候u-boot的代码已经被拷贝并重定位到内存中，所以此处加在到pc的地址应当是内存中的地址，即33f800之后的某一地址 */
_start_armboot:    .word start_armboot 

上述均为个人理解，如有不正确之处，还请指正，谢谢！
问题：编译连接时是依据什么样的顺序来连接各个目标文件的？

start.S当然在上述文件中已经确定在第一个位置，那之后的文件会以什么样的顺序来连接呢？是调用关系吗？