PATH=ASSA脚本学习区

PATH=ASSA脚本学习区

2011-05-08 18:59:38| 分类： 石器脚本 assa |字号 订阅

下载LOFTER我的照片书 |
PATH=ASSA脚本学习区
DATA=
资料由灵亦整理，如要转贴，请说明出处！

喜欢做ASSA脚本的你，怎么能错过？
END;

PATH=ASSA脚本学习区->脚本代码
DATA=
原作者：情缘GM，广二杰哥

已经分开,方便浏览
END;

PATH=ASSA脚本学习区->脚本代码->【check】(状态检测)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【check】(状态检测)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
check {人物},{名称|LV|HP|MP|石币|攻击|防御|敏捷|魅力|转生},{=|!=|<|<=|>=|>},数值,{跳转符号}
check {宠物1-5|战宠|骑宠},{名称|LV|HP|攻击|防御|敏捷|魅力|忠诚|职位|技能1-7},{=|!=|<|<=|>=|>},数值,{跳转符号}

例子：
check 人物,魅力,<,100,做橘子 '人物的魅力小于100,就跳转到标记"做橘子",大于或等于100就执行下一行指令
check 战宠,忠诚,<,100,加忠 '战宠的忠诚小于100,就跳转到标记"加忠"
check 宠物1,技能4,=,料理,+3 '检查宠物1的技能4是否为料理,如果是,就跳转到+3行,不是就执行下一
行"say "指令
say 料理宠物放第1位，技能第4位。
end

还有几个小指令没介绍:
beep '提示声音,会发出"铛"的一声来提醒玩家
end '结束脚本,一般加在判断类指令后面和脚本结尾
pause '暂停脚本,随便加到哪都行,一行加在"MSG"命令的后面
log mode 'mode=0重登，1回纪录点，2注销，3断线 log 1表示回记录点
usemagic {1-5} '使用精灵
usemagic {1-26},-1 '使用技能,usemagic 1,-1 如果你的第一个技能是寻敌追踪,那么这个命令就能用出寻敌追
踪这技能

道具栏1-15位置顺序（从左上到右下）：

┏━━┳━━┳━━┳━━┳━━┓
┃　１┃　２┃　３┃　４┃　５┃
┣━━╋━━╋━━╋━━╋━━┫
┃　６┃　７┃　８┃　９┃１０┃
┣━━╋━━╋━━╋━━╋━━┫
┃１１┃１２┃１３┃１４┃１５┃
┗━━┻━━┻━━┻━━┻━━┛
宠物字段置顺序（主要按数据显示–>人宠数据上为准）及宠物技能位置顺序从上到下：

┏━━━┓ ┏━━━┓
┃宠物一┃ ┃技能１┃
┣━━━┫ ┣━━━┫
┃宠物二┃ ┃技能２┃
┣━━━┫ ┣━━━┫
┃宠物三┃ ┃技能３┃
┣━━━┫ ┣━━━┫
┃宠物四┃ ┃技能4 ┃
┣━━━┫ ┗━━━┛
┃宠物五┃
┗━━━┛

石器6.0及以下版本装备101-105位置顺序：

┏━━━━━━━┳━━━━━━━┓ ┏━━━━━━━┓
┃左饰（１０４）┃右饰（１０５）┃ ┃头盔（１０１）┃
┗━━━━━━━┻━━━━━━━┛ ┗━━━━━━━┛
┏━━━━━━━┓ ┏━━━━━━━┓
┃武器（１０３）┃ ┃衣服（１０２）┃
┗━━━━━━━┛ ┗━━━━━━━┛

石器7.0及以上版本装备101-109位置顺序：
┏━━━━━━━┳━━━━━━━┳━━━━━━━┓
┃左饰（１０５）┃头盔（１０１）┃右饰（１０４）┃
┣━━━━━━━╋━━━━━━━╋━━━━━━━┫
┃左武（１０３）┃衣服（１０２）┃右武（１０７）┃
┣━━━━━━━╋━━━━━━━╋━━━━━━━┫
┃手套（１０９）┃腰带（１０６）┃鞋子（１０８）┃
┗━━━━━━━┻━━━━━━━┻━━━━━━━┛

名片位置顺序从第一页开始翻页，从上到下（1-80）7.5以上的时代，2.0的为（1-40）。
END;

PATH=ASSA脚本学习区->脚本代码->【ifpos】(判断坐标)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【ifpos】(判断坐标)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
ifpos x,y, {跳转符号}
用途：在一些利用地图传送点换地图的时候,真正的地图编号没有换的,只是换了一个地方,例如泪之海底,
就可以用到ifpos来判断是否真的切换了地方.因为这时用waitmap已经没有任何作用了,换来换去都是同一
个地图编号,怎么判断都是判断不出是否真的换了地方的.

例子：
walkpos 147,61
walkpos 147,62
walkpos 148,63
delay 1000
ifpos 148,63,-4 '判断坐标,如果坐标还在148,63,说明地图没有切换成功,就跳转到
-4行,再走一次坐标
walkpos 149,63
walkpos 148,71
walkpos 148,72
walkpos 148,74
END;

PATH=ASSA脚本学习区->脚本代码->【doffpet】(丢弃宠物)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【doffpet】(丢弃宠物)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
doffpet 1-5 '丢弃宠物1-5
例子：
doffpet 2 '丢弃宠物2,这指令不要随便使用,因为用这个丢宠物不需要按确定的
END;

PATH=ASSA脚本学习区->脚本代码->【ifpet】(判断宠物)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【ifpet】(判断宠物)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
ifpet {名称|空位},{=|!=|<|<=|>=|>},数量,{跳转符号}
ifpet {?|*},{=|!=},{名称|空位},{跳转符号}
ifpet {1|2|4-5},{=|!=},{名称|空位},{跳转符号}
例子：
ifpet 5,=,风水火地满2,全部喂满 '宠物5的名字等于风水火地满2的话就跳转到"全部喂满"继续执行脚本
ifpet 2,!=,那提拉,+5 '宠物2的名字不等于那提拉的话就跳转到+5行继续执行脚本,
等于那提拉的话就继续执行下一行脚本
ifpet ?,=,那提拉,err '宠物栏只要有一个名字叫那提拉的宠物,就跳转到"err"执行
脚本,没有的话就执行下一行脚本

这里和判断道具的是一样的只是变成判断宠物了而已
END;

PATH=ASSA脚本学习区->脚本代码->【iffight】(判断战斗回合数)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【iffight】(判断战斗回合数)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
iffight {=|!=|<|<=|>=|>},战斗回合数,{跳转符号} 判断战斗回合

例子：
label 开始迭加
delay 200
iffight !=,0,-1 '判断战斗回合数不等于0(说明在战斗中)
就跳转到-1行的delay 200中去循环执行,等于0就执行下一个指令
“moveitem”(移动道具),因为移动道具一定要在平时状态中才可以的,所以这里通过判断战斗回合来判断战斗是否结束.
moveitem 1,2
delay 200
iffight !=,0,-1
moveitem 2,3
delay 200
iffight !=,0,-1
moveitem 3,4
delay 200
END;

PATH=ASSA脚本学习区->脚本代码->【ifstone】(判断石币)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【ifstone】(判断石币)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
ifstone {=|!=|<|<=|>=|>},数值,{跳转符号}

ifstone <=,980000,+2 '石币小于或等于980000就跳转到+2行执行脚本,跳转call save.
如果大于980000,就调用 标记 SAVE下的指令
CALL SAVE

'中间的代码省略

LABEL SAVE
save 950000,1
delay 5000
ifstone >=,980000,-2
RETURN '返回到call
END;

PATH=ASSA脚本学习区->脚本代码->【ifitem】(判断道具)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【ifitem】(判断道具)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
ifitem {名称|说明|空位},{=|!=|<|<=|>=|>},数量,{跳转符号}
ifitem {?|*},{=|!=},{名称|说明|空位},{跳转符号}
ifitem {1|2|4-15},{=|!=},{名称|说明|空位},{跳转符号}
ifitem {101-109},{=|!=},{名称|说明|空位},{跳转符号} '判断装备,本教程最后有装备具体位置代码

例子：
ifitem 空位,>,5,XX2 '检测道具1-15, 其中有 空位>5 则跳转到标记XX2,空位小于或等于
5则继续执行下一个指令
ifitem 火灵石,!=,0,err '检测道具1-15,火灵石数量不等于0则跳转到标记err,等于0则继续执
行下一个指令
ifitem ?,=,不可思议的贝壳,XX2 '检测道具1-15, 其中有一个不可思议的贝壳则跳转到标记XX2
ifitem *,=!,火灵石,XX2 '检测道具1-15, 所有道具没有一个是火灵石则跳转到标记XX2

set 快速遇敌,1
delay 1000
ifitem 13|14-15,=,水灵石,+2 '检测道具13-15,都等于水灵石,则跳转到+2行,即"set 快速遇敌,0"
goto -2
set 快速遇敌,0
delay 100 '延时100毫秒,即0.1秒
set 自动逃跑,1
delay 1000 '延时1000毫秒,即1秒

ifitem 103,=,猛毒的精灵,+4 '检测装备栏,左武器是否为猛毒的精灵,是的话就跳转到+4行,否则的话就继续
执行下一个指令

