FMS3 系列(一)：第一个FMS程序,连接到FMS服务器(Flash/Flex两种实现)

  FMS是个很牛X的东西，到底有多牛X我不想在这里多说，有兴趣的朋友可以baidu一把了解一下，如果实在是不想动手，那你就点下面的连接吧，我搜索了点资料简单的总结了一下。

    你可以点击这里了解一些关于FMS的基本知识： 了解一些FMS的基本概念

     通常做FMS都是和Flash或是Flex结合开发的，特别是在视频流这方面相当的突出，成功案例也不少，比如http://www.tudou.com,  www.ku6.com , http://www.15dv.com 等视频网站都与FMS挂钩。本人也是因为工作需要，趁工作之余来学习这门技术，想通过写博客的方式来巩固和分享学习，更希望爱好或是在从事这方面开发工作的朋友多多指正，交流。OK，本文就以连接FMS服务器作为写作话题，来看看我们学习FMS应该从什么地方出发，逐步的走上更高的台阶。

     Adobe公司的产品Flash和Flex都可以结合FMS进行编程，本文示例比较简单，为了多凑几个字我打算通过Flash和Flex 两种实现来介绍怎么来实现我们的第一个FMS程序“连接到FMS服务器”。

     上山砍柴不忘磨柴刀，那么我们做技术开发肯定也离不开对开发环境，开发工具，开发语言的选择和准备。本文中我们的工具就是Flash CS 4,Flex Builder 3和FMS 3.0，所使用的开发语言是ActionScript 3.0，这里我不想浪费时间去介绍软件的安装，相信看这篇文章的你对于安装软件不会存在有什么难度，OK，下面看看怎么编码实现。


一 、FMS应该做些什么

     本文中所使用到的FMS是非常简单的，主要就就是建立一个FMS应用，方法很简单。找到你安装FMS的目录你会发现里面有一个 appliations的目录。对的，它就是管理FMS应用的目录，进入该目录在里面建立一个文件夹就OK，我建立的文件夹为"firstFMS"。



二、Flash连接到FMS服务器

     首先建立一个Flash文件（ActionScript 3.0）并将其保存在某个目录(自己决定吧)中。然后打开组件面板(可以按Ctrl+F7)从组件面板中拖拽一个button组件到刚建立好的Flash 的舞台（也就是Flash显示东西的那一块地方），然后通过属性面板（可以按Ctrl+F3）将刚拖拽出的button取个名字(Flash中叫他为实例名,舞台中的每一个组件就是一相对应的对象的实例)，我取的是btnConnFMS。

     完成上面两步后回到舞台，鼠标在舞台中空白位置点击一下，然后同样打开属性面板，你会发现现在的属性面板和先前的有些不一样，在发布选项下找到“类”，这里我填写的为“ConnFMS”，表示我将要通过ConnFMS.as这个类文件来对当前的这个Flash进行编码。

     上面承诺了由ConnFMS.as来负责Flash的编码工作，那该怎么做呢？建立一个ActionScript类文件，保存在之前保存Flash文件的同一目录就OK，记住这个类文件一定是“ConnFMS.as”。下面是ConnFMS.as的完整代码：


package
  {
      import flash.net.NetConnection;
      import flash.net.NetStream;
      import flash.display.MovieClip;
      import flash.net.Responder;
      import flash.events.MouseEvent;
      import flash.events.NetStatusEvent;
      import flash.events.AsyncErrorEvent;
    
     public class ConnFMS extends MovieClip
     {
         private var nc:NetConnection;
        
         public function ConnFMS()
         {
             btnConnFMS.label="连接到FMS";
         }
        
         private function onClickHandler(evt:MouseEvent):void
         {
             trace("正在连接FMS服务器");
             nc = new NetConnection();
             nc.connect("rtmp://localhost/firstFMS");
             nc.addEventListener(NetStatusEvent.NET_STATUS,onNetStatusHandler);
         }
        
         private function onNetStatusHandler(evt:NetStatusEvent):void
         {
             switch (evt.info.code)
             {
                 case "NetConnection.Connect.Success":
                     trace("成功连接FMS服务器！");
                     break;
                 case "NetConnection.Connect.Rejected":
                     trace ("访问FMS服务器权限不足,连接被拒绝！");
                     break;
                 case "NetConnection.Connect.InvalidApp":
                     trace("指定的应用程序名称没有找到");
                     break;
                 case "NetConnection.Connect.Failed":
                     trace("连接失败！");
                     break;
                 case "NetConnection.Connect.AppShutDown":
                     trace("服务器端应用程序已经关闭(由于资源耗用过大等原因)或者服务器已经关闭！");
                    break;
                 case "NetConnection.Connect.Closed":
                     trace("与FMS的连接中断！");
                     break;
             }
         }
     }
}



三、Flex连接到FMS服务器

     首先建立好Flex项目，默认会创建一个MXML文件，简单化实现这里就直接在这个MXML文件里来实现连接FMS。代码上和Flash连接到FMS几乎没有什么差别，主要就是学习NetConnection类来完成，如下代码定义：


//Flex与FMS建立连接的对象
private var netConn:NetConnection;
//FMS服务器的地址,使用rtmp协议
private var rtmpUrl:String="rtmp://localhost/firstFMS";　


NetConnection指示 Flash Player 是通过持久性的 RTMP 连接连接到服务器，实现这一步操作是通过NetConnection类的connect()方法来完成的。如下：


