Devcon+Robcopy 实现单机"异地"备份功能 v1.2

最近公司的电脑中了个网络型病毒加上今年“勒索病毒”当地有多家企业被勒索！

公司预算有限没有上专业的存储设备，原有的黑NAS,因是DIY的,网络拓扑100M,备份时间要几小时。

所以最简单的办法就是申请了USB3.0移动盘。为了更好的利用移动盘和安全考虑，特想到以下方法：

总体思路，只有要备份时，才启用移动盘。备份完后关闭多动盘（自动执行）不想人工插拔！

现把相关的脚本提供上来

adminrun.cmd文件内容如下：

@echo off
color 6
echo 服务器移动介质备份脚本 v1.2
echo 微信电话:15928282893
echo 本程序需要关闭UAC
echo -------------------------
cacls "%SystemDrive%\System Volume Information" >nul 2>nul
if %errorlevel%==0 goto Admin
if exist "%temp%\GetAdmin.vbs" del /f /q "%temp%\GetAdmin.vbs"
echo Set RequestUAC = CreateObject^("Shell.Application"^)>"%temp%\GetAdmin.vbs"
echo RequestUAC.ShellExecute "%~s0","","","runas",1 >>"%temp%\GetAdmin.vbs"
echo WScript.Quit >>"%temp%\GetAdmin.vbs"
"%temp%\GetAdmin.vbs" /f
if exist "%temp%\GetAdmin.vbs" del /f /q "%temp%\GetAdmin.vbs"
exit
:Admin
reg.exe ADD HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System /v EnableLUA /t REG_DWORD /d 0 /f
devcon find usb* >DevicesID.txt
if not exist "%SystemRoot%\system32\devcon.exe" copy %~dp0devcon.exe %SystemRoot%\system32\devcon.exe /y >nul
if not exist "%SystemRoot%\system32\crc32.exe" copy %~dp0crc32.exe %SystemRoot%\system32\crc32.exe /y >nul
echo 正在启用你所指定的移动介质
echo -------------------------
rem [下面一行请根据情况修改""内内容]
devcon.exe enable @"USBSTOR\DISK&VEN_WD&PROD_MY_PASSPORT_2626&REV_1028\575831314137393231523543&0"
rem DevicesID.txt文件中的ID是，你要控制的USB存储设备;
echo -------------------------
echo 请等待,倒计时完成后,开始备份文件!
timeout /t 10
cls
echo 系统正在备份文件.....
rem [下面n行内中的目录，请根据情况增、删、改]
ROBOCOPY F:\ambak G:\JY0000 /E /B /J /COPYALL
ROBOCOPY F:\pmbak G:\JY0000 /E /B /J /COPYALL
echo 倒计时完成后，将断开你所指定的移动介质
timeout /t 60
rem [下面一行请根据情况修改""内内容]
devcon.exe disable @"USBSTOR\DISK&VEN_WD&PROD_MY_PASSPORT_2626&REV_1028\575831314137393231523543&0"
REM 禁用以上硬件ID对应的设备，意义同上。。。。
echo -------------------------
SCHTASKS /DELETE /TN “WF_AdminRun”/F
SCHTASKS /Create /SC DAILY /TN WF_AdminRun /TR %~dp0AdminRun.cmd /ST 23:59 /F
timeout /t 10
rem 该脚本在Micrsoft Server2008R2、Server2012r2、Windows 10 1909系统上稳定运行.

----------美丽的分隔线----------------------

文件中所涉及到地2个文件为：

devcon.exe 微软官网下载

crc32.exe 微软官网可下（该文件我用于校验crc32用，这里可以不用）;

欢迎大家交流改进，也希望能帮助大家解决实际问题！

欢迎转载，请保留原创连接！