指令拆分解释：
“名称” 代表 “道具的名称”（包括道具栏及装备栏）
“说明” 代表 “道具的说明文”（包括道具栏及装备栏）
“?” 代表 “道具栏里全部位置”
“*” 代表 “道具栏及装备栏里的全部位置”

“(1-15)” 代表 “道具栏里的指定位置，顺序为从左上到右下，如1-1为第一个道具格，1-5为第一到第五个道具格
，如此类推”
“101-109” 代表石器7.0及以上版本装备101-109位置顺序
“{==|>|>=|<|<=}” 代表 “{等于|大于|大于或等于|小于|小于或等于}”
END;

PATH=ASSA脚本学习区->脚本代码->【useitem】【doffitem】(使用道具) (丢弃道具)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【useitem】【doffitem】(使用道具) (丢弃道具)指令∽∽∽∽∽∽∽∽∽
useitem {1-15|道具名|道具说明},对象[,x,y] '使用道具 items格式：1|2|3-15 数值:1-15, 对象:0=人物,1-5宠物
格式1：useitem 1|2|3|4-6 '指定道具1,2,3,4,5,6 给人物吃掉
格式2：useitem 豪华船生鱼片 '把道具1-15中为 豪华船生鱼片 的全部 都给人物吃掉
格式3：useitem ?豪华船生鱼片 '在道具1-15中找到第一个的 豪华船生鱼片 都给人物吃掉

例子：
useitem ?飞行至萨姆吉尔 '飞到萨姆吉尔村,如果你道具栏第2格有一根萨村羽毛,第4格也有一根,
脚本只会用第一根羽毛
useitem 1|2|3-5 '道具1,2,3,4,5 给人物吃掉
useitem 1|2|3-5,0 '道具1,2,3,4,5 给人物吃掉
useitem 1-10,2 '道具1-10 给宠物2吃掉
useitem 俄式宠物食物2,3 '道具俄式宠物食物2全部 给宠物3吃掉

doffItem {1-15|道具名全称}[,x,y] 丢出道具 items格式：1|2|3-6 数值:1-15
格式1：doffitem 1|2|3|4-6 '指定道具1,2,3,4,5,6 被丢出
格式2：doffitem 豪华船生鱼片 '把道具1-15中为 豪华船生鱼片 的全部 被丢出
格式3：doffitem ?豪华船生鱼片 '在道具1-15中找到第一个的 豪华船生鱼片 被丢出
END;

PATH=ASSA脚本学习区->脚本代码->【label】【goto】(标记)(跳转)指令
DATA=
∽∽∽∽∽∽∽∽【label】【goto】(标记)(跳转)指令∽∽∽∽∽∽∽∽
label 标记名称
goto 标记名称|+ -行数
'特殊保留标记
label .log. 断线重登后，脚本将跳到此处运行
label .end. 按停止按钮，脚本将跳到此处运行

简单的说标记实质是为脚本设置一个点，让脚本到达某个时候或者达到/不能达到某个条件时跳到这个
点上继续执行其它指令跳转，就是无条件跳到某个标记的指令
END;

PATH=ASSA脚本学习区->脚本代码->【mail】【petmail】(邮件)(宠物邮件)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【mail】【petmail】(邮件)(宠物邮件)指令∽∽∽∽∽∽∽∽∽∽∽∽∽
mail {对方名片位置(1-80),邮件内容}

发送宠物邮件给名片上的人
例子：
mail 5,你好吗？ '发送邮件内容为"你好吗？"给你名片匣位置5的玩家
mail 1-40,你最近怎么样? '发送邮件内容为"你最近怎么样?"给你名片匣位置1-40的玩家

petmail {对方名片位置(1-80),道具索引1-15} [,mode] '宠物邮件 mode=1 等待任务完成
格式1：petmail 1,1|2|3-5 '把道具1-5中寄出给名片位置1的玩家
格式2：petmail 1,不可思议的贝壳 '把道具1-15中为 不可思议的贝壳 的全部寄出给名片位置1的玩家
格式3：petmail 1,?不可思议的贝壳 '在道具1-15中找到第一个的 不可思议的贝壳寄出给名片位置1的玩家

例子：
mail 5,2-4 '发送宠物邮件道具为道具栏上2-4格给你名片匣位置5的玩家
mail 15,聪明的豆子3 '发送宠物邮件道具为道具栏上所有聪明的豆子3给你名片匣位置15的玩家
END;

PATH=ASSA脚本学习区->脚本代码->【call】【return】(调用)(返回)指令
DATA=
∽∽∽∽∽∽∽∽【call】【return】(调用)(返回)指令∽∽∽∽∽∽∽∽
call 标记名称
return

例子：
walkpos 24,24
walkpos 26,24
call 票 　'调用标记为"票"的指令执行完"票"的指令后将返回到下一行指令中去
ifitem ?,=,猜谜的参加票,+2 　'道具栏上只要有猜迷的参加票就跳转到+2行
goto -2
walkpos 28,23
walkpos 29,22
walkpos 29,21
walkpos 29,20
goto 我猜我猜我猜猜猜

label 票
ifitem ?,=,猜谜的参加票,+13 '道具栏上只要有猜迷的参加票就跳转到+13行,即return指令,直接返回到call
say 现在帮你打猜谜的参加票，如果没有空位会帮你丢掉猜拳的参加券,4
set 自动逃跑,0
set 快速遇敌,1
delay 500
ifitem ?,=,猜谜的参加票,+4
ifitem 空位,>=,1,+2
doffitem ?猜拳的参加券
goto -4
delay 1000
set 快速遇敌,0
set 自动逃跑,1
delay 2000
return 　　'返回到"call 票"的下一行指令" ifitem ?,=,猜谜的参加
票,+2"继续执行脚本

简单的说call和return就是能使多个地方共享一个地方的指令。假设"goto"是只去不回的单程指令，
那"call"加上"return"就是既去又回的双程了。是"从那里来，就回到那里去"的控制脚本流程指令。

例如，标记A后面的指令是一组很长的指令，我们常称此标记A后面的这一组指令为一个"组件"（现在简称为A组件）。
而标记B后面当执行完一段指令后，要执行A组件，执行完毕后要继续回到标记B处；
标记C后面执行完一段指令后也要执行A组件，执行完毕后要继续回到标记C处；
此时就要用上"call"指令，当然A组件最后面要用"return"指令，才能使指令"从那里来，就回到那里去"
END;

PATH=ASSA脚本学习区->脚本代码->【join】(组队和脱离团队)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽【join】(组队和脱离团队)指令∽∽∽∽∽∽∽∽∽∽∽∽
join mode [,x,y] 'mode:=组队，0=脱队,后面的坐标一般都没有用

加入团队的指令，前方必须有人打开组队，即使组队了继续发送指令也不会有问题，进入战场再发送指
令并且前方有人打开组队状态可能会造成掉线
例子：
join 1 '加入团队,这个命令可以在一些无法按加入团队按钮的地方使用,比
如成人礼的洞,五兄弟的
join 0 '脱离团队
END;

PATH=ASSA脚本学习区->脚本代码->【get】【put】(取得)(寄放)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽【get】【put】(取得)(寄放)指令∽∽∽∽∽∽∽∽∽∽∽∽
get {道具名|道具索引1-n} '封包命令,取道具
put {道具名|道具索引1-15} '封包命令,存道具

一定要打开个人寄放店窗口或者仓库寄放店窗口才能使用,打开的方法很简单,可以不用lclick鼠标左击命令
,直接用button命令来打开,这样不容易出错,下面的例子将介绍

寄放失败没问题，领取失败也不会出现问题，现脚本指令支持个人寄放店和仓库的领取和寄放

例子：
say 我要存进个人寄放店一些东西
waitdlg 欢迎光临,1,5,-1
button 1 '这个button 1就是在欢迎光临对话框下打开个人寄放店存东西
的对话框的,button 2就是取的对话框
put 飞行至萨 '这个就是把萨村羽毛存进寄放店里了,只要带有"飞行至萨"的东
西都会给一起存进去,所以有时候可以把名字写清楚点,
put萨姆 '这个就是含有"萨姆"2个字的道具存进寄放店,当你的身上有萨
姆吉尔首饰和萨村羽毛的时候,都会一起存进去

say 我要存进仓库一些东西
waitdlg 欢迎光临,1,5,-1
button 3 '这个button 3就是在欢迎光临对话框下打开
"使用道具仓库"对话框
waitdlg 使用道具仓库,1,5,-3 '等待对话框的出现
button 1 '这个button 1就是在使用道具对框下打开仓库存东西的对话框
的,button 2就是取的对话框
put 飞行至玛丽 '这个就是含有"飞行至玛丽"的道具存进仓库

say 我要存进个人寄放店一些东西
waitdlg 欢迎光临,1,5,-1
button 2
get 飞行至萨
get萨姆 '这个就是含有"萨姆"2个字的道具取出来,当你的寄放店有萨姆
吉尔首饰和萨村羽毛的时候,都会一起取出,所以有时要把名字写详细点
say 我要存进仓库一些东西
waitdlg 欢迎光临,1,5,-1
button 3 '这个button 3就是在欢迎光临对话框下打开
"使用道具仓库"对话框
waitdlg 使用道具仓库,1,5,-3 '等待对话框的出现
button 2
get 飞行至玛丽 '这个就是含有"飞行至玛丽"的道具从仓库取出来
END;

