gradle 自定义打包项目tar包

---

title: gradle自定义打包项目tar包
date: 2017-09-18 16:41:52
tags: [Gradle]
categories: "Gradle"

---

gradle 自定义打包项目tar包

本文主要是想介绍如何使用gradle管理java项目，并实现自定义打包部署tar包的完整过程。使用的打包项目是一个springboot 项目，其他java 项目同理适用。

先来看下这个spring boot项目的目录结构：

.
|-- build.gradle
|-- gradle
|   `-- wrapper
|       `-- gradle-wrapper.properties
|-- gradlew
|-- gradlew.bat
`-- src
    |-- main
    |   |-- java   
    |   `-- resources
    |       |-- bin
    |       |   |-- start.sh
    |       |   `-- stop.sh
    |       |-- dev
    |       |   |-- application.properties
    |       |   `-- log4j.properties
    |       |-- online
    |       |   |-- application.properties
    |       |   `-- log4j.properties
    `-- test   

如上是一个典型的Java项目，有源码目录src/main/java ，有资源目录 src/main/resources，资源下有脚本目录bin，以及多个环境的配置文件（dev && online），除外还有test 模块。

下边针对这么一个项目，如何编写build.gradle 文件，从而实现自定义打包部署tar包。tar包解压后期望的目录结构如下：

.
|-- bin
|   |-- start.sh
|   `-- stop.sh
|-- conf
|   |-- application.properties
|   `-- log4j.properties
|-- currentpid
|-- lib
`-- logs
    `-- console.log

直接对照 成型的 build.gradle 进行讲解:

buildscript {
    ext {
        springBootVersion = '1.5.6.RELEASE'
    }
    repositories {     // 指定仓库
        mavenLocal()       
        jcenter()
    }
    dependencies {
        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
    }
}

// 声明使用的插件
apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'org.springframework.boot'
apply plugin: 'distribution'   //打包tar包用到的插件

version = '0.0.1-SNAPSHOT'
sourceCompatibility = 1.7    //JDK版本

repositories {
    mavenCentral()
}

// 指定项目的结构
sourceSets {
    main {
        java {
            srcDirs 'src/main/java'
        }
    }
}
//判断 build命令是否指定属性 profile。
//例如 gradle buildTar -xtest -Pprofile=online

ext {
    if (project.hasProperty('profile')) {
        profile = project['profile']
    } else {
        profile = "dev"
    }
    println "profile:" + profile
}
// task 用来新建一些目录，目录位于build/package下
task createDirs() << {
    file('build/package/lib').mkdirs()
    file('build/package/bin').mkdirs()
    file('build/package/logs').mkdirs()
    file('build/package/conf').mkdirs()
}
//task 用来复制build出来的主jar包
task copyLibs(type: Copy) {
    from('build/libs')
    into('build/package/lib')
}
//task 用来复制配置文件
task copyConf(type: Copy) {
    println 'copy conf from src/main/resources/'+profile
    from('src/main/resources/'+profile)
    into('build/package/conf')
}
//task 用来复制bin下的脚本。这里的fileMode并没有生效，原因不详
task copyBin(type: Copy) {
    from('src/main/resources/bin')
    into('build/package/bin')
    fileMode 0744
}
// task 用来复制启动所依赖的jar包
task copyDep(type: Copy) {
    from configurations.runtime
    into 'build/package/lib'
}
//把上述的task串联起来
task prepareFile(dependsOn: [
        'createDirs',
        'copyLibs',
        'copyConf',
        'copyBin',
        'copyDep'
]){}
//指定打包的tar包的名字，以及文件来源目录
distributions {
    monitor {
        baseName = 'azkaban-monitor'
        contents {
            from { 'build/package' }
        }
    }

}
//项目所依赖的jar包
dependencies {
    compile('org.springframework.boot:spring-boot-starter-web')
    compile('org.springframework.boot:spring-boot-devtools')
    compile('org.springframework.boot:spring-boot-configuration-processor')
    compile('org.springframework.data:spring-data-jpa')
    compile('org.springframework.boot:spring-boot-starter-data-jpa')
    compile group: 'log4j', name: 'log4j', version: '1.2.17'
    compile group: 'org.slf4j', name: 'slf4j-api', version: '1.7.21'
    compile group: 'org.apache.httpcomponents', name: 'httpcore', version: '4.3.1'
    compile group: 'org.apache.httpcomponents', name: 'httpclient', version: '4.3.1'
    compile group: 'commons-configuration', name: 'commons-configuration', version: '1.8'
    compile group: 'net.sf.jopt-simple', name: 'jopt-simple', version: '4.9'
    compile group: 'mysql', name: 'mysql-connector-java', version: '5.1.41'
    compile group: 'org.apache.commons', name: 'commons-jexl', version: '2.1.1'
    compile group: 'org.mybatis.spring.boot', name: 'mybatis-spring-boot-starter', version: '1.3.0'
    compile group: 'org.apache.curator', name: 'curator-recipes', version: '4.0.0'
    compile group: 'com.alibaba', name: 'fastjson', version: '1.2.33'

    testCompile('org.springframework.boot:spring-boot-starter-test')
}

//distribution 插件的特性，以DistTar结尾
monitorDistTar.dependsOn  'prepareFile'
monitorDistTar.compression = Compression.GZIP
monitorDistTar.extension = 'tar.gz'

//定义一个task，先build 然后再打包tar包
task buildTar(dependsOn: [
        'build',
        monitorDistTar
]){}