oracle系统包——DBMS_PIPE用法

转：http://www.cnblogs.com/linjiqin/p/3152635.html

oracle系统包——DBMS_PIPE用法

DBMS_PIPE包用于在同一例程(实例)的不同会话之间进行通信；注意，如果用户要执行包dbms_pipe中的过程和函数,则必须要为用户授权。

sql>conn sys/oracle as sysdba;
sql>grant execute on dbms_pipe to scott;

 

一、管道：
1)、公有管道：所有数据库用户可访问。
2)、私有管道：只能建立管道的数据库用户可访问。

二、DBMS_PIPE包的过程和函数解析
CREATE_PIPE：用于建立公用管道或私有管道。如果将参数private设置为TRUE，则建立私有管道；如果设置为FALSE，则建立公用管道。
eg：   

declare
   flag int;
begin
   flag:=dbms_pipe.create_pipe('public_pipe',8192,false);
   if flag=0 then
      dbms_output.put_line('建立公用管道成功');
   end if;
end;
/

 

PACK_MESSAGE：用于将消息写入到本地消息缓冲区
SEND_MESSAGE：用于将本地消息缓冲区中的内容发送到管道
RECEIVE_MESSAGE：用于接收管道消息
NEXT_ITEM_TYPE：用于确定本地消息缓冲区下一项的数据类型。
如果该函数返回0,则表示管道没有任何消息;
如果返回6,则表示下一项的数据类型为number;
如果返回9,则表示下一项的数据类型为varchar2;
如果返回11,则表示下一项的数据类型为rowid;
如果返回12,则表示下一项的数据类型为date;
如果返回23,则表示下一项的数据类型为raw.
UNPACK_MESSAGE：用于将消息缓冲区的内容写入到变量中.
REMOVE_PIPE：用于删除已经建立的管道
PUGER：用于清除管道中的内容
RESET_BUFFER：用于复位管道缓冲区
UNIQUE_SESSION_NAME：用于为特定会话返回惟一的名称,并且名称的最长度为30字节.

案例：
1、创建一个发消息的过程：

CREATE OR REPLACE PROCEDURE SEND_MESSAGE(PIPENAME VARCHAR2,
                                         MESSAGE  VARCHAR2) IS
  FLAG NUMBER;
BEGIN
  FLAG := DBMS_PIPE.CREATE_PIPE(PIPENAME);
  IF FLAG = 0 THEN
    DBMS_PIPE.PACK_MESSAGE(MESSAGE);
    FLAG := DBMS_PIPE.SEND_MESSAGE(PIPENAME);
  END IF;
END;
/

 

2、创建一个接收消息的包

CREATE OR REPLACE PROCEDURE RECEIVE_MESSAGE(PIPENAME VARCHAR2,
                                            MESSAGE  OUT VARCHAR2) IS
  FLAG NUMBER;
BEGIN
  FLAG := DBMS_PIPE.RECEIVE_MESSAGE(PIPENAME);
  IF FLAG = 0 THEN
    DBMS_PIPE.UNPACK_MESSAGE(MESSAGE);
    FLAG := DBMS_PIPE.REMOVE_PIPE(PIPENAME);
  END IF;
END;
/

 

3、运行包

--在一个会话中执行：
exec send_message('pipe','I send message');
--在另一会话中执行：
var message varchar2(200);
exec receive_message('pipe',:message);
print message;

 执行结果如下：

PL/SQL procedure successfully completed
message
———
I send message

 转：http://blog.csdn.net/ziwen00/article/details/6415189

DBMS_PIPE管道通信 

/**问题:
在编译过程的时候发现有"DBMS_PIPE"标识符必须声明的错误PLS-00201
*/
/**分析:
通过角色获得的权限无效
所以通过grant dba to xaxnb而得到的xaxnb用户的权限是dba的权限,在PLSQL中是没有这个权限的
需要通过显式的直接给用户授权,所以需要执行grant all on dbms_pipe to public来进行授权
*/
/**解决:
1 使用sysdba用户权限登录ORACLE
2 执行grant execute on dbms_pipe to public;让其他用户可以使用DBMS_PIPE
3 退出SYSDBA用户
4 使用XAXNB用户登录,从而可以编译相应的PACKAGE
*/

sqlplus sys/system@orcl as sysdba
grant execute on dbms_pipe to public;
commit;
exit

sqlplus xabjxnb/xabjxnb@orcl
alter package PKG_DataExchange compile;