PATH=ASSA脚本学习区->脚本代码->【moveitem】【waititem】(移动物品)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽【moveitem】【waititem】(移动物品)(等待物品)指令∽∽∽∽∽∽∽∽∽∽∽∽
moveitem 1,|2-15
waititem {1|2|3-15},道具名称,等待时间[,错误跳转] '等待道具

例子：
moveitem 2,15 '把道具栏第2格的物品称动到第15格
moveitem 14,3 '把道具栏第14格的物品称动到第3格

walkpos 92,101
walkpos 93,101
say buy
waitdlg ?,0,5,-3
buy 1,1
waititem 1,飞行至萨姆吉尔,5,-5 '等待道具栏第1位的道具,如果5秒内道具栏第一格还没有出现包含有
“飞行至萨姆吉尔”,就跳转到-5行执行脚本
END;

PATH=ASSA脚本学习区->脚本代码->【sellitem】【出售】指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽【sellitem】【出售】指令∽∽∽∽∽∽∽∽∽∽∽∽∽
SellItem {道具名|道具索引1-15} '这个命令一定要出现卖的对话框才能使用,要不然会变成买的命令

例子：
walkpos 25,26
walkpos 25,28
W 0,0,东 '人物方向向东
say 卖
waitdlg ?,0,5,-4
sellitem 12,5 '出售第十二格的道具五个（道具被迭加后）

walkpos 25,26
walkpos 25,28
W 0,0,东
say 卖
waitdlg ?,0,5,-4
sellitem 贝壳,5 '卖出名为"贝壳"的物品，卖五个，迭加后的道具，只要迭加5个或者以上的贝
壳都卖掉其中的5个。
END;

PATH=ASSA脚本学习区->脚本代码->【buy】【购买道具】指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽【buy】【购买道具】指令∽∽∽∽∽∽∽∽∽∽∽∽∽
buy {道具名|道具索引1-n},数量[,x,y] '这个命令可以直接站在NPC面前,不用说话都可以买到道具,封包命令

详尽的料理材料购买目录，请参考情报显显〖村庄购物指南〗

例子：
walkpos 25,26
walkpos 25,28
W 25,28,C '人物方向向东
say 买
waitdlg 店,1,5,-4
buy 12,5 '购买从第一页第一个数起，第十二个的物品，买五个

walkpos 25,26
walkpos 25,28
W 0,0,东 '人物方向向东
say 买
waitdlg 店,1,5,-4
buy 贝壳,5 '购买名为"贝壳"的物品，买五个，如果商店里有重复名字的物品
，则会先买排列在最前面的，可能买到的道具不是你想要的等级的，所以最好把想要购买的道具名字（或者道具
的说明）写全写清楚。
END;

PATH=ASSA脚本学习区->脚本代码->【chpet】(改变战宠骑宠命令)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【chpet】(改变战宠骑宠命令)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
chpet {0-5}{,模式} '模式只有1,1表示更换的是骑宠,不写表示更换的是战宠

在平时状态下换战宠，除了正在骑乘的宠物外，其余状态的宠都可以变成"战斗"，0为把当前战宠状态变回"等待"

chpet 1 '把第一位的宠物状态改变成"战斗"
chpet 2 '把第二位的宠物状态改变成"战斗"
chpet 0 '把战宠设置为等待状态
chpet 2,1 '把第二位的宠物状态改变成"骑乘"
chpet 3,1 '把第三位的宠物状态改变成"骑乘"

END;

PATH=ASSA脚本学习区->脚本代码->【set】(设定)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【set】(设定)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
set {快速遇敌|快速行走|自动逃跑|自动捉宠|快速战斗|自动KNPC|原地保护|经验显示|断线重登|
穿墙行走|W2|自动堆栈|}{,1|0}
'1表示开启,0表示关闭
set指定攻击, {宠物名称|宠物名称……| 宠物名称} '最多可以设置捉10只宠物的名字
set锁定攻击, {宠物名称|宠物名称……| 宠物名称} '最多可以设置捉10只宠物的名字
set捉宠等级,等级数值
set捉宠名称,{宠物名称|宠物名称……| 宠物名称} '最多可以设置捉10只宠物的名字
set捉宠血量,血量数值
set捉宠魔法,{1|2|3|4|5} '1表示帽子精灵,2表示衣服精灵,3表示武器精灵,4表示左饰精灵,5表示
右饰精灵,一般都设置为3

例子：
set 快速战斗,1
set 快速战斗,0
set 捉宠等级,50 '设置捕捉50级的宠物
set 捉宠名称,卡特|史克杰|史菲洛
set 捉宠名称,那提拉
set 捉宠名称,0 '设置捕捉宠物名称选项前面的勾去掉
set 捉宠等级,0 '设置捕捉宠物等级选项前面的勾去掉
set 捉宠魔法,3 '设置用武器精灵捕捉宠物
set 锁定攻击,扑满乌力|吉比
END;

PATH=ASSA脚本学习区->脚本代码->【W】(封包走路)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【W】(封包走路)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
W x,y,[*]{[a…h|aa…hh|A…H]} '这个指令也可以让人物转向,如W 0,0,东

格式1：W 0,0,{北|东北|东|东南|南|西南|西|西北} 转向
格式2：W 0,0,{A|B|C|D|E|F|G|H} 转向
格式3：W 50,50,{北|东北|东|东南|南|西南|西|西北} 1.82瞬移（面向） 限三步
格式4：W 50,50,{A|B|C|D|E|F|G|H} 1.82瞬移（面向） 限三步
格式5：W 50,50 1.82瞬移（默认面向） 限三步
格式6：W 50,50,aa 在50,50的位置上向北(a)移两步

上面这个W(封包走路)走路命令用得比较多的是它的转向功能.一般用在和NPC对话时.
END;

PATH=ASSA脚本学习区->脚本代码->【walkpos】(坐标)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【walkpos】(坐标)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
walkpos X,Y

注意：使用此指令，必须跟有X和Y两个坐标参数，获得参数的方法如下图：
①数据显示的下面的信息那一栏有"坐标"显示出鼠标在当前窗口的坐标X和Y
② 选上脚本制作器里的"记录走路"，然后在窗口里控制人物走动捕捉

用途：控制人物走到某个坐标，是石器辅助软件里最原始，最普遍，使用率最高的指令
END;

PATH=ASSA脚本学习区->脚本代码->【nearpos】(查找最近坐标)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【nearpos】(查找最近坐标)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
nearpos

任意位置只限于开头任意位置，若后面跟有交通类脚本指令，则相当于"开始位置"般锁定了开始的位置，
举个例子说说吧：

nearpos
say 这里是奇喀喀村，现在出发下海去了
walkpos 63,48
walkpos 60,43
walkpos 60,40
waitmap 200,5,-3
walkpos 133,1007
walkpos 128,1007
walkpos 122,1008
walkpos 116,1010
walkpos 102,1018
walkpos 102,1019
walkpos 102,1022
waitmap 817,5,-3
……

假若上面那段指令没有用"nearpos"指令的话，那么站在128,1007里开始运行脚本， 脚本会在说完"这
里是奇喀喀村，现在出发下海去了"这句话后就马上走到63,48,而你又站在地图 200中了,这样肯定就会
造成坐标错误.用了"nearpos"的话,脚本就会找到在地图200下的最近坐标,比如"122,1008",然后就直接
在122,1008这个指令开始继续运行这个脚本.
END;

PATH=ASSA脚本学习区->脚本代码->【Pickup】(拾道具)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽【Pickup】(拾道具)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽
Pickup {*|北|东北|东|东南|南|西南|西|西北|A|B|C|D|E|F|G|H} [,x,y] '一般后面的坐标是不用加的
,加上去了也没有什么作用
拣取身边以人物为中心，人物身边连同人物站立位置一共9个位置范围内的物品
Pickup * '把人物周围所有东西拾起
pickup北 '把人物北边的道具拾起
pickup A '把人物北边的道具拾起
Pickup 东,12,13 '站在12,13下拾起人物位置东边的东西,一定要站在12,13下才能用这个指令,否则会出错
END;

PATH=ASSA脚本学习区->脚本代码->【button】(点击按钮)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【button】(点击按钮)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
button {OK|CANCEL|确定|取消|上一页|下一页}

例子：
Say hi
waitdlg ?,0,4,-1
button 下一页
waitdlg 你想接这个任务吗？,1,5,-3
button 确定
waitdlg 麻烦你了,1,5,-5
button OK

当窗口出现对话框时，发送封包点击对话框下面的按钮。
与"lclick"指令对比–优点：即使图形加速有问题导致对话框的出现很卡或者鼠标在石器窗口里胡乱移
动也可以点击成功
缺点：有时候窗口没有该按钮（如指令是button 确定，但实际上对话框只有"下一页"而没有"确定"按钮
）有可能会点击不成功或造成掉线
END;

