Javascript操作文件（FSO）

FileSystemObject (FSO) 对象模式，允许对大量的属性、方法和事件，使用较熟悉的 object.method 语法，来处理文件夹和文件。

使用这个基于对象的工具和：

• HTML 来创建 Web 页
• Windows Scripting Host 来为 Microsoft Windows 创建批文件
• Script Control 来对用其他语言开发的应用程序提供编辑脚本的能力

因为在客户端使用 FSO 而引起重要的安全性问题，提供潜在地不受欢迎的对客户端本地文件系统的访问，假定本文档使用 FSO 对象模式，来创建由服务器端的 Internet Web 页执行的脚本。因为使用了服务器端，Internet Explorer 默认安全设置不允许客户端使用 FileSystemObject 对象。覆盖那些默认值可能会引起在本地计算机上不受欢迎的对其文件系统的访问，从而导致文件系统完整性的全部破坏，同时引起数据遗失或更糟的情况。

FSO 对象模式使服务器端的应用程序能创建、改变、移动和删除文件夹，或探测特定的文件夹是否存在，若存在，还可以找出有关文件夹的信息，如名称、被创建或最后一次修改的日期，等等。

FSO 对象模式还使文件处理变得很容易。在处理文件时，主要的目标是以易于访问的格式把数据存储在有效的空间和资源中。这就要求能够创建文件，插入和改变数据，以及输出（读取）数据。因为把数据存储在数据库中，如 Access 或 SQL 服务器，会给应用程序增加很大的开销，所以把数据存储在二进制或文本文件中可能是最有效的解决方案。可能不希望有该开销，或者数据访问要求可能不需要与功能完备的数据库相关联的所有额外功能

处理文件

有两种主要的文件处理类型：

• 创建、添加或删除数据，以及读取文件
• 移动、复制和删除文件

创建文件

创建空文本文件（有时被叫做“文本流”）有三种方法。

第一种方法是用 CreateTextFile 方法。 下面的示例示范了在 VBScript 中如何用这种方法来创建文本文件：

Dim fso, f1
Set fso = CreateObject("Scripting.FileSystemObject")
Set f1 = fso.CreateTextFile("c:/testfile.txt", True)

要在 JScript 中用这种方法，则使用下面的代码：

var fso, f1;
fso = new ActiveXObject("Scripting.FileSystemObject");
f1 = fso.CreateTextFile("c://testfile.txt", true);

创建文本文件的第二种方法是，使用 FileSystemObject 对象的 OpenTextFile 方法，并设置 ForWriting 标志。在 VBScript 中，代码就像下面的示例一样：

Dim fso, ts
Const ForWriting = 2
Set fso = CreateObject("Scripting. FileSystemObject")
Set ts = fso.OpenTextFile("c:/test.txt", ForWriting, True)

要在 JScript 中使用这种方法来创建文本文件，则使用下面的代码：

var fso, ts;
var ForWriting= 2;
fso = new ActiveXObject("Scripting.FileSystemObject");
ts = fso.OpenTextFile("c://test.txt", ForWriting, true);

创建文本文件的第三种方法是，使用 OpenAsTextStream 方法，并设置 ForWriting 标志。要使用这种方法，在 VBScript 中使用下面的代码：

Dim fso, f1, ts
Const ForWriting = 2
Set fso = CreateObject("Scripting.FileSystemObject")
fso.CreateTextFile ("c:/test1.txt")
Set f1 = fso.GetFile("c:/test1.txt")
Set ts = f1.OpenAsTextStream(ForWriting, True)

在 JScript 中，则使用下面示例中的代码：

var fso, f1, ts;
var ForWriting = 2;
fso = new ActiveXObject("Scripting.FileSystemObject");
fso.CreateTextFile ("c://test1.txt");
f1 = fso.GetFile("c://test1.txt");
ts = f1.OpenAsTextStream(ForWriting, true);

添加数据到文件中

一旦创建了文本文件，使用下面的三个步骤向文件添加数据：

打开文本文件。

写入数据。

关闭文件。

要打开现有的文件，则使用 FileSystemObject 对象的 OpenTextFile 方法或 File 对象的 OpenAsTextStream 方法。

要写数据到打开的文本文件，则根据下表所述任务使用 TextStream 对象的 Write、WriteLine 或 WriteBlankLines 方法。

任务	方法
向打开的文本文件写数据，不用后续一个新行字符。	Write
向打开的文本文件写数据，后续一个新行字符。	WriteLine
向打开的文本文件写一个或多个空白行。	WriteBlankLines

要关闭一个打开的文件，则使用 TextStream 对象的 Close 方法。

注意  新行字符包含一个或几个字符（取决于操作系统），以把光标移动到下一行的开始位置（回车/换行）。注意某些字符串末尾可能已经有这个非打印字符了。

下面的 VBScript 例子示范了如何打开文件，和同时使用三种写方法来向文件添加数据，然后关闭文件：

Sub CreateFile()
   Dim fso, tf
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set tf = fso.CreateTextFile("c:/testfile.txt", True)
   ' 写一行，并且带有新行字符。
   tf.WriteLine("Testing 1, 2, 3.") 
   '向文件写三个新行字符。        
   tf.WriteBlankLines(3) 
   '写一行。
   tf.Write ("This is a test.") 
   tf.Close
End Sub

这个示例示范了在 JScript 中如何使用这三个方法：

