Shader学习——渐变纹理

核心

效果图

三种渐变纹理效果对比

Shader "Unlit/014"
{
    Properties
    {
        _RampTex ("MainTex", 2D )= "white" {}
        _Diffuse("Diffuse",Color) = (1,1,1,1)
        _Specular("Specular",Color) = (1,1,1,1)
        _Gloss("Gloss",Range(1,256)) = 5
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            sampler2D _RampTex;
            float4 _RampTex_ST;
            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            struct v2f
            {
                float4 vertex :SV_POSITION;
                fixed3 worldNormal: TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : TEXCOORD2;
            };

            v2f vert (appdata_base v)
            {
                v2f o;
                //顶点位置
                o.vertex = UnityObjectToClipPos(v.vertex);
                //法线方向
                fixed3 worldNormal =UnityObjectToWorldNormal( v.normal);
                o.worldNormal=worldNormal;
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                //UV =顶点纹理坐标进行缩放+偏移
                o.uv =TRANSFORM_TEX(v.texcoord, _RampTex);//v.texcoord.xy * _RampTex_ST.xy + _RampTex_ST.zw;
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {   
                //光源方向
                fixed3 worldLightDir = UnityWorldSpaceLightDir(i.worldPos);
                //半罗伯特模型
                fixed halfLambert = max(0, dot(worldLightDir,i.worldNormal)*0.5+0.5);
                //漫反射光=入射光线强度*纹素值*散射颜色
                fixed3 diffuse = _LightColor0.rgb * tex2D(_RampTex, fixed2( halfLambert, halfLambert)) * _Diffuse.rgb ;

                //环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                //视角方向
                fixed3 viewDir = normalize( UnityWorldSpaceViewDir(i.worldPos));
                //半角方向
                fixed3 halfDir =normalize(worldLightDir + viewDir);
                //BlinnPhong高光反射=入射光线颜色强度*材质的高光反射系数*n次平方(取值为正数(法线方向 · 半角方向)，n）；
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(i.worldNormal,halfDir)),_Gloss);

                fixed3 color = ambient + diffuse + specular;

                return fixed4(color,1);
            }
            ENDCG
        }
    }
}