PATH=ASSA脚本学习区->脚本代码->【mousemove】【lclick】【rclick】鼠标指令
DATA=
∽∽∽∽∽∽∽∽【mousemove】【lclick】【rclick】(鼠标移动)(鼠标左击)(鼠标右击)指令∽∽∽∽∽∽∽
注意：使用此类指令，必须跟有X和Y两个坐标参数，获得参数的方法如下：
① 数据显示的下面的信息那一栏有"鼠标"显示出鼠标在当前窗口的坐标X和Y

②　选上脚本制作器里的"记录鼠标"，然后在窗口里单击鼠标左键捕捉

mousemove X,Y

用途：把鼠标移动到某坐标

lclick X,Y

用途：在某坐标位置上单击鼠标左键
注意：即使连点两下也不能充当"双击"
rclick X,Y

用途：在某坐标位置上单击鼠标右键
END;

PATH=ASSA脚本学习区->脚本代码->【waitdlg】【ifdlg】(等待对话框)(判断对话框)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【waitdlg】【ifdlg】(等待对话框)(判断对话框)指令∽∽∽∽∽∽∽∽∽
waitdlg 对话框内容,对话框行数,等待时间[,错误跳转]

一般与NPC对话后，就弹出相应的对话框，此指令用途为可以按设定时间等待指定内容或任意内容的对话框的弹出
，在设定的时间内直到对话框出现才进行下一步，若超时没有出现则执行错误跳转的内容。
例子：
walkpos 278,331
walkpos 278,326
walkpos 278,326
W 0,0,北 '人物方向往北
say 进去
waitdlg ?,0,5,-5 '不管对话是什么内容,只要弹出有对话框就执行下一个指令,如果5秒内没出现
对话框,就跳转到 -5行
button 确定

label 地图错误
walkpos 278,331
walkpos 278,326
walkpos 278,326
W 0,0,A '人物方向往北
say 进去
waitdlg ?,0,5,地图错误 '不管对话是什么内容,只要弹出有对话框就执行下一个指令,如果5秒内没出现
对话框,就跳转到"地图错误"
button 确定 '这里加上地图错误跳转在遇敌的地方使用可以纠正因遇敌而不能跟NPC说话出
现对话框的情况，但有时候却即使有出现对话框也当作没有出现而跳转，所以一般可以在"waidlg"指令后面添加
“delay”（详细请参考"delay"指令）。

walkpos 69,48
walkpos 69,47
walkpos 69,46
walkpos 69,45
W 69,45,A
say 买
waitdlg只要使用这根羽毛，无论在任何地方都可以立刻回,2,5,-5 '等待对话框的第2行是否出现"只要使用….
“是的话就执行下一个指令,不是的话就执行-5行的指令,即"walkpos 69,47”
buy 1,1
delay 500
walkpos 70,45
walkpos 71,45

因最近7.0服务器速度缓慢，出现对话框时难免会比较慢，可能会出现类似"waitmap"注意事项里的错误，请各脚本
编写员留意并想办法解决好。

ifdlg 对话框内容,对话框行数[,正确跳转] '只要对话框内容符合脚本ifdlg中指定行数的内容,就执行正确
跳转的指令
此指令用途为可以指定内容对话框的弹出，只要弹出了指定的内容脚本会执行正确跳转指定的指令

SAY 感谢你使用广二-杰哥2005.3.12为你制作的全智能二转MM喂挂看风景脚本,4
waitdlg ?,0,5,-8 '不管对话是什么内容,只要弹出窗口就执行下一个"ifdlg"指令
,一般这里的不判断内容的等待对话框指令后面要跟"ifdlg"来配套使用,这样既能解决一些会变化的,不固定的对话
框等待(因为有时会遇敌,所要要加等待对话框命令,但那个对话框出现的内容是不固定的,所以就不能在等待对话框
里加判断,要用ifdlg来判断,例如做二转MM时的喂水的那个NPC) 又能解决对话框判断的问题
ifdlg 哇，你带来了很漂亮的宝石呢。,1,+2 '判断对话框的第1行是否为" 哇，你带来了很……",是的话则跳转
到+2行,否则就执行下一行指令"ifdlg 你已经有一条灵石,1,err"

ifdlg 你已经有一条灵石,1,err '判断对话框的第1行是否为"ifdlg 你已经有一条灵石",是的
话就跳转　　　　　　到"err",否则就执行下一行
button 确定
waitdlg 了喔。,2,5,-12 '如果5秒内第2行没出现包含有"了喔。"对话框,就跳转到 -12行
button OK
delay 500
walkpos 49,48
w 49,48,C
SAY 感谢你使用广二-杰哥2005.3.12为你制作的全智能二转MM喂挂看风景脚本,4
waitdlg ?,0,5,-3
delay 500
ifdlg 还好嘛，害我以为是很稀奇的珍宝呢…,3,+5
ifdlg 的运气真的不错喔！,4,+10
ifdlg 普普通通的嘛，真让我失望阿。,3,+3
ifdlg 质地有点差，差强人意啦！,3,+2
ifdlg 呃…虽然不好明讲，不过质地很差呢…,3,+1
’
button 确定
delay 100
doffitem ?风灵项炼
delay 500
goto 换极品风项炼
’
button 确定
delay 500
goto 戴极品风项炼
END;

PATH=ASSA脚本学习区->脚本代码->【waitmap】(等待地图)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【waitmap】(等待地图)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
waitmap 地图编号,等待时间[,错误跳转]

在切换地图时等待此地图编号的地图出现，若出现则执行下一行的指令
例子：
walkpos 72,108
walkpos 72,111
walkpos 72,114
walkpos 72,117
waitmap 100,5,-3 '5秒内还没出现地图100,就自动跳转到-3行,即walkpos 72,111
delay 2000 '这里加延时是怕辅助软件当掉,养成在waitmap后面加延时的习惯
walkpos 260,175
walkpos 260,177
walkpos 260,179
W 260,179,A '这个"W"是封包走路命令,这里的意思是把人物方向转到A(北)
say 芝麻关门
waitdlg 你可以进去,1,5,-5 '这个"waitdlg"是判断对话框命令,将在后面进来解释
Button 确定
Walkpos 13,15
Walkpos 14,16
此类跟NPC对话点对话框进门的情况，一般都要加"waitdlg"命令，等待时间和错误跳转，避免在对NPC说话时因遇敌
而没有出现对话框而出错。不仅是和有可能会遇敌的NPC对话要加"waitdlg"，只要是和NPC对话的一定要加"waitdlg"命令。

注意：①"waitmap"指令其实可以当作"判断条件类"指令
②因为现在的7.5可以"无限制走路"，玩家和脚本都"看到"游戏人物在快速的走到一个地方并切换地图，其实因为
石器服务器的速度有时候跟不上的缘故，游戏人物的实际位置并不是我们所看到的位置，游戏人物其实还在行走的
途中甚至已经遇敌了，如果是这样的情况，按上面所写在"waitmap 地图编号,5,-3"一般可以解决这样的问题。
③石器服务器的缓慢出现了又一问题：其实切换地图已经成功，只是当时因为服务器速度慢地图还没有换，此时脚
本判断成"地图错误"，就跳转到前面的标记里去，此时刚好换完了地图，人物已经出现在下一地图里，而却要走上
一地图的坐标，后果可想而知了。这就要求脚本制作者要想方设法去解决各种各样的问题，使脚本更稳定.可配合
"ifpos"命令使用。
END;

PATH=ASSA脚本学习区->脚本代码->【cls】(清屏)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【cls】(清屏)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
cls

用途：用了此指令，除了有可以清除屏幕的文字的作用，还必须用此指令来消除"waitsay"的屏幕讯息
，不至于让"waitsay"混淆了之前和之后的信息。

错误例子：
say 好了，请玩家现在说出用方法一（继续脚本之后说一）还是用方法二（继续脚本之后说二）
pause
label 一
waitsay 1-10,一,5,二
goto 方法一
label 二
waitsay 1-10,二,5,一
goto 方法二
goto 一

结果因为之前的对话里请玩家现在说出用方法1包含了"1"，所以即使玩家说"1"还是说"2"，所以还是会变成听见了"1"

正确例子：
say 好了，请玩家现在说出用方法一（继续脚本之后说一）还是用方法二（继续脚本之后说二）
pause
cls
label 一
waitsay 1-10,一,5,二
goto 方法一
label 二
waitsay 1-10,二,5,一
goto 方法二
goto 一

继续脚本后用了"cls"指令，脚本就会变成一直处于等待状态，直至玩家说出"一"或者"二"脚本才会跳转去使用方法
一或者二。
END;

PATH=ASSA脚本学习区->脚本代码->【waitsay】(等待说话)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【waitsay】(等待说话)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
waitsay {1-20},等待要出现的说话,等待时间[,错误跳转]

用途：用作判断当时状况，而后应该采取什么行动。如MM喂食时出现的文字可判断MM是否已经喂满该种灵石
；魔法或抗性是否练到一个程度；是否得到某些物品（如不可思议的贝壳）；或者让玩家以自己的发言表示
应该采取什么样的行动等在石器窗口里以对话形式出现的文字。

