用Unity Shader实现一个Blinn-Phong光照明模型

“计算机图形学第一定律：如果它看起来是对的，那么它就是对的。”

在基于物理渲染（PBR）之前，主要受硬件计算水平的影响，人们不能像PBR那样使用真实世界的物理法则进行光照渲染。转而根据自己的经验使用一些开销不那么大的近似计算进行渲染。裴祥风提出的Phong光照明模型一直是基于经验的光照明模型当中的经典。后来Blinn简化了其中关于高光的计算，改进后的光照明模型被成为Blinn-Phong光照明模型。

Blinn-Phong光照明可表达为：c_result = c_ambient + c_diffuse+c_specular

其中：

1，环境光 c_ambient ：
c_ambient = g_ambient
g_ambient：环境光常量（通过全局光照明烘焙后可知的常量）

2，漫反射 c_diffuse ：
c_diffuse = (c_light + m_diffuse) * max(0, n * ** l)
c_light：光照颜色
m_diffuse：材质的漫反射颜色
n：法线
** l：指向光源的矢量

3，高光反射 c_specular
c_specular = (c_light + m_specular) * max(0,v * h)^m_shininess
c_light：光照颜色
m_specular：材质的高光反射颜色
v：指向观察者的矢量
h：h = normalize(v + l)
m_shininess：反光度

因此c_result = g_ambient + (c_light + m_diffuse) * max(0, n * ** l) + (c_light + m_specular) * max(0,v** * h)^m_shininess

Blinn使用了Halfway的简化计算取代了Reflected

用Unity Shader实现一个Blinn-Phong光照明模型

现在的Unity5+渲染主要推荐使用PBR方式，即Standard材质，Legacy中多是使用Phong光照明模型实现的。如果要自己定制一些特效Shader也可以使用Phong光照明模型，那么我们首先要书写一个基础的Blinn-Phong光照明模型的Shader

Shader "Unlit/PhongLightModel"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}//主贴图
        _MainColor ("Main Color", Color) = (1.0, 1.0, 1.0, 1.0)//主颜色，默认白色
        _SpecularColor ("Specular Color", Color) = (0, 0, 0, 1.0)//高光颜色，默认黑色
        _Shininess ("Gloss", Range(0.0, 10)) = 0.5//反光度
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            Tags { "LightMode" = "ForwardBase" }

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"
            #include "Lighting.cginc" 

            struct a2v
            {
                float4 vertex : POSITION;//顶点
                float2 uv : TEXCOORD0;//uv
                float3 normal : NORMAL;//法线
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;//顶点
                float3 worldLightDir:TEXCOORD1;//世界坐标系下的指向光源的矢量
                float3 worldNormal:TEXCOORD2;//世界坐标系下法线
                float3 worldViewDir :TEXCOORD3; //世界坐标系下的指向观察者的矢量
                float4 pos : SV_POSITION;//裁剪坐标下的顶点
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            fixed4 _SpecularColor;
            fixed4 _MainColor;
            float _Shininess;
            
            v2f vert (a2v v)
            {
                v2f o;

                //使用UNITY_MATRIX_MVP矩阵做仿射变换，把模型空间下的顶点转到裁剪坐标下
                o.pos = mul(UNITY_MATRIX_MVP,v.vertex);
                
                //取得世界坐标系下的法线,UnityObjectToWorldNormal()在UnityCG.cginc被定义
                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                //取得世界坐标系下的指向光源的矢量，WorldSpaceLightDir()在UnityCG.cginc被定义
                o.worldLightDir = WorldSpaceLightDir(v.vertex);

                //取得世界坐标系下的指向观察者的矢量，WorldSpaceLightDir()在UnityCG.cginc被定义
                o.worldViewDir = WorldSpaceViewDir(v.vertex);

                //uv采样
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                //归一化
                fixed3 normalizedLightDir  = normalize(i.worldLightDir);
                fixed3 normalizedNormal = normalize(i.worldNormal);
                fixed3 normalizedViewDir = normalize(i.worldViewDir);

                //像素颜色采样
                fixed3 albedo = tex2D(_MainTex, i.uv);
                
                //计算环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;

                //计算漫反射
                fixed3 diffuse = (_LightColor0.rgb * albedo) * saturate(dot(normalizedNormal,normalizedLightDir));

                //计算高光
                fixed3 halfDir = normalize(normalizedViewDir + normalizedLightDir);
                fixed3 specular = (_SpecularColor.rgb * _LightColor0.rgb) * pow(saturate(dot(halfDir,normalizedNormal )),_Shininess);

                return fixed4((ambient+diffuse+specular),1);
            }
            ENDCG
        }
    }
    FallBack  "Specular"
}

要控制各种向量的点积大于0，否则取0（小于0会是完全相反的方向，甚至表现为光线是从背面照过来的）；

结果：

对比，左：PBR Standard材质，右：Blinn-Phong 手写Shader