Silvaco_Atlas_LED_ledex01学习笔记

# (c) Silvaco Inc., 2018
go atlas 
# GaN LED Device Simulation
# Blue single-quantum well LED
# Parameter used for this blue SQW LED
#############################################################################
#  Epilayer #  Material  #  Type  # Thickness #  Doping    #    Mobility    #
#           #            # p or n #     [nm]  #   [cm-3]   #    [cm2/V-s]   #
#############################################################################
# n-Buffer  #    GaN     #    -   #     30    #       -    #       100      #
# n-Contact #    GaN     #    n   #   4000    #     1e18   #       100      #
# n-Contact #  In0.2GaN  #    -   #      3    #       -    #       100      #
# p-Emitter #  Al0.2GaN  #    p   #    100    #     1e19   #        10      #
# p-Contact #    GaN     #    p   #    500    #     1e19   #        10      #
#############################################################################

#运行atlas

# width for 1 Dimensional Structure conversion to  A/cm^2
mesh width=1e8
# 代表仿真得到的电流密度由一维的A/um变为二维的A/cm2，其中width代表未定义的另一维度，默认值1um
x.mesh loc=0.0    spac=0.5
# loc表示网格线的位置，spac代表此网格线左右的网格疏密设置，对于参数剧烈变化的位置，应设置较密集的网格
x.mesh loc=1.0    spac=0.5
#
y.mesh loc=-5.00  spac=1.0
y.mesh loc=-0.65  spac=0.005
y.mesh loc=-0.603 spac=0.0002
y.mesh loc=-0.600 spac=0.0002
y.mesh loc=-0.55  spac=0.005
y.mesh loc=-0.5   spac=0.001
y.mesh loc=-0.0   spac=0.1

#划分网格

region num=1 material=GaN y.max=-0.603 substrate
# 可用x.min x.max y.min y.max定义区域
# 可对不同region设置同一num，实现用矩形拼接不规则多边形
# 定义substrate可用于后续的应力仿真
region num=2 material=InGaN y.max=-0.6 y.min=-0.603 x.comp=0.20 \
       name=well qwell led well.ny=50      
# x.comp-掺杂的阳离子组分，y.comp-掺杂的阴离子组分
# name=well-定义此region名字为well，便于后续调用，起label作用
# qwell定义此region为光电仿真中的量子阱层，for EL谱
# led定义此层为发光层，for EL谱
# well.ny-量子阱层中y方向的网格点数目
region num=3 material=AlGaN y.max=-0.5 y.min=-0.6 x.comp=0.2 
region num=4 material=GaN y.min=-0.5 

#根据器件结构，定义材料分区

electrode name=anode   bottom
electrode name=cathode top

#电极设置

# p type is Mg
# n type is Si
doping region=4 uniform p.type conc=1e19
# uniform-恒定掺杂，此时必须给定掺杂类型和掺杂浓度
doping region=3 uniform p.type conc=1e19
doping region=1 uniform n.type conc=1e18

#掺杂设置

models calc.strain polarization polar.scale=1.0
# GaN类，因存在内建电场，需要进行极化模型设置
# calc.strain-压电极化，polarization-自发极化，polar.scale-自发和压电极化的比例因子，在实际曲线拟合中可调节，默认值1.0
models  fermi ^incomplete consrh auger optr print k.p
# 定义全区域
# fermi和incomplete表示Fermi-Dirac carrier statistics及incomplete ionization of impurities？
# consrh-寿命依赖于浓度的SRH，consrh auger optr-两个非辐射复合和一个general辐射复合模型
# print-打印所有模型的状态、各种系数和常量
# k.p-载流子的漂移和扩散模型
models region=2 k.p chuang spontaneous lorentz
# 定义阱区
# chuang等同于WZ.KP，一种辐射率模型，同类于optr
# spontaneous-辐射复合速率，关联WZ.KP和k.p
# lorentz-洛伦兹增益展宽，参数可单独定义，如下# Lorentz Broaden factor？

#仿真模型设置

material material=GaN taun0=1e-9 taup0=1e-9 copt=1.1e-8 \
         augn=1.0e-34 augp=1.0e-34
# taun0和taup0表示SRH的电子和空穴的寿命
# copt-光学复合率，因models的optr的出现而定义
# augn和augp表示俄歇复合中的俄歇系数
material material=AlGaN taun0=1e-9 taup0=1e-9 copt=1.1e-8 \
         augn=1.0e-34 augp=1.0e-34
material material=InGaN taun0=1e-9 taup0=1e-9 copt=1.1e-8 \
         augn=1.0e-34 augp=1.0e-34
# Lorentz Broaden factor
# 带内散射引起的谱线展宽
material well.gamma0=30e-3
# 在实际曲线拟合中可调节，默认值2e-3
material edb=0.080 eab=0.101
# edb-施主能级，eab-受主能级，对应于models的incomplete所需参数
mobility mun0=100 mup0=10
# mun0-电子迁移率；mup0-空穴迁移率