例子：
Waitsay 1-10,成长率达到最高,5,没有达到最高 '在石器窗口1-10行里,5秒内一定要有以对话形式出现的
"成长率达到最高"才继续执行waitsay后面的指令,否则就跳转到label 没有达到最高waitsay 1-10,成长率达
到最高,5,-4 '在石器窗口1-10行里,5秒内一定要有以对话形式出现的"成长率达到最高"才继续执行waitsay
后面的指令,否则就跳转到-4行,-4行是指在当前命令上,往上数第4行waitsay 1-10,成长率达到最高,5,+6 ’
在石器窗口1-10行里,5秒内一定要有以对话形式出现的"成长率达到最高"才继续执行waitsay后面的指令,
否则就跳转到+6行,+4行是指在当前命令上,往下数第6行

注意：
①该指令为判断类指令.
②此为"包含"指令，如waitsay 1-10,最高,5,-4，即听见的内容包含有"最高"的都达到"正确"的条件,
继续执行waitsay后面的指令
END;

PATH=ASSA脚本学习区->脚本代码->【msg】(弹出窗口)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【msg】(弹出窗口)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
msg 想要在窗口显示的内容[|] '|表示换行
例子：
msg 感谢你使用Assa脚本
msg 感谢你使用Assa脚本|感谢你使用Assa辅助软件|||欢迎光临www.93play.com

END;

PATH=ASSA脚本学习区->脚本代码->【say】(说话)【print】(显示)指令
DATA=
∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽【say】(说话)【print】(显示)指令∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽∽
say说话内容[,color[,x,y]]封包说话 （56字节长度）（0=白,1=蓝绿,2=紫红,3=蓝,4=黄,5=绿,6=深红,7=灰,8=灰蓝,
9=灰绿,10=黑）
print显示内容, [,color[,x,y]]封包说话 （56字节长度）（0=白,1=蓝绿,2=紫红,3=蓝,4=黄,5=绿,6=深红,7=灰,
8=灰蓝,9=灰绿,10=黑）
例子：
say感谢你使用Assa脚本
say感谢你使用Assa脚本,4 '这里说出来的话是显示为黄色的:感谢你使用Assa脚本
say感谢你使用Assa脚本,4,15,14 '在坐标15,14上说出字体为黄色的:感谢你使用Assa脚本

print感谢你使用Assa脚本 '用这个命令说话只显示在你的计算机上,其它玩家是看不到的
print感谢你使用Assa脚本,3 '在你屏幕上显示出来的话是蓝色的:感谢你使用Assa脚本
print感谢你使用Assa脚本,3,12,13 '在坐标12,13上显示出字体为蓝色的:感谢你使用Assa脚本
END;

PATH=ASSA脚本学习区->高手心得
DATA=
学习ASSA脚本制作的朋友必看！
END;

PATH=ASSA脚本学习区->高手心得->墨香篇
DATA=
哈哈
END;

PATH=ASSA脚本学习区->高手心得->墨香篇->1
DATA=
绝对超级菜鸟进阶
第一步，来学习下，什么是脚本和脚本的构成部分。
脚本：就是你们一群懒猪天天用的啦，基本全自动的，运行下，等到逛街回来，呀我到ED了。终于可以去买砖石咯。。。。抓金暴暴咯o(∩_∩)o…拿着母金暴暴勾引公金暴，生一大堆小金暴暴。
为什么会全自动的运行不要手动呢？。
想知道原因么？听我细细道来：
首先脚本的组成绝大部分是走路的命令，大家有时候在运行脚本的时候会经常看到walkpos 100，111.这些一大串的命令。
举例下 地图上不是有坐标么?walkpos 100，111是走到这个地图的100，111坐标。那么怎么实现连续性的走路呢？
比喻下坐标的作用，其实你人物站在一个地方，你打开地图，地图的上面都有一个坐标，也就是说，你无论站在地图那个地方，都会有一个坐标，当你用鼠标在地图上点一个地方，人物就会走到那个地方去，那你现在人物站的地方坐标又变了，你打开地图看下，是不是变了。
比如我在渔村医院的旁边打开地图我的坐标是69，78. 那么在脚本里编辑进去命令
walkpos 70,78 那么这一连串的命令就是人物会一行一行的来根据你编辑的这个坐标来走路
walkpos 71,78
walkpos 72,78
walkpos 73,78 又如说，你现在地图上显示的是你在73，78，你想走到74，78这个坐标，因为74，
walkpos 74,78 ，78的那个位置有个石器MM在向你招手，那么你只要编辑进去walkpos 74,78那么
walkpos 75,78 当你保存下脚本然后运行的时候脚本就会自动的走到74,78这个位置，也就是你朝思
walkpos 76,78 暮想的那个美女站在一起了，高兴了吧。你在想了，要是MM在萨村怎么办？那去萨
walkpos 77,78 村的坐标有几千个要编辑输入啊，不可能我在73，78的坐标 一下子飞到美女身 walkpos 78,78 去吧。到时候，美女都跟别人跑了。别当心，我教你泡MM，现在脚本采集坐标不需要你一个一个输入命令walkpos 79,78 有全自动的哦，下面我来教你如何采集坐标。
在ASSA外挂面板上有个脚本制作，就是战斗设置的下面，情报设置的右边。点击。
出现一个画面。 在记录走路上面打钩下。然后你试试，你人物在地图里走路，用鼠标随便点，在看脚本内容框里，是不是出现一长串的走路坐标了，其实啊，那些坐标都是你刚才走过的坐标。如果你想做去萨村见那个石器美女的脚本的话，那么你就用鼠标一点一点的点击你所要走过的艰辛的路程，为了脚本走路的稳定，所以要一点一点的用鼠标在人物的前面一格点下去，然后脚本会自动生成一大串的坐标。提醒一点如果你点到一块石头，那么脚本也会生成一个坐标，但是当到时候脚本运行到这一行你点到石头的坐标时候你就卡住了，因为你人物走不到石头在的那个坐标啊，卡住了，所以采集坐标一定要注意这一点，不能踩到花花草草哦。。。。。。到时候美女可不要你了哦。。。
脚本还有其它的部分，但是你先弄出一个会自动走路的脚本在来学习下面的吧，
好了听我说了上面的那么多废话，应该懂了吧，现在你可以试试制作一个简单的走路脚本。不会做，我来教你。
END;

PATH=ASSA脚本学习区->高手心得->墨香篇->2
DATA=
超级菜鸟进阶
第二步： 制作一个简单的走路脚本，试起步。
打开脚本制作， 不是有个脚本名称，看到了么？在那里可以输入名字的，你可以输入有个性的脚本名字比如我的墨香脚本，或者你的追萨村美女脚本。脚本密码你也可加上。别人以后拿到你的脚本如果密码输入不对不能查看你的脚本的。
你点 新建→输入脚本名称→采集坐标→保存在脚本目录里→完成。
采集坐标要仔细哦，不能鼠标点太远，如果太远人物会忽略过中间的坐标直接跳到那个坐标。脚本不稳定的。
END;

PATH=ASSA脚本学习区->高手心得->墨香篇->3
DATA=
OK，试试我上面教你的方法，来做一个走路的脚本吧，保存以后是不能直接从脚本列表里看到你刚刚保存的脚本的，要按一下[副控] 然后在按一下 [脚本] 然后你就可以看到你刚才保存的自己的脚本点击运行看看吧，你的人物能不能自动走路。
做出来了么？当你人物能按你刚才采集坐标的时候走路的时候那么你离美女不远了，至少可以走到那里。但是走到那里还是有许多的困难的，下面来简单的教你加些使这个脚本运行起来更加稳定的命令，更加体现你个人脚本魅力的命令。
记住 当你每次编辑进去命令之后，保存下，脚本是不能直接显示你刚刚保存的脚本的，也就是你的脚本已经创建了，但是你要继续修改保存进去一些命令，那么保存以后呢？你点击下别的已经有的脚本运行下，然后在运行你自己的脚本，就会发现，脚本的命令内容变成保存过的了。这点可以提高做脚本的效率也可以帮你早点见到萨村的MM不然等到你做好都人老珠黄。
say 为了美女我辛苦从渔村做脚本去萨村见他，拼了。
当你输入这个命令保存下，运行时候，人物就会自动说：“为了美女我辛苦从渔村做脚本去萨村见，他拼了。”
walkpos 78,78 这里的命令详细解释下，很经常用到，最基本的防卡命令【必学】。走到坐标78，78
delay 800 然后等待800毫秒ifpos的命令解释是，如果坐标是在78，78的话就自动+2（直接跳到下面第二行，
ifpos 78,78，+2 跳到walkpos 79,79，如果不是在78，78那么就执行下一行命令就是goto -3了，-3的
goto -3 意思是，倒上去数第三行也就是walkpos 78,78这里。这里也就所谓的防卡命令，因为要换一个地图啦，所以要检测下坐标，就像你吃饭检查你有没筷子一样。
walkpos 79,79 没筷子不能吃饭，如果坐标没到不能换地图一个道理。。。
waitmap 2000,5,-2 这个命令是换地图，当你用脚本采集坐标的时候走进村庄脚本就自动会显示这个命令。wait是等待 2000是地图编号 5是5毫秒 -2是，如果5毫秒内没有出现
walkpos 79,80 2000这个地图，就自动回到前面两行，goto -3 那这样 脚本就会自动重新检测一遍坐标。
walkpos 80,80
say 美女我来见你了。
end 结束命令。。。脚本到这里结束。
END;

