Vcpkg新增MSBuild构建库示例

概述

针对一些没有提供CMake，提供有sln/vcxproj的库，则需要采用vcpkg_build_msbuild方法，然后混合一些CMake脚本方法来完成构建及处理。

ZeroMQ

ZeroMQ是一个分布式消息队列实现，C++的实现是libzmq。

在libzmq的源代码路径builds\msvc下提供了Visual Studio的各个版本的解决方案，Vcpkg已经包含了该库，可以看一下具体是如何配置。

调整triplet

if (TRIPLET_SYSTEM_ARCH MATCHES "x86")
    set(MSBUILD_PLATFORM "Win32")
else ()
    set(MSBUILD_PLATFORM ${TRIPLET_SYSTEM_ARCH})
endif()

对于Vcpkg来讲,其triplet只有x86和x64,但是正常情况下sln/vcxproj中的配置都是Win32/x64，因而需要根据用户安装的triplet来调整一下MSBuild构建时的Platform。

判定构建类型

鉴于用户安装时指定的triplet可能是static，也就是说构建时需要进行不同的处理，判定方法如下:

if(VCPKG_LIBRARY_LINKAGE STREQUAL dynamic)
# 动态构建指令
else()
# 静态构建指令
endif()

如果不支持static，则最好在开头添加判定并调整到dynamic

if (VCPKG_LIBRARY_LINKAGE STREQUAL static)
    message(STATUS "Warning: Static building not supported yet. Building dynamic.")
    set(VCPKG_LIBRARY_LINKAGE dynamic)
endif()

动态库构建

vcpkg_build_msbuild(
    PROJECT_PATH ${SOURCE_PATH}/builds/msvc/vs2015/libzmq/libzmq.vcxproj
    RELEASE_CONFIGURATION ReleaseDLL
    DEBUG_CONFIGURATION DebugDLL
)

其中分别指定了release和debug的配置。

静态库构建

vcpkg_build_msbuild(
   PROJECT_PATH ${SOURCE_PATH}/builds/msvc/vs2015/libzmq/libzmq.vcxproj
    RELEASE_CONFIGURATION ReleaseLIB
    DEBUG_CONFIGURATION DebugLIB
)

安装

MSBuild会根据工程配置将结果输出到特定目录,安装的时候就需要手动复制到包对应路径下。

动态库安装

    file(INSTALL
        ${SOURCE_PATH}/bin/${MSBUILD_PLATFORM}/Debug/v140/dynamic/libzmq.dll
        DESTINATION ${CURRENT_PACKAGES_DIR}/debug/bin
    )
    file(INSTALL
        ${SOURCE_PATH}/bin/${MSBUILD_PLATFORM}/Release/v140/dynamic/libzmq.dll
        DESTINATION ${CURRENT_PACKAGES_DIR}/bin
    )
    file(INSTALL
        ${SOURCE_PATH}/bin/${MSBUILD_PLATFORM}/Debug/v140/dynamic/libzmq.lib
        DESTINATION ${CURRENT_PACKAGES_DIR}/debug/lib
    )
    file(INSTALL
        ${SOURCE_PATH}/bin/${MSBUILD_PLATFORM}/Release/v140/dynamic/libzmq.lib
        DESTINATION ${CURRENT_PACKAGES_DIR}/lib
    )

静态库安装

    file(INSTALL
        ${SOURCE_PATH}/bin/${MSBUILD_PLATFORM}/Debug/v140/static/libzmq.lib
        DESTINATION ${CURRENT_PACKAGES_DIR}/debug/lib
    )
    file(INSTALL
        ${SOURCE_PATH}/bin/${MSBUILD_PLATFORM}/Release/v140/static/libzmq.lib
        DESTINATION ${CURRENT_PACKAGES_DIR}/lib
    )

头文件

file(INSTALL
    ${SOURCE_PATH}/include/
    DESTINATION ${CURRENT_PACKAGES_DIR}/include
)

注意

由于工程本身的复杂性，针对MSBuild构建包，需要根据不同情况进行调整。