/**相关资料: http://www.souzz.net/html/database/ORACLE/40773.html
PL/SQL是基于Oracle的一个主流应用程序编程语言，它的主要特点是将SQL语句与过程化程序开发语言相结合，以实现更为复杂的商业逻辑。本文主要就其中多进程通信进行讨论。
显然，多进程技术是用来提高应用的并发性，进而提高整个系统的执行效率，那么如何在PL/SQL中实现多进程的通信呢？其实，PL/SQL其设计的初衷主要是增强SQL语句的功能，而没有考虑到其他编程语言的高级功能，所以在PL/SQL中实现多进程通信只能借助于Oracle提供的两个开发包：DBMS_PIPE和DBMS_ALERT。

1．DBMS_PIPE
该包提供多进程之间管道通信的方法，比如连接到同一个数据库的两个独立会话之间可以通过管道进行通信，另外也可以在存储过程和Pro*C之间进行通信，这样就大大地增强了PL/SQL的处理能力。该包主要提供两对函数：
pack_message(v_msg varchar2)-----将v_msg信息打包放入到缓冲器中，准备发送；
send_message(v_pipename varchar2)-----发送名为v_pipename的管道的缓冲器；
unpack_message(v_msg varchar2)-----将信息解析到v_msg中；
receive_message(v_pipename varchar2)----接受名为v_pipename的管道的缓冲器；
其执行的原理是：首先建立有名管道（这点熟悉unix很清楚），管道的发送端和接受端都有相应的缓冲器进行接受和发送处理，要注意的是，文本信息必须打包来发送，通过解析来读取信息。
为了理解前面的描述，下面列举一个两个会话之间通信的实例。**/

--发送进程：
declare
v_pipename varchar2(30):='pipe1';
v_status integer;
begin
dbms_pipe.pack_message(' hello,this is sending process!');
v_status:=dbms_pipe.send_message(v_pipename);
if v_status !=0 then
dbms_output.put_line('error!');
end if;
end;
/
--接受进程：
declare
v_pipename varchar2(30):='pipe1';
v_status integer;
v_msg varchar2(20);
begin
v_status:=dbms_pipe.receive_message(v_pipename);
if v_status !=0 then
dbms_output.put_line('error');
end if;
dbms_pipe.unpack_message(v_msg);
dbms_output.put_line(v_msg);
end;
/
/***2．DBMS_ALERT
与DBMS_PIPE类似，DBMS_ALERT可以实现多个进程（会话）之间的通信。其基本的执行过程为：首先建立一个报警通道，然后通过报警通道来发送报警信号；在接收端需要先注册该报警通道，对该通道进行监听，然后等待报警信号的到来。下面是该包中的主要函数说明：
dbms_alert.signal(报警管道名,待发送消息)---发送报警信息；
dbms_alert.reGISter（报警管道名）------注册报警管道；
dbms_alert.waitone（报警管道名,接受消息值，返回状态值）-------对报警管道进行监听，等待消息的到来；
同样，这里也给出使用DBMS_ALERT的一个实例。**/
--发送进程：
declare
v_alertName varchar2(30):='alert1';
begin
dbms_alert.signal(v_alertName,' hello,this is sending process!');
commit;
end;
/
--接受进程：
declare
v_alertName varchar2(30):='alert1';
v_status integer;
v_msg varchar2(20);
begin
dbms_alert.register(v_alertName);
dbms_alert.waitone(v_alertName,v_msg,v_status);
if v_status !=0 then
dbms_output.put_line('error');
end if;
dbms_output.put_line(v_msg);
end;
/

/**3．说明
DBMS_PIPE和DBMS_ALERT这两个包都可以进行多进程间的通信，但两者任然是有一些区别：
(1)报警信号是同步的。报警信号直到会话发出Commit时才被发出；如果它所处的事务回滚，则该信号就不发送了。但是管道信号是异步的，而且其通信过程不受事务提交和回滚的影响。
(2)　沿着管道进行传递的消息只能被一个进程进行处理，其消息的接收方式是拷贝后删除，但是报警信号可以被多个进程所获得，即消息的接收方式仅仅是拷贝。
(3) 管道消息不仅可以传递文本信息，还可以传递其他信息，比如对象等，这一好处得益于其对消息的打包预处理；而报警消息只能是文本，不能是其他类型。
4． 总结
近年来，虽然多进程应用有逐渐被多线程应用取代的趋势，但是多进程仍然有其适用的空间，希望读者通过本文初浅的介绍，对基于PL/SQL的多进程通信这一技术有一个初步的认识，这样为以后深入的开发打下一定的基础。
**/

 使用PL/SQL Developer的Event Monitor代替Output做调试。

转自：http://blog.csdn.net/zlowly/article/details/534143

 

PL/SQL Developer里的Event Monitor不知道是什么版本开始加上去的，一直以来都忽视了这个东东，不知道他是干什么的，最近研究DBMS_PIPE才发觉原来它可以在存储过程等调试过程中实时获取调试信息。使用方法很简单，自己创建一个存储过程

PROCEDURE p_message(msg VARCHAR2) AS
  sta NUMBER;
BEGIN
  dbms_pipe.pack_message(msg);
  sta := dbms_pipe.send_message('MyDebug', 60); -- 把打包好的消息发送给名为MyDebug的管道，超时设置为60秒
END;

直接用这个p_message代替平时使用的dbms_output.put_line就可以了，在调试程序前打开PL/SQL Developer里Event Monitor，选择Event Type为DBMS_PIPE，Event Name填上MyDebug，然后按start开始监听。然后就可以像平常一样运行自己存储过程了，不同的是调试信息是实时显示出来的，而不是像Output那样要等程序执行完才显示，感觉真是方便多了。

要注意的是，你必须要有DBMS_PIPE的执行权限，有关DBMS_PIPE可以在Oracle文档中找到详细解释，我就没必要翻译了。另外也可以使用DBMS_ALERT，它和DBMS_PIPE最大不同的是它基于事务的，消息要commit才会发送。