PATH=ASSA脚本学习区->高手心得->墨香篇->4
DATA=
最基本的防卡命令。delay 800就是等待800毫秒，也就是延迟，要稍微等下，如果人物在战斗就不会到达你所要的那个坐标的。
在这里解释下，人物如果在走路中战斗的话，脚本会自动判断你现在的坐标在多少，然后重新修正坐标走路，所以放心，
一般延迟是加载在某个地图非常不稳定或者在准备换一个地图，走进一个村庄，一个洞口，一个NPC面前的时候，加一个延迟，然后在加一个判断坐标命令ifpos。
好了上面介绍的就是当你走到一个洞口面前要进洞口，或者走到一个NPC面前要说话的时候，走到一个村庄面前要进去的时候，你在马上要进去的时候加一个防卡坐标，让脚本更加稳定。如果还不懂………………你的IQ 50-
以上的你基本就可以做一个渔村到萨村的脚本了。可以去见你的美女了。。。GOGO。
END;

PATH=ASSA脚本学习区->高手心得->墨香篇->5
DATA=
下面介绍下一些其他要用到的命令的解释，在平时你要做其他脚本的时候可以添加进去。。。
say hi 说话一下 NPC自动会弹出对话框
waitdlg 你爱我吗,1,5，-3 如果NPC对话框里的第一行5毫秒出现‘你爱我吗’这句话，就自动执行下面的，否则就回到前面3行。--------1 的意思是NPC对话框里第一行。-3的意思是如果没有出现；你爱我吗，就自动回到前面3行，当然 前面三行是你自己编辑的命令 一般是防卡命令了，或者其他的。这个看你自己的。提醒下，一般在马上跟NPC对话或者走进一个洞口一个村庄换一个地图的时候都要加一个防卡命令，也就是检测下坐标，如果你人物不再NPC面前，脚本会自动判断下重新走一次到NPC面前。这样也是为了脚本的稳定button 确定 当你跟NPC对话的时候对话结束后不是都会有确定那个么，确定下才能接任务。。。那么就用这个命令就会自动点确定了。
delay 800 延迟800毫秒，也就是 稍等8毫秒的意思，脚本会稍等800毫秒然后执行下面一连串的命令。
ifmap 2000,+2 其实这个ifmap跟上面的 waitmap 2000,5,-2 是一样的效果，只是ifmap 2000,+2是如果地图是2000那么就跳到下面第二行。如果不是就执行下面第一行。
label 美女 这个命令其实是个标记，这个好好解释下，其实上面所有提示到的命令比如ifmap 2000,+2 这个+2可以换成美女，那么地图编号如果是2000自动会跳转到label 美女这行。waitmap 2000,5,-2 这个-2如果改成美女，那么地图如果不是2000那么自动跳转到label 美女。ifpos 78,78，+2 这个+2如果换成美女，那么坐标如果是78，78那么自动跳转到label 美女 也就是说，会自动跳转到label 美女这行 然后跳转到这行后 中间的命令全部跳过去不执行了，接下去执行的是 label 美女下面的命令。
好了 第一期脚本教程就到这里了。。。。。。还有很多很多的命令可以用的，等你们会用的时候就是一个脚本高手了，这个只是介绍脚本入门的一些。。。希望脚本人员越来越多哈。。。呵呵大家努力加油。。。。。
END;

PATH=ASSA脚本学习区->高手心得->copyvc脚本知识讲座
DATA=
此贴的用意就是带领想做脚本的人们进入菜鸟眼中神秘的脚本世界;
当然在学习做脚本之前肯定要先去看看杰哥的脚本代码指令大全,在以后的讲座里面对复杂的指令我也会详细的分析的!当然脚本的范例会以为杰哥和寂星的脚本为讲解教材;

在这里有什么看不懂的地方,完全可以跟贴问我或者加我QQ996905043进行交流;
好,那我就开始吧!
END;

PATH=ASSA脚本学习区->高手心得->copyvc脚本知识讲座->第一节
DATA=
第一节:交通范例
作用一个初学脚本的菜鸟来说,如果在对杰哥的<脚本代码指令大全>有一点了解后,那么就可以先学着做一段交通脚本;

例如:取至杰哥的渔村记录点到宠物店

label 玛丽娜丝渔村纪录点
''地图(2000)玛丽娜丝渔村
wait 地图,2000
walkpos 64,58
walkpos 63,58
walkpos 62,58
walkpos 62,59
walkpos 62,60
walkpos 62,61
walkpos 62,62
walkpos 62,63
walkpos 63,63
walkpos 64,63
walkpos 65,63
walkpos 66,63
walkpos 67,63
walkpos 68,62
walkpos 69,61
walkpos 70,61
walkpos 71,61
walkpos 72,61
walkpos 73,61
walkpos 74,61
walkpos 75,60
walkpos 75,59
walkpos 75,58
wait 地图,2003,-4 '玛丽娜丝渔村
walkpos 11,16
walkpos 13,16
walkpos 13,17
walkpos 15,17
walkpos 16,17
delay 500
EO
delay 1000
check 座标,!=,16,17,-4
W 0,0,东
在这段指令里面,label 在这里起到的是一个标记作用,标记的用处在于,方便你的跳转,特别是循环脚本的时候

''地图(2000)玛丽娜丝渔村 这个在这里表示注释的意思,这行在脚本实际运行的时候是不会执行的,所以大家以后如果想某行不被执行的时候就可以在这行前面加个 ’ 就可以了

walkpos 这个指令表示移动到坐标X,Y,当然在制作脚本的过程中,这个指令是最轻松的,不用你手动输入,因为外挂的脚本制器有录制走路的功能

wait 地图,2000 这段的意思是等待地图编号2000(渔村),当然这个指令在用的时候一般还会起到一个判断的作用,指令可以是waitmap 2000,5,跳转标记 这就是说等待地图编号为2000,如果在5秒内没有到达地图2000,那么就跳后面的标记那段,如果当前地图编号为2000,那么就执行下一步,这个命令一般会运用在地图切换的地方,用来判断是不是切换了地图.具体运用,以后我会慢慢再讲解.

delay 这里表示等待的时间,单位是毫秒;1000毫秒=1秒 这个指令主要运用于防卡的地方和一些检测的地方,因为那是需要时间的,当然如果你自己的网速卡的话,为了增加脚本的稳定性,你可以delay 的时间大点;反之这可以设下小点

EO 这个指也很简单,就是相当做了一个动作,EO的实际作用就是刷新当前的游戏信息,只用在防卡上,比如说:人物现在所在的位置是16,17 但是别人看你的人物却是在15,17上,这表示你的人物卡位了,所以在脚本运用中,如果加上EO指令后,人物就会站回它真实的坐际上
卡位 卡位就是你的人物已经到这个位置了,但实际上人物还没有到这个位置上,所以就会碰到我明明在某个NPC面前了,可是讲话,NPC却没有反应,这就很大的可能卡位了,这个你做个动作(意义跟EO一样),人物就会回到他真实的坐标上.

check 这个命令在ASSA脚本里面运用得当相的广,所以能够适时的运用这个指令,会达到很多不同的功能,当然它本身的功能就是检测的意思,在上面这段代码里的意思就是检测当前坐标,如果不等于(!=),16,17 的时候就跳转到 -4(由本行为0算起,向上一行表示-1,两行表示-2,以次类推,-4就是walkpos 16,17这一行) 就是如果人物当前坐标不是16,17 那就会再执行一次移动到16,17这个坐标.

w 0,0,东 这个就比较简单了,就是在当前位置,人物面向东…当然这个也可以用一些大写字母来代替的:A 代表东,C代表东,E代表南,G代表西;在石器里是可以有8个方向的,所以还有方向按顺时针来表示就是ABCDEFGH八个方向,这个指令主要是用于对话NPC,或者某个需要方向的时候.
END;

PATH=ASSA脚本学习区->高手心得->copyvc脚本知识讲座->第二节
DATA=
第二节:飞机脚本为例;

label GOGOGO
cls
join 1
delay 1000
check 说话,1-10,like,支付了1000 Stone！,加上了
check 说话,1-10,like,支付了3000 Stone！,加上了
check 说话,1-10,like,支付了10000 Stone！,加上了
join 0
goto GOGOGO
label 加上了
cls
say 还没登机的朋友快检票登机啦，飞机将会在3秒后起飞！
say Three！
delay 1000
say Two！
delay 1000
say One！
delay 1000
say gogogo
cls
delay 1000
check 说话,1-10,like,加美航空：嘎（到～～～～达了）,+3
check 说话,1-10,like,加美航空：嘎（到～～～～达了！开始空投啰，请做好着地准备！）,+2
goto -3
delay 1000
check 说话,1-10,like,团队已解散！,+2
goto -2
cls
end
那我就来详细的看看这段代码,label 这个上节已经讲过就是起一个标识的作用,以便于跳转;

cls 这个指令表示清除游戏屏幕里所有的文字,这个指令一般运用于要说话或者print之前;

join 1 这是加入组队的指令,如果join 0就表示退出组队,这个指令经常用到的就是坐飞机加加美和2DMM任务时装水加队于引路人时,其它也有脱机自动组队也有可能用到