//当Flex应用程序启动的时候就建立与FMS服务器的连接，
internal function onInit():void
{
     netConn = new NetConnection();
     netConn.connect(rtmpUrl);
     netConn.addEventListener(NetStatusEvent.NET_STATUS,onNetStatusHandler);
     netConn.addEventListener(AsyncErrorEvent.ASYNC_ERROR,onAsyncErrorHandler);
} 　　


connect()方法打开指定rtmp协议地址的FMS服务器的连接。一旦调用该方法NetConnection的对象就会捕捉到FMS返回的一个网络连接状态，通过NetStatusEvent事件监听可以得到返回状态的值(详细见本文前Flash部分)，AsyncErrorEvent事件为异步引发异常(既本机异步代码)时调度。关于 NetConnection的各种状态的详细请查看本文之前的Flash实例有详细的介绍。

　　由于实例比较简单，这里我就不在多说废话，下面是通过Flex实现连接到FMS的完整代码：

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
     <mx:Script>
         <![CDATA[
             import mx.controls.Alert;
             //Flex与FMS建立连接的对象
             private var nc:NetConnection;
             //FMS服务器的地址,使用rtmp协议
             private var rtmpUrl:String="rtmp://localhost/firstFMS";
           
            //当Flex应用程序启动的时候就建立与FMS服务器的连接
            internal function onClick():void
            {
                nc = new NetConnection();
                nc.connect(rtmpUrl);
                nc.addEventListener(NetStatusEvent.NET_STATUS,onNetStatusHandler);
                nc.addEventListener(AsyncErrorEvent.ASYNC_ERROR,onAsyncErrorHandler);
            }
           
            private function onClickHandler(evt:MouseEvent):void
            {
                trace("正在连接FMS服务器");
                nc = new NetConnection();
                nc.connect("rtmp://localhost/firstFMS");
                nc.client=this;
                nc.addEventListener(NetStatusEvent.NET_STATUS,onNetStatusHandler);
                nc.addEventListener(AsyncErrorEvent.ASYNC_ERROR,onAsyncErrorHandler);
           }
       
            private function onNetStatusHandler(evt:NetStatusEvent):void
            {
                switch (evt.info.code)
                {
                    case "NetConnection.Connect.Success":
                        trace("成功连接FMS服务器！");
                        break;
                    case "NetConnection.Connect.Rejected":
                        trace ("访问FMS服务器权限不足,连接被拒绝！");
                        break;
                    case "NetConnection.Connect.InvalidApp":
                        trace("指定的应用程序名称没有找到");
                        break;
                    case "NetConnection.Connect.Failed":
                        trace("连接失败！");
                        break;
                    case "NetConnection.Connect.AppShutDown":
                        trace("服务器端应用程序已经关闭(由于资源耗用过大等原因)或者服务器已经关闭！");
                        break;
                    case "NetConnection.Connect.Closed":
                        trace("与FMS的连接中断！");
                        break;
                }
            }
           
            private function onAsyncErrorHandler(evt:AsyncErrorEvent):void
            {}
    ]]>
    </mx:Script>
    <mx:Button x="135" y="89" label="Button" click="onClick()" fontSize="12" fontWeight="normal"/>
</mx:Application>


四、注意事项

　　通常新手在学习FMS的时候都会遇到一个问题，那就是通过NetConnection连接FMS服务器的时候，连接状态总是返回 “NetConnection.Connect.Rejected”这样的状态结果，然后接着还有会有一个 “NetConnection.Connect.Failed”状态，是什么原因造成这样的错误的呢？

　　第一个错误从本文实例中你可以得到，是访问FMS服务器的权限问题，如果FMS没有开设足够的访问权限，通常在访问FMS的客户端都会接受到这样一个异常状态。第二个错误又是怎么产生的呢？这还是又访问权限引起，当客户端没有主够的权限访问FMS服务器，就将返回 “NetConnection.Connect.Rejected”状态并自动断开与FMS服务器的连接，“NetConnection.Connect.Failed”状态本身是由于连接服务器失败产生，而这里是因为权限问题而引发的。

　　前几天很多朋友就在问我这个问题，怎么来解决这个问题呢？如果你是一个技术专研者，如果又你赶兴趣的技术在你面前，你首先会做什么？查看官方提供的文档？实例代码？还是什么？ OK，其实要解决这个问题很简单，在FMS服务器安装好后的目录下有一个"applications"目录，里面有两个FMS默认安装的FMS服务器 (live和vod)，随便打开一个默认安装然后打开里面的"readme.txt"文件会看到下面的字样：

================================================================
Deploying an unsigned vod service
================================================================
   
1. Create a new folder in the {FMS-Install-Dir}/applications folder.

2. If you are replacing the default Adobe signed live service, back up
   the following files:
   * main.far
   * Application.xml
   * allowedHTMLDomains.txt
   * allowedSWFDomains.txt

3. Copy files from {FMS-Install-Dir}/samples/applications/vod to the directory you created in step 1.



　　现在你知道怎么解决上面出现的问题了吗？？将这main.far、Application.xml、 allowedHTMLDomains.txt和allowedSWFDomains.txt这四个文件复制到你创建的FMS服务器目录下就解决了，运行上面的实例程序，然后可以通过FMS的管理控制台查看到详细的连接信息。

　　我通常是使用的FMS安装目录下的fms_adminConsole.swf 来查看连接信息,也可以使用FMSfms_adminConsole.htm查看。