程序的构建
当你编写的程序越来越大或者多人在同一代码库协作开发时，将代码划分成不同的模块是很有必要的. newLISP中使用context来创建模块, 也就是命名空间. 命名空间将各个模块之间的词法隔离开. 这样各模块可以拥有相同名字的变量而不会发生冲突.
通常，每个文件都有一个context来组织模块.可能一个模块文件包含数据库访问代码.
; database.lsp
;
(context 'db)
(define (update x y z)
...
)
(define (erase x y z)
...
)
另一个模块包含多种数据操作代码.
; auxiliary.lsp
;
(context 'aux)
(define (getval a b)
...
)
最后，会有一个主模块 MAIN 加载和控制所有其他模块:
; application.lsp
;
(load "auxiliary.lsp")
(load "database.lsp")
(define (run)
(db:update ....)
(aux:putval ...)
...
...
)
(run)
一个文件多个模块
当在一个文件中使用多个context时，每一个context都要以(context MAIN)来关闭:
; myapp.lsp
;
(context 'A)
(define (foo ...) ...)
(context MAIN)
(context 'B)
(define (bar ...) ...)
(context MAIN)
(define (main-func)
(A:foo ...)
(B:bar ...)
)
注意在创建context A 和 B 的时候,他们的名字前都有单引号,这是因为他们是新创建的. 但是 MAIN 前没有使用单引号,这是因为 newLISP 在启动时就已经创建了MAIN. 当然, 给他加个引号也没有问题.
可以使用下面的技术合并掉 (context MAIN)语句:
; myapp.lsp
;
(context 'A)
(define (foo ...) ...)
(context 'MAIN:B)
(define (bar ...) ...)
(context 'MAIN)
(define (main-func)
(A:foo ...)
(B:bar ...)
)
(context 'MAIN:B) 回到 MAIN 并创建一个新的context B.
默认函数
每一个模块都可以有一个和宿主context同名的函数. 这个函数有着特殊的作用:
(context 'foo)
(define (foo:foo a b c)
...
)
函数 foo:foo 就是模块 foo的默认函数, 因为当使用模块名foo 的时候就像调用一个函数, 他将会被自动的映射到 foo:foo
(foo x y z)
; same as
(foo:foo x y z)
默认函数看起来像普通函数，但是它拥有自己的名命名空间。我们可以用此特性来编写保持数据状态的函数:
(context 'generator)
(define (generator:generator)
(inc acc)) ; when acc is nil, assumes 0
(context MAIN)
(generator) → 1
(generator) → 2
(generator) → 3
下面是个更复杂的例子,用来生成斐波纳契序列:
(define (fibo:fibo)
(if (not fibo:mem) (set 'fibo:mem '(0 1)))
(last (push (+ (fibo:mem -1) (fibo:mem -2)) fibo:mem -1)))
(fibo) → 1
(fibo) → 2
(fibo) → 3
(fibo) → 5
(fibo) → 8
...
这个示例还展示了如何在不显示创建context的情况下动态定义默认函数。作为另一种选择，也可以在明确创建context下定义默认函数:
(context 'fibo)
(define (fibo:fibo)
(if (not mem) (set 'mem '(0 1)))
(last (push (+ (mem -1) (mem -2)) mem -1)))
(context MAIN)
(fibo) → 1
(fibo) → 2
(fibo) → 3
(fibo) → 5
(fibo) → 8
虽然第一种形式较短，但是第二种形式更容易阅读.
用context封装数据
前面的例子展示了用命令空间中的默认函数来封装数据. 在 generator 的例子中 acc 用来保存状态. 在 fibo 的例子中用 mem 来保存增长的列表. 两个例子里,函数和数据在一个命名空间中共存. 下面的例子展示了如何仅在命名空间的默认函数中保存数据:
(set 'db:db '(a "b" (c d) 1 2 3 x y z))
就像使用默认函数 fibo 和 generator 那样,我们可以用 db来调用 db:db . 此时db就像普通list一样,可以完成任意的列表操作:
(db 0) → a
(db 1) → "b"
(db 2 1) → d
(db -1) → z
(db -3) → x
(3 db) → (1 2 3 x y z)
(2 1 db) → ((c d))
(-6 2 db) → (1 2)
用引用传递对象
当默认函数被作为某个函数的参数调用的时候, 默认函数会通过引用传递. 这意味这传递给函数的参数是原始数据, 而不是列表或者字符串的拷贝. 在传递庞大的数据的时候这个特性非常有用:
(define (update data idx expr)
(if (not (or (lambda? expr) (primitive? expr)))
(setf (data idx) expr)
(setf (data idx) (expr $it))))
(update db 0 99) → a
db:db → (99 "b" (c d) 1 2 3 x y z)
(update db 1 upper-case) → "b"
db:db → (99 "B" (c d) 1 2 3 x y z)
(update db 4 (fn (x) (mul 1.1 x))) →
db:db → (99 "B" (c d) 1 2.2 3 x y z)
db:db 中的数据通过变量 data 传递给函数 update , 现在update就拥有一个 context db的数据引用. 接着判断传入的 expr 参数是否是系统函数,操作符或者用户定义的函数的,如果是的话就使用expr 操作 it , it是一个系统变量包含了表达式(这里是setf)要操作的原始数据(data idx).
当一个newLISP函数需要一个列表或者在字符串参数的时候, 使用context的名称就能将默认函数传递进去. 示例如下:
(define (pop-last data)
(pop data -1))
(pop-last db) → z
db:db → (99 "B" (c d) 1 2.2 3 x y)
update 同时也展示了如何将函数作为数据传递给别的函数 (upper-case 也依靠 $it). 更多内容请看函数即数据.