check 说话,1-10,like,支付了1000 Stone！,加上了
上节讲过,check 这个命令功能运用非常广,基本上有用到需要检测的时候,都可以用这个命令,所以这段代码的意思就是:检测屏幕由下往上10行内,如果出现了"支付了1000 Stone！"就跳转到label 加上了这行开始执行,如果没有出现就执行下一行

join 0 脱离团队,这里主要是怕有人捣乱站到加美的位置上了,所以加上这个会不容易加上人,而加不上加美;

goto GOGOGO这就是label 方便的地方了,可以直接goto(跳转)至label GOGOGO这行开始执行,如果没加上加美在这里就会一直循环,直到加上加美为止.

say gogogo 这就是相当于我们坐上加美后,说出发,或者go,加美就会起飞

cls 在这里的作用是清出屏幕,以免有的相当的字行在10行内出现,就会导致脚本出错,清过屏后这样就不容易出错.

check 说话,1-10,like,加美航空：嘎（到～～～～达了）,+3
这段指令就是加美到达的语句检测.当然实际运行用在这个+3的那行可以是join 0 因为到达后就可以直接脱离团队,而不用等它自动解散.

end 表示结束,这个指令一般运用于最后脚本运行完后才使用,比如说这里,如果我们坐完飞机还需要接着做其它操作的话,那这个end就不能在这里出现,如果在这里出现就表示坐完飞机到达目的地后脚本就结束.
END;

PATH=ASSA脚本学习区->高手心得->copyvc脚本知识讲座->第三节
DATA=
第三节:这里讲解过原藏或者近藏的对话;
label 打藏哥
walkpos 472,298
waitpos 472,298,1,-4
w 472,298,A
say 你的发型无敌了
waitdlg ?,0,1,+6
set 自动逃跑,0
button 确定
delay 1000
iffight !=,0,-1
set 自动逃跑,1
walkpos 472,296
waitpos 472,296,1,打藏哥
这段是我自己做的过近藏的对话;

walkpos 472,298 这是由萨村方向走到近藏面前的一步

waitpos 472,298,1,-4 这是一个坐标防卡判断;等待坐标472,298,在1秒内没有出现则执行-4,否则执行下一步;

w 472,298,A 方向向北,在坐标472,298位置上向面向北;

say 你的发型无敌了 对话NPC;

waitdlg ?,0,1,+6 这里注意,这里的意思是:等待对话框,如果在1秒出现则执行下一步,如果没有出现则执行+6这行;这里讲讲,本来一般的都是waitdlg ?,0,1,-?这里为什么要+6呢,大家都知道近藏这家伙经常给人虐?所以有时他都不在,所以我设置了不如果1秒内没有出现对话框就表示它不在,就直接跳过;这样可以节约一点时间

set 自动逃跑,0 set 就是设定的意思;这里表示,将自动逃跑,设置为取消状态,就表示不逃跑;如果后面的0改成1就表示选定自动逃跑;

button 确定 这里就是点击对话框上的确定,当然也有"OK",“下一页”,“取消”…

iffight !=,0,-1 这里iffight的意思是判断战斗回合数,不等于0的时候跳转上一行,就是说如果有战斗就执行上一步,一直到战斗结束后再执行下一步.

walkpos 472,296
waitpos 472,296,1,打藏哥 这两行合在一起讲:就是说移动坐标472,296,等待这个坐标,如果当前人物的坐标不在472,296那就跳转label 打藏哥 这行.
END;

PATH=ASSA脚本学习区->高手心得->copyvc脚本知识讲座->关于ASSA脚本里的变量@
DATA=
看来大家对这个比较有兴趣些;其实这个并不高深,跟普通的脚本指令也没多大区别,而且有些东西都可以互通互用的;
进入主题:
我笼统的把脚本里的变量分为两个方面
END;

PATH=ASSA脚本学习区->高手心得->copyvc脚本知识讲座->关于ASSA脚本里的变量@->1.固定变量
DATA=
1.固定变量:这种变量一般不会在实际应用的时候有所变化的,固定的是什么就是什么?以下是我所知的几个固定变量:(当然能用到脚本里的,肯定不只这些,不过我暂时只知道这些)
@[寻找NPCID.NPC的名字]
@[寻找宠物.宠物的名字]
@[日期]
@[时间]
@[人物名称]
@[人物等级]
@[战斗回合]
@[石币]
@[tick]
@[地图编号]
@[地图名称]
@[座标X]
@[座标Y]
@[寻找道具.道具名字]
上面这些固定变量是可以直接跟ASSA里的指令一起使用的,比如说:print @[座标X] 这个指令就可以在屏幕上显示人物当前坐标里的X的数值;其实的大家都可用print 变义命令 来看看这个变量的实际作用;所以固定变量的作用是有限的,它的优点在于方便,缺点在于没有变化变量灵活;而且用到的地方也不是很多,所以大家可以看看就好,当玩的就行.
END;

PATH=ASSA脚本学习区->高手心得->copyvc脚本知识讲座->关于ASSA脚本里的变量@->2.变化变量
DATA=
2.变化变量:顾名思义,就是这个变量是可以变化的,怎么样的变化?这里不好解释,我通俗点说就是:变化变量是你想让它是什么,代表一个什么值,或者是一个字,一行字,一个字数,等等;运用的就是它的变化;当然条件是你要先定义出一个变量,就大比方说你要用泥巴去捏一个东西;你就给这坨泥巴取名叫泥巴A,然后才能开始捏你想捏的造型,我这样比喻不知道大家会不会懂,下面我就进如实例来说明:
dim @a 我给一坨泥巴取名叫@a,当然如果多坨的话,可以再取名叫@b…等等,中间用半角状态的逗号隔开;1个dim最多定义5个泥巴.

let @a,=,我是copyvc 我现在开始给你这泥巴捏造型了,我让@a有了个一值;这个什就是 我是copyvc;

msg @a 这里就是输出;就是说这个三行指令执行完后会跳个框框出来说:我是copyvc

当然这个一最简单的变量例子,在ASSA脚本应用当中这个根本没用,如果直接用脚本指令的话,就只需要msg 我是copyvc就行了.
变量中常用的几个命令我说下:
1.dim 这个命令是必须的,就是定义一个变量;如果用在脚本的话,一般在脚本的最开始,特别是会循环的脚本,更要在循环的执行范围之外,因为1个变量在一个脚本里只能被定义1次,如果再执行这个指令,脚本就会出错;这点要记住,
2.let 这个命令是赋值的意思,这里的赋值是脚本制作者在需要用的时候所给个值;使用脚本的人不需要知道这个;
3.input 这个命令就是跟第二个命令功能一样,但不同的是,这个命令表示是需要使用这个脚本的人赋的值;

变量的主要命令就这个三个,怎么样?很简单吧?嘿嘿!这三个命令中,第一和第三个都比较简单,而且也比较固定;关键就是第二个命令,因为变量的这个变化之妙也就是因为这个let
let 的功能是变量中最重要的部分;它可以计算,可以联接…等等~~~

let @a,=,50 这行指令是let 中运用最简单的一个例子,就是说让@a的值为50;当然在做脚本的时候当然不可能就这简单,脚本有时需要做到它有计算的能力…以我做的自动抓练存1级宠为例;

我们在游戏里抓的1级宠,它的四围值通常都不一样,所以我们在练宠后不太好用同个4V值来计算宠物的成长,那样就不准确了,那么我就得让这个变量有自己检测到宠物的4V数据,并保存着备用;

dim @x,@g,@f,@m '1个dim 最多可以定义5个变量;如果要定义更多变量,可以在下一行再dim;在这里我定义的是@x为血,@g为攻,@f为防,@m为敏
假如说我现在身上已经有脚本已经抓好的1只宠,在宠物的位置1

let @x,=,1 '这里因为我不知道抓到的宠血是多少,所以我给它赋值为1

check 宠物1,HP,=,@x,+3 '检测宠物1的HP,是不是@x,如果是就跳转到+3这行,如果不是,就执行下一行;

let @x,+,1 '好戏来了,这里就是它的计算功能了,我让@x,加1,有人会觉得为什么不加2呢?因为在我们不知道血的情况下,加1是最准确,加2的话,有可能会过多;

goto -2 跳转-2,就是说我让@x加了1后再来检测,看是不是我宠物1现在的HP,如果不是,那么就再加1,一直+到我宠物1的HP数值一样为止;剩下的攻防敏是一样的;我把整段都一起弄出来;

dim @x,@g,@f,@m
let @x,=,1
check 宠物1,HP,=,@x,+3
let @x,+,1
goto -2
let @g,=,1
check 宠物1,攻击,=,@g,+3
let @g,+,1
goto -2
let @f,=,1
check 宠物1,防御,=,@f,+3
let @f,+,1
goto -2
let @m,=,1
check 宠物1,敏捷,=,@m,+3
let @m,+,1
goto -2

当执行完上面这段代码后,你的宠物1的四围数值就已经被记录在案了.如果你想知道它们是什么数值,就可以直接用ASSA命令
print @x
print @g
print @f
print @m

你的屏幕上就会由上到下四行,出行你宠物1的四围数值,呵呵,是不是觉得有点神奇?那么如果你想把宠物的名字改成四围.那这里就要再用到let 的一个联连功能;具体运用如下:

