HEMT例子4
energy balance models 和漂移扩散模型对比。能量依赖模型主要包括了速度过冲和非局部碰撞离化
This example demonstrates Id-Vds calculations in single quantum-well AlGaAs/GaAs HEMT using Energy Balance (EB) and Drift Diffusion (DD) Models. It includes
- Construction of a heterojunction structure using Atlas syntax
- Material parameter specification
- Physical model specification including the energy balance model
- Simulation of Id-Vds characteristic with Vgs=0.0V
- Repeat simulation using drift-diffusion models for comparison
- Display of combined results in TonyPlot
The example file consists of two Atlas runs. Both use the same device structure defined in a similar manner to the previous two examples. The first run uses energy balance models to simulate Id-Vds characteristics and the second does the same electrical simulation using the classical drift-diffusion model. The aim of the example is to compare the effects of the different carrier transport models.
Energy balance models provide a more accurate description of physical device effects, in particular the effects of velocity overshoot and non-local impact ionization. These are not handled by the classical drift-diffusion model. These two effects can be observed in sub-micron HEMT simulation. This example concentrates on the velocity overshoot effect in the GaAs-AlGaAs structure. Non-local impact ionization effects can be seen in breakdown simulations. Since velocity overshoot is not accounted for in the drift-diffusion model, the results from simulations with this model will underestimate the current. This discrepancy gets worse as the channel length decreases.
The sequence of simulation syntax is similar to the previous example. For energy balance simulation, additional input parameters need to be defined in particular carrier energy and mobility relaxation times. In these examples the electron relaxation times taurel.el and taumob.el are defined in the two separate material statements for the GaAs and AlGaAs materials, overriding the default values. In the same statements the low field electron mobilities are specified for GaAs and AlGaAs. The saturation velocity is also explicitly defined here for GaAs. The material statement for AlGaAs also contains the align parameter, which defines the portion of the energy band gap difference going to the conduction band (60% in this example) at the GaAs-AlGaAs heterojunction. If the align parameter is present in the material statement the energy band alignment is calculated based on the value of this parameter rather than using electron affinities of the materials forming the respective heterojunction.
Since HEMTs are majority carrier devices and the impact-ionization and breakdown are not a subject of analysis here, the one carrier (electrons only) transport model is used in both continuity and energy balance equations. Thus the following three basic equations are solved in this example to simulate the device characteristics: Poisson, electron continuity and energy balance equations.
In the model statements the set of physical models used is specified: field dependent mobility, and the one carrier transport model (carriers=1 electron). The solution of the energy balance equation for electrons is activated in this statement using the parameter hcte.el.
The contact statement is used to specify the workfunction of the gate electrode, giving the Schottky barrier height of approximately 0.8V.
After the initial solution the gate voltage is set to 0, and the Id-Vds characteristic is calculated. First the drain voltage is ramped up to 0.1V. The solutions are obtained using the combined Gummel-Newton block algorithm specified in the following statement:
method gummel block newton
The algorithm implies that, if the solution does not converge in the course of Gummel iterations, the program will automatically switch over to the block algorithm where the Poisson and electron continuity equations are solved by the Newton algorithm with the frozen electron temperature, and then the electron continuity equation and energy balance equation are solved by the Newton algorithm. If the solution still does not converge, the program will switch over to the fully coupled Newton method.
Next the drain voltage is ramped up to 3V. This part of simulation is performed using the Newton method:
method newton
The results of the simulation are saved in a log file to be displayed later with the results of the DD simulation.
The second Atlas run repeats the first but uses the conventional one carrier Drift Diffusion Model: Poisson's equation and the electron continuity equation are solved self-consistently. The same set of physical models is used, except the energy balance equation. The latter is turned off by not indicating the hcte.el parameter in the models statement. The resulting Id-Vds characteristic is saved in a log file. The statement output con.band val.band e.velocity is used in both runs to save the conduction and valence band potentials and the electron velocity information to the solution files. Generating the solution files in the energy balance simulation and selecting to plot them will show the velocity overshoot effect.
Results from two runs with the EB and DD models are compared by overlaying the two log files in TonyPlot.
To load and run this example, select the Load example button in DeckBuild. This will copy the input file and any support files to your current working directory. Select the run button to execute the example.
讲真根本不知道什么是EB仿真什么是DD仿真 估计是两种不同的模型 得到的都是漏极电流和电压的关系
# (c) Silvaco Inc., 2015
go atlas
# EB simulation
# SECTION 1: Mesh input
mesh
x.mesh loc=0.0 spac=0.025
x.mesh loc=0.1 spac=0.025
x.mesh loc=0.35 spac=0.01
x.mesh loc=0.45 spac=0.025
x.mesh loc=0.5 spac=0.025
y.mesh loc=-0.02 spac=0.01
y.mesh loc=0.0 spac=0.005
y.mesh loc=0.03 spac=0.0005
y.mesh loc=0.0425 spac=0.005
y.mesh loc=0.055 spac=0.0005
y.mesh loc=0.2 spac=0.05
# SECTION 2: Structure Specification
region num=1 material=GaAs y.min=0.03 y.max=0.055
region num=2 material=AlGaAs y.max=0.03 x.composition=0.3
region num=3 material=AlGaAs y.min=0.055 x.composition=0.3
region num=4 oxide y.min=-0.02 y.max=0
elec num=1 name=source x.min=0.0 x.max=0.0 y.min=0.0 y.max=0.05
elec num=2 name=gate x.min=0.1 x.max=0.35 y.min=0.0 y.max=0.0
elec num=3 name=drain x.min=0.5 x.max=0.5 y.min=0.0 y.max=0.05
doping uniform y.min=0 y.max=0.03 n.type conc=1.e18
doping uniform y.min=0.03 n.type conc=1.e15
doping uniform x.min=0.0 x.max=0.05 y.min=0.03 y.max=0.05 n.type conc=1.e18
doping uniform x.min=0.45 x.max=0.5 y.min=0.03 y.max=0.05 n.type conc=1.e18
interface x.min=0 x.max=0.5 y.min=-0.01 y.max=0.005 qf=-1.e12
# SECTION 3: Material Models
material material=GaAs mun=6500 taurel.el=1.e-12 taumob.el=1.e-12 vsat=1.e7
material material=AlGaAs mun=2000 taurel.el=1.e-12 taumob.el=1.e-12 align=0.6
#hcte 是能量平衡模型， el ho表示计算电子和空穴的温度 tc.const 热导率
model fldmob print hcte.el
model material=GaAs print evsatmod=1
contact number=2 workfun=4.64
# SECTION 4: Initial solution
solve init
save outf=hemtex04_0.str
tonyplot hemtex04_0.str -set hemtex04_0.set
#ix.tol 相对电流收敛准则 ir.tol 绝对电流的收敛准则 我猜这个vsatmod是速度饱和模型。 carriers=1是载流子类型是1中，elec代表电子 hole代表空穴 如果设置为0则主要得到电势分布的仿真结果
method gummel block newton maxtrap=6 \
ir.tol=1.e-20 ix.tol=1.e-20 vsatmod.inc=0.05 carriers=1 electron#不懂是什么
# SECTION 5: Bias gate
output con.band val.band e.velocity
solve vgate=0
# SECTION 6: Drain ramp
log outf=hemtex04_eb.log master
method newton maxtrap=6 \
ir.tol=1.e-20 ix.tol=1.e-20 vsatmod.inc=0.05 carriers=1 electron
solve
solve vdrain=0.01
solve vdrain=0.025 vstep=0.025 vfinal=0.2 name=drain
solve vdrain=0.25 vstep=0.05 vfinal=0.9 name=drain
solve vdrain=1 vstep=0.2 electr=3 vfinal=1.6
save outf=hemtex04_eb.str
solve vdrain=1.8 vstep=0.2 electr=3 vfinal=3.0
go atlas
# DD Simulation
# SECTION 1: Mesh input
mesh
x.mesh loc=0.0 spac=0.025
x.mesh loc=0.1 spac=0.025
x.mesh loc=0.35 spac=0.01
x.mesh loc=0.45 spac=0.025
x.mesh loc=0.5 spac=0.025
y.mesh loc=-0.02 spac=0.01
y.mesh loc=0.0 spac=0.005
y.mesh loc=0.03 spac=0.0005
y.mesh loc=0.0425 spac=0.005
y.mesh loc=0.055 spac=0.0005
y.mesh loc=0.2 spac=0.05
# SECTION 2: Structure Specification
#
region num=1 material=GaAs y.min=0.03 y.max=0.055
region num=2 material=AlGaAs y.max=0.03 x.composition=0.3
region num=3 material=AlGaAs y.min=0.055 x.composition=0.3
region num=4 oxide y.min=-0.02 y.max=0
elec num=1 name=source x.min=0.0 x.max=0.0 y.min=0.0 y.max=0.05
elec num=2 name=gate x.min=0.1 x.max=0.35 y.min=0.0 y.max=0.0
elec num=3 name=drain x.min=0.5 x.max=0.5 y.min=0.0 y.max=0.05
doping uniform y.min=0 y.max=0.03 n.type conc=1.e18
doping uniform y.min=0.03 n.type conc=1.e15
doping uniform x.min=0.0 x.max=0.05 y.min=0.03 y.max=0.05 n.type conc=1.e18
doping uniform x.min=0.45 x.max=0.5 y.min=0.03 y.max=0.05 n.type conc=1.e18
interface x.min=0 x.max=0.5 y.min=-0.01 y.max=0.005 qf=-1.e12
# SECTION 3: Material Models
material material=GaAs mun=6500 taurel.el=1.e-12 taumob.el=1.e-12 vsat=1.e7
material material=AlGaAs mun=2000 taurel.el=1.e-12 taumob.el=1.e-12 align=0.6
model fldmob print
model material=GaAs print evsatmod=1
contact number=2 workfun=4.64
# SECTION 4: Initial solution
solve init
method gummel newton maxtrap=6 \
ir.tol=1.e-20 ix.tol=1.e-20 vsatmod.inc=0.05 electron carr=1
# SECTION 5: Bias gate
output con.band val.band e.velocity
solve vgate=0
# SECTION 6: Drain ramp
log outf=hemtex04_dd.log master
method newton maxtrap=6 \
ir.tol=1.e-20 ix.tol=1.e-20 vsatmod.inc=0.05 electron carr=1
solve
solve vdrain=0.01
solve vdrain=0.025 vstep=0.025 vfinal=0.2 name=drain
solve vdrain=0.25 vstep=0.05 vfinal=0.9 name=drain
solve vdrain=1 vstep=0.2 electr=3 vfinal=1.6
save outf=hemtex04_dd.str
solve vdrain=1.8 vstep=0.2 electr=3 vfinal=3.0
tonyplot -overlay hemtex04_dd.log hemtex04_eb.log -set hemtex04_log.set
conc杂质浓度
quit