分类汇总compute,compute by,with rollup,with cube使用示例

if object_id('[tb]') is not null drop table [tb]
go
create table [tb]([部门] varchar(7),[电话] varchar(20),[金额] int)
insert [tb]
select '营业部',8001,20 union all
select '营业部',8002,30 union all
select '财务部',6001,10 union all
select '财务部',6003,100 union all
select '财务部2',6004,50 union all
select '财务部2',6004,100

--COMPUTE 示例
select *
from tb
order by [部门]
compute sum([金额])
/*
部门 电话 金额
------- -------------------- -----------
财务部 6001 10
财务部 6003 100
财务部2 6004 50
财务部2 6004 100
营业部 8001 20
营业部 8002 30

sum
-----------
310

(7 行受影响)

*/
--COMPUTE BY 示例
select *
from tb
order by [部门]
compute sum([金额]) by [部门]
/*
部门 电话 金额
------- -------------------- -----------
财务部 6001 10
财务部 6003 100

sum
-----------
110

部门 电话 金额
------- -------------------- -----------
财务部2 6004 50
财务部2 6004 100

sum
-----------
150

部门 电话 金额
------- -------------------- -----------
营业部 8001 20
营业部 8002 30

sum
-----------
50

(9 行受影响)
*/
--with rollup 示例
select
isnull(部门,'总计') as 部门,
isnull(电话,'小计') as 电话,
sum(金额) as 金额
from tb
group by 部门,电话
with rollup
/*
部门 电话 金额
------- -------------------- -----------
财务部 6001 10
财务部 6003 100
财务部 小计 110
财务部2 6004 150
财务部2 小计 150
营业部 8001 20
营业部 8002 30
营业部 小计 50
总计 小计 310

(9 行受影响)
*/
--with cube 示例
select
isnull(部门,'总计') as 部门,
isnull(电话,'小计') as 电话,
sum(金额) as 金额
from tb
group by 部门,电话
with cube
/*
部门 电话 金额
------- -------------------- -----------
财务部 6001 10
财务部 6003 100
财务部 小计 110
财务部2 6004 150
财务部2 小计 150
营业部 8001 20
营业部 8002 30
营业部 小计 50
总计 小计 310
总计 6001 10
总计 6003 100
总计 6004 150
总计 8001 20
总计 8002 30

(14 行受影响)
*/