我假设宠物1的四V是,38 8 5 6;

let @x,&,| 这个指令就是让@x的值为38| 呵呵怎么可以有一竖呢,我前面讲过了,在VB语言范围内变量可以是任何东西,甚至符号;

let @x,&,@g @x的值为38|8

let @x,&,| @x的值为38|8|

let @x,&,@f @x的值为38|8|5

let @x,&,| @x的值为38|8|5|

let @x,&,@m @x的值为38|8|5|6

这个时候@x就是这串字符"38|8|5|6"

chname 宠物1,@x 这个时候你再看你的宠物1,它的名字就变成了"38|8|5|6"

呵呵,好玩吧,当然这里只用到了+和&的功能,当然还有-,*,\还有取整int 等等…

想学来玩的,大家可以互相交流交流…
END;

PATH=ASSA脚本学习区->强者脱机脚本指令
DATA=
脱机的指令都是可以在内挂脚本中直接使用的,就以前使用的内挂指令,只不过内挂更新后会加入一些新的指令,一求方便;脱机的主要功能就变成了挂机,而运行脚本方面的功能就变少了;现在我就来说说脱机的一些指令和作用:

w x,y,a|b|c|d|e|f|g|h 这是脱机脚本的走路模式,x,y代表坐标,abcdefgh代表不同的8个方向;和内挂的walkpos 功能差不多,不同的是walkpos 有遇敌等待的功能;这就比w x,y, 要方便;

ifpos x,y,跳转标记 这个指令表示判断坐标,而且是固定的肯定判断,跟内挂中的check 座标,=,x,y,跳转标记 功能一样,不同的是脱机只能表示肯定跳转,但是内挂的可以check 座标,!=,x,y,跳转标记 来否定跳转;

ifmap n,跳转标记 这是判断地图的,和上面的坐标定义是一样的,都是代表肯定跳转的,而内挂可以用肯定或者否定,所以内挂更方便;

ifsay 1-20,说话的内容,跳转标记 这个指令和内挂的check 说话,1-20,说话的内容,跳转标记,功能是一样的;都是判断当前屏幕由下向上20行以内的说话内容的;

ifdlg 对话框里的一行字或者一行里的几个字,1或者2或者3或者4,跳转标记 这个是判断对话框内容的,跟内挂中的chceck 对话,对话内容,行数,跳转标记,功能一样;喂MM的时候就可以用到这个命令,通过对话框的判断来确定包里还有没有灵石,或者有了灵石没喂什么的

ifitem ?,=,不可思议的贝壳,跳转标记 这是道具的用的,跟内挂的check 道具,?,=,不可思议的贝壳,跳转标记 一样

ifpet 绿龟,>,1,跳转标记 这个判断宠物的,如果身上绿龟的数量大于1就跳转,否则执行下一行.和内挂的check 宠物,绿龟,>,1,跳转标记 作用一样

ifstone 判断石币数量;

iffight 判断战斗回合的;这个主要用于防卡设置里,内挂经常也会用到这个,格式为: iffight !=,0,跳转

还有一些命令就基本上跟内挂的是一样的,详细情参阅杰哥的ASSA脚本指令,这些脱机命令其实都可以在内挂中使用,只不过功能没有内挂的check 这个命令强,大多数命令都有的,而且脱机的主要功能只能是挂机练级,所以它在脚本方面肯定不如内挂来的厉害;当然这并不影响有些强人,对强者脱机脚本的挖掘.

另外脱机脚本是不能用变量的,而且也不能run 和call …

还有其它的可以联系我,大家一起交流,脱机脚本如果用得好的,会比内挂脚本更受欢迎

脱机里没有,内挂的是check 宠物1-5中的一个,LV,>=,级数,跳转
copyvc
这个指令脱机支持的
没这个指令就写不出脱机mm一条龙

END;

PATH=ASSA脚本学习区->强者脱机脚本指令->存钱
DATA=
save stone [,mode]存钱 （在村长家使用）
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->取钱
DATA=
load stone [,mode]取钱 （在村长家使用）
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->转换地图
DATA=
chmap x,y [,mode]转换地图 （站在地图转换点使用）
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->封包说话
DATA=
say text [,color[,x,y]]封包说话 （56字节长度）
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->买物品
DATA=
buy index,num [,x,y]买物品 （在买的对话框使用）
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->发邮件
DATA=
mail index, text发邮件

格式1：mail 1,你好吗

格式2：mail 1-40,你好吗 发信给 1-40
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->合成和料理
DATA=
LL pet,fun,items合成和料理

格式1：LL 1,2,1|2|3-5

格式2：LL 1,2,高级鱼|毛蟹|大王花枝|活跳跳章鱼|高级玛丽娜丝虾
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->卖物品
DATA=
SellItem items,stone [,x,y]卖物品（在卖的对话框使用，stone为对话框里的石头数值）

格式1：sellitem 1|2|3|4-6,1000指定道具1,2,3,4,5,6 以1000卖掉

格式2：sellitem 高级鱼,1000 把道具1-15中为 高级鱼 的全部都以1000卖掉

格式2：sellitem ?高级鱼,1000 在道具1-15中找到第一个的 高级鱼 以1000卖掉
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->使用道具
DATA=
UseItem items, who [,x,y]使用道具items格式：1|2|3-6 数值:1-15, wh0=人物,1-5宠物

格式1：useitem 1|2|3|4-6指定道具1,2,3,4,5,6 给人物吃掉

格式2：useitem 豪华船生鱼片 把道具1-15中为 豪华船生鱼片 的全部 都给人物吃掉

格式2：useitem ?豪华船生鱼片 在道具1-15中找到第一个的 豪华船生鱼片 都给人物吃掉

END;

PATH=ASSA脚本学习区->强者脱机脚本指令->丢出道具
DATA=
DoffItem items [,x,y]丢出道具items格式：1|2|3-6 数值:1-15

格式1：doffitem 1|2|3|4-6指定道具1,2,3,4,5,6 被丢出

格式2：doffitem 豪华船生鱼片 把道具1-15中为 豪华船生鱼片 的全部 被丢出

格式2：doffitem ?豪华船生鱼片 在道具1-15中找到第一个的 豪华船生鱼片 被丢出
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->拾东西
DATA=
Pickup pos [,x,y]拾东西

格式1：pickup * 把人物周围东西拾起

格式2：pickup {北|东北|东|东南|南|西南|西|西北}

格式3：pickup {A|B|C|D|E|F|G|H}
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->对话框按钮
DATA=
Button btn [,x,y]对话框按钮（在打开对话框使用）

格式1：button index(1…8) 选择行数

格式2：button {OK|CANCEL|确定|取消|上一页|下一页}
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->移动道具
DATA=
MoveItem items, index移动道具

格式1：moveitem 1,15 把道具1 移到 15
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->交货封包
DATA=
Packet [x,y]交货封包（在打开对话框使用）
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->不限等封包
DATA=
Pass [x,y]不限等封包（在打开对话框使用）
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->走路封包
DATA=
W x,y,

{[a…h|aa…hh|A…H]}走路封包 *为不显示

格式1：W 0,0,{北|东北|东|东南|南|西南|西|西北}转向

格式2：W 0,0,{A|B|C|D|E|F|G|H}转向

格式3：W 50,50,{北|东北|东|东南|南|西南|西|西北} 1.82瞬移（面向） 限三步

格式4：W 50,50,{A|B|C|D|E|F|G|H}1.82瞬移（面向） 限三步

格式5：W 50,501.82瞬移（默认面向） 限三步

格式6：W 50,50,aa 在50,50的位置上向北(a)移两步
END;

PATH=ASSA脚本学习区->强者脱机脚本指令->判断跳转命令
DATA=
判断跳转命令：

label text标签

return返回 call

goto label跳转 label 格式：可以是文字，或 +[-]行数

call label调用模块

ifmap num, label 判断地图

ifpos x,y, label判断人物坐标

ifstone {=|!=|<|<=|>=|>},stone, label 判断石头数值

ifitem {名称|空位},{=|!=|<|<=|>=|>},数量,{跳转符号}

例如：ifitem 空位,>,5,XX2 检测道具1-15, 其中有 空位>5 则跳转

ifitem {?|*},{=|!=},{名称|空位},{跳转符号}

例如：ifitem ?,=,晒干的鱼,XX2 检测道具1-15, 其中有一个 晒干的鱼 则跳转

ifitem {1|2|4-5},{=|!=},{名称|空位},{跳转符号}

例如：ifitem 4-5,=,晒干的鱼,XX2 检测道具4-5,都是 晒干的鱼 则跳转

ifpet {名称|空位},{=|!=|<|<=|>=|>},数量,{跳转符号}

ifpet {?|*},{=|!=},{名称|空位},{跳转符号}

ifpet {1|2|4-5},{=|!=},{名称|空位},{跳转符号}

check {人物},{名称|LV|HP|MP|石币|攻击|防御|敏捷|魅力|转生},{=|!=|<|<=|>=|>},数值,{跳转符号}

check {宠物1-5},{名称|LV|HP|攻击|防御|敏捷|魅力|忠诚|职位|技能1-7},{=|!=|<|<=|>=|>},数值,{跳转符号}
END;

阅读(278)| 评论(0) |删除 |推送 |置顶