sqlserver字符串拆分(split)方法汇总

declare @s varchar(100),@sql varchar(1000)
set @s='1,2,3,4,5,6,7,8,9,10,11'

 while(charindex(',',@s)<>0)
 begin
  --第一个','之前的字符串
  select substring(@s,1,charindex(',',@s)-1)
  --将第一个','后面的字符串重新赋给@ids
  set @s=stuff(@s,1,charindex(',',@s),'')
  --最后一个字符串
  if(charindex(',',@s)=0)
  begin
     select @s
  end
 end

参考以下

sqlserver字符串拆分(split)方法汇总

--方法0：动态SQL法
declare @s varchar(100),@sql varchar(1000)
set @s='1,2,3,4,5,6,7,8,9,10'
set @sql='select col='''+ replace(@s,',',''' union all select ''')+''''
PRINT @sql
exec (@sql)

 

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_splitSTR]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_splitSTR]
GO
--方法1：循环截取法
CREATE FUNCTION f_splitSTR(
@s   varchar(8000),   --待分拆的字符串
@split varchar(10)     --数据分隔符
)RETURNS @re TABLE(col varchar(100))
AS
BEGIN
 DECLARE @splitlen int
 SET @splitlen=LEN(@split+'a')-2
 WHILE CHARINDEX(@split,@s)>0
 BEGIN
  INSERT @re VALUES(LEFT(@s,CHARINDEX(@split,@s)-1))
  SET @s=STUFF(@s,1,CHARINDEX(@split,@s)+@splitlen,'')
 END
 INSERT @re VALUES(@s)
 RETURN
END
GO

 

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_splitSTR]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_splitSTR]
GO
--方法2：使用临时性分拆辅助表法
CREATE FUNCTION f_splitSTR(
@s   varchar(8000),  --待分拆的字符串
@split varchar(10)     --数据分隔符
)RETURNS @re TABLE(col varchar(100))
AS
BEGIN
 --创建分拆处理的辅助表(用户定义函数中只能操作表变量)
 DECLARE @t TABLE(ID int IDENTITY,b bit)
 INSERT @t(b) SELECT TOP 8000 0 FROM syscolumns a,syscolumns b

 INSERT @re SELECT SUBSTRING(@s,ID,CHARINDEX(@split,@s+@split,ID)-ID)
 FROM @t
 WHERE ID<=LEN(@s+'a')
  AND CHARINDEX(@split,@split+@s,ID)=ID
 RETURN
END
GO

 

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_splitSTR]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_splitSTR]
GO
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[tb_splitSTR]') and objectproperty(id,N'IsUserTable')=1)
drop table [dbo].[tb_splitSTR]
GO
--方法3：使用永久性分拆辅助表法
--字符串分拆辅助表
SELECT TOP 8000 ID=IDENTITY(int,1,1) INTO dbo.tb_splitSTR
FROM syscolumns a,syscolumns b
GO
--字符串分拆处理函数
CREATE FUNCTION f_splitSTR(
@s     varchar(8000),  --待分拆的字符串
@split  varchar(10)     --数据分隔符
)RETURNS TABLE
AS
RETURN(
 SELECT col=CAST(SUBSTRING(@s,ID,CHARINDEX(@split,@s+@split,ID)-ID) as varchar(100))
 FROM tb_splitSTR
 WHERE ID<=LEN(@s+'a')
  AND CHARINDEX(@split,@split+@s,ID)=ID)
GO

 

--方法4：利用sql server2005的OUTER APPLY

CREATE FUNCTION [dbo].[ufn_SplitStringToTable]
(
  @str VARCHAR(MAX) ,
  @split VARCHAR(10)
)
RETURNS TABLE
    AS
RETURN
    ( SELECT    B.id
      FROM      ( SELECT    [value] = CONVERT(XML , '<v>' + REPLACE(@str , @split , '</v><v>')
                            + '</v>')
                ) A
      OUTER APPLY ( SELECT  id = N.v.value('.' , 'varchar(100)')
                    FROM    A.[value].nodes('/v') N ( v )
                  ) B
    )

问题描述:有一个字符串,如"a,b,c,d,e,f,g",如何将该字符串中的a,b,c...分别提取出来执行增删改查呢??

熟悉java和.net语言的人应该都知道解决这个问题并不难,在java或.net中都有split()方法,该方法专门用于拆分字符串的,拆分后字符单元放在一个数组中作为返回值,用它便可轻松解决问题.

可现在我们是在SqlServer中,SqlServer中是没有split()方法和数组的.

 

怎么办呢??

 

既然有需求,就一定有解决方案.

记住:microsoft是一家伟大的公司!

只要你想到了,microsoft一定也想到了.

 

在sqlserver中有charIndex()方法、substring()方法和stuff()方法，运用这三个方法便可解决上述问题。

sqlserver中有多种拆分和批量拆分字符串的方案,在这里介绍两种方案

【方案一】

创建临时表一次性执行

 

sqlserver中是没有数组的概念的,因此我们用临时表作为数组

代码如下：

 

--创建一个临时表作为数组
create function f_split(@ids varchar(2000),@split varchar(2))
returns @t_split table(col varchar(20))
as
begin
 --循环找到字符串中第一个','的索引
 while(charindex(@split,@ids)<>0)
 begin
  --将第一个','之前的字符单元插入临时表中
  insert @t_split(col) values(substring(@ids,1,charindex(@split,@ids)-1))
  --将第一个','后面的字符串重新赋给@ids
  set @ids=stuff(@ids,1,charindex(@split,@ids),'')
 end
 --将最后一个字符单元插入表中(已经没有',')
 insert @t_split(col) values(@ids)
 return
end
go

临时表创建好了，可以作为一张表执行增加改查了。

select * from f_split('1,2,3,4,5,6,7',',')
drop function f_split

 

【方案二】

循环提取，分别执行

 

创建一个存储过程

代码如下：

create procedure proc_ModifyBookCategory
@CategoryId int,
@Ids varchar(2000) --要分割的字符串
as

--循环找到字符串中第一个','的索引
 while(charindex(',',@Ids)<>0)
 begin
  declare @id int;

--将字符单元截取出来赋给id,执行SQL语句
  set @id=substring(@ids,1,charindex(',',@Ids)-1)
  update Books set categoryId=@CategoryId whereId=@id

--截取剩余的字符串重新赋给Ids
  set @Ids=stuff(@Ids,1,charindex(',',@Ids),'')
 end

--字符串中没有‘，’了，则最后一个Ids为最后一个字符单元
 update Books set categoryId=@CategoryId whereId=@Ids
go