#材料参数设置（根据模型需要，设置对应的材料参数)

output con.band val.band band.param charge polar.charge e.mobility \
       h.mobility u.srh u.radiative u.auger permi
# con.band-导带边；val.band-价带边；band.param-Eg ni Nc Nv等能带参数；charge-净电荷；polar.charge-极化电荷；u.srh-复合中的SRH部分；permi-介电常数

#output（定义需求参数，后续可保存在输出文件中）

method climit=1e-4 maxtrap=10
# climit-浓度归一化因子，表示数值分析中的误差测量，默认值1e4；maxtrap-在出现发散时重复陷阱过程的次数，设置范围1-10，默认值4

#数值分析

solve init
# 设置所有电压为0，若没有此设置，则系统会自动插入
solve prev
# 指定前面的解作为初始近似
save outf=ledex01_1.str
# 保存输出文件

#零偏压下，初始解（solve+save，save保存solve的最后一个run）

probe name=Recombination integrate recomb
# name-命名用于后续tonyplot的数据处理；integrate-积分，可用x.min x.max y.min y.max region等定义积分范围；recomb-净复合速率
probe name=Radiative integrate radiative rname=well
# radiative-辐射复合速率；rname-region name=well？

#对output的值进行处理和计算，并且一并保存在输出文件中

log outf=ledex01.log
solve vstep=0.05 vfinal=3.5 name=anode
save outf=ledex01_3p5.str
save spectrum=ledex01_3p5.spc lmin=0.40 lmax=0.50 nsamp=100
# solve的过程保存在log文件中，.str保存结构文件，.spc保存光谱文件
solve vstep=0.05 vfinal=4.0 name=anode
save outf=ledex01_4p0.str
save spectrum=ledex01_4p0.spc lmin=0.40 lmax=0.50 nsamp=100
# 
solve vstep=0.05 vfinal=5.0 name=anode
save outf=ledex01_5p0.str
save spectrum=ledex01_5p0.spc lmin=0.40 lmax=0.50 nsamp=100
# 

#偏压下，器件的电学特性仿真

# V-I Curve
tonyplot ledex01.log     -set ledex01_0.set
# I-L Curve
tonyplot ledex01.log     -set ledex01_1.set
# EL Intensity at 3.5V, 4.0V and 5.0V
tonyplot -overlay ledex01_3p5.spc ledex01_4p0.spc ledex01_5p0.spc -set ledex01_2.set

extract init infile="ledex01_3p5.str"
extract name="Electron" curve(depth,impurity="Electron Conc" material="All" \
        x.val=0.5) outfile="ledex01_3p5_Electron.dat"
# x=0.5的截线上，全区域内，电子浓度分布随y的变化，结果保存在.dat文件
extract name="Electron" curve(depth,impurity="Hole Conc" material="All" \
        x.val=0.5) outfile="ledex01_3p5_Hole.dat"
# 从.str .log等输出文件的仿真结果中提取感兴趣的信息，也可在.str后，由tonyplot模块中提取。
extract init infile="ledex01_4p0.str"
extract name="Electron" curve(depth,impurity="Electron Conc" material="All" \
        x.val=0.5) outfile="ledex01_4p0_Electron.dat"
extract name="Electron" curve(depth,impurity="Hole Conc" material="All" \
        x.val=0.5) outfile="ledex01_4p0_Hole.dat"
        
extract init infile="ledex01_5p0.str"
extract name="Electron" curve(depth,impurity="Electron Conc" material="All" \
        x.val=0.5) outfile="ledex01_5p0_Electron.dat"
extract name="Electron" curve(depth,impurity="Hole Conc" material="All" \
        x.val=0.5) outfile="ledex01_5p0_Hole.dat"
        
tonyplot -overlay ledex01_3p5_Electron.dat ledex01_3p5_Hole.dat ledex01_4p0_Electron.dat ledex01_4p0_Hole.dat ledex01_5p0_Electron.dat ledex01_5p0_Hole.dat -set ledex01_3.set

#图形化显示信息，包括直接输出量 I V L等（整体），也包括extract提取出来的信息（局部空间的参数变化情况）

quit

#结束程序

#备注
#output和probe用于得到仿真需要的参数；extract用于提取仿真结果中感兴趣的部分。
#了解框架，（mesh-region-electrode-doping-model-material-（output）-（probe））（-method-initial-solve-（extract）-tonyplot）
#熟悉各statement，包括mesh region electrode doping model material output probe method solve save log（参考atlas_users），extract（参考deckbuild_users），tonyplot（参考tonyplot_users），了解其常用语法，其它的用到了再去查就可以。
#了解LED的常用模型（原理依据？），常用数值分析方法，常用参数及其提取方式。如何导入新材料信息？
#需要看atlas_users的chapter2 chapter12 chapter6 chapter3？

#絮絮叨叨看完example01，继续继续…
#（说明：只用于个人学习，不用于任何商业用途）