function CreateFile()
{
   var fso, tf;
   fso = new ActiveXObject("Scripting.FileSystemObject");
   tf = fso.CreateTextFile("c://testfile.txt", true);
   // 写一行，并且带有新行字符。
   tf.WriteLine("Testing 1, 2, 3.") ;
   // 向文件写三个新行字符。  
   tf.WriteBlankLines(3) ;
   // 写一行。
   tf.Write ("This is a test.");
   tf.Close();
}

读取文件

要从文本文件读取数据，则使用 TextStream 对象的 Read、ReadLine 或 ReadAll 方法。下表描述了不同的任务应使用哪种方法。

任务	方法
从文件读取指定数量的字符。	Read
读取一整行（一直到但不包括新行字符）。	ReadLine
读取文本文件的整个内容。	ReadAll

如果使用 Read 或 ReadLine 方法，并且想跳过数据的特殊部分，则使用 Skip 或 SkipLine 方法。read 方法的结果文本存在一个字符串中，该字符串可以显示在一个控件中，也可以用字符串函数（如 Left、Right 和 Mid）来分析，连接等等。

下面的 VBScript 示例示范了如何打开文件，和如何写数据到文件中并从文件读取数据：

Sub ReadFiles
   Dim fso, f1, ts, s
   Const ForReading = 1
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set f1 = fso.CreateTextFile("c:/testfile.txt", True)
   ' 写一行。
   Response.Write "Writing file <br>"
   f1.WriteLine "Hello World"
   f1.WriteBlankLines(1)
   f1.Close
   ' 读取文件的内容。
   Response.Write "Reading file <br>"
   Set ts = fso.OpenTextFile("c:/testfile.txt", ForReading)
   s = ts.ReadLine
   Response.Write "File contents = '" & s & "'"
   ts.Close
End Sub

下面的代码示范了在 JScript 中做同样的事：

function ReadFiles()
{
   var fso, f1, ts, s;
   var ForReading = 1;
   fso = new ActiveXObject("Scripting.FileSystemObject");
   f1 = fso.CreateTextFile("c://testfile.txt", true);
   // 写一行。
   Response.Write("Writing file <br>");
   f1.WriteLine("Hello World");
   f1.WriteBlankLines(1);
   f1.Close();
   // 读取文件的内容。
   Response.Write("Reading file <br>");
   ts = fso.OpenTextFile("c://testfile.txt", ForReading);
   s = ts.ReadLine();
   Response.Write("File contents = '" + s + "'");
   ts.Close();
}

移动、复制和删除文件

FSO 对象模式各有两种方法移动、复制和删除文件，如下表所述。

任务	方法
移动文件	File.Move 或 FileSystemObject.MoveFile
复制文件	File.Copy 或 FileSystemObject.CopyFile
删除文件	File.Delete 或 FileSystemObject.DeleteFile

下面的 VBScript 示例，在驱动器 C 的根目录中创建一个文本文件，向其中写一些信息，然后把它移动到 /tmp 目录中，并在 /temp 中做一个备份，最后把它们从两个目录中删掉。

要运行下面的示例，需要先在驱动器 C 的根目录中创建 /tmp 和 /temp 目录：

Sub ManipFiles
   Dim fso, f1, f2, s
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set f1 = fso.CreateTextFile("c:/testfile.txt", True)
   Response.Write "Writing file <br>"
   '写一行。
   f1.Write ("This is a test.")
   '关闭文件。
   f1.Close
   Response.Write "Moving file to c:/tmp <br>"
   '获取 C 的根目录(C:/)中的文件的句柄。
   Set f2 = fso.GetFile("c:/testfile.txt")
   '把文件移动到 /tmp 目录。
   f2.Move ("c:/tmp/testfile.txt")
   Response.Write "Copying file to c:/temp <br>"
   '把文件复制到 /temp 目录。
   f2.Copy ("c:/temp/testfile.txt")
   Response.Write "Deleting files <br>"
   '获得文件当前位置的句柄。
   Set f2 = fso.GetFile("c:/tmp/testfile.txt")
   Set f3 = fso.GetFile("c:/temp/testfile.txt")
   '删除文件。
   f2.Delete
   f3.Delete
   Response.Write "All done!"
End Sub

下面的代码示范了在 JScript 中做同样的事：

function ManipFiles()
{
   var fso, f1, f2, s;
   fso = new ActiveXObject("Scripting.FileSystemObject");
   f1 = fso.CreateTextFile("c://testfile.txt", true);
   Response.Write("Writing file <br>");
   // 写一行。
   f1.Write("This is a test.");
   // 关闭文件。
   f1.Close();
   Response.Write("Moving file to c://tmp <br>");
   // 获取 C 的根目录(C:/)中的文件的句柄。
   f2 = fso.GetFile("c://testfile.txt");
   // 把文件移动到 /tmp 目录。
   f2.Move ("c://tmp//testfile.txt");
   Response.Write("Copying file to c://temp <br>");
   // 把文件复制到 /temp 目录。
   f2.Copy ("c://temp//testfile.txt");
   Response.Write("Deleting files <br>");
   // 获得文件当前位置的句柄。
   f2 = fso.GetFile("c://tmp//testfile.txt");
   f3 = fso.GetFile("c://temp//testfile.txt");
   // 删除文件。
   f2.Delete();
   f3.Delete();
   Response.Write("All done!");
}