深入理解控制台程序
目录(?)[+]
控制台程序的误区
在Delphi中可以创建Console--控制台应用程序。这种类型的程序在Win32文本模式下，或者CUI（文本用户界面）子系统中运行。如图一。
尽管从表面上看起来控制台应用程序界面简单、没什么吸引力。但是，它的确非常能干。在后面的章节中，我们将证明这一点。GUI程序能做的，它都能做；而且，可执行文件大小甚至只是前者的十分之一。
运行中的控制台应用程序
控制台应用程序可不是想象中那么简单。很多程序员其实没有真正了解它的内涵和威力。以下是一些常见的误解--之所以有这些误解，是因为控制台应用程序看起来就像古老的DOS程序那么简陋。看看你是否也有这些误解：
* 控制台应用程序不是真正的32位程序。错。我们可以用Readln/Writeln等标准I/O函数进行输入/输出操作，但这只是编译器给予的方便。实际上，在内部使用和其它32位Windows程序一样的I/O函数进行输入/输出操作。
* 控制台应用程序在实模式DOS窗口中运行。完全错误。事实正好相反。DOS程序通过一个名为Winoldap的控制台程序来运行，而这个程序则是在32位Windows控制台窗口中运行。原理上，Winoldap利用x86的"Virtual86"模式来虚拟实模式。
* 控制台应用程序不能调用Windows API。错。在控制台应用程序中，所有的Windows API都可供使用。
* 控制台程序不能显示窗口；GUI程序不能从控制台读数据，亦不能向控制台写数据；控制台程序不能使用VCL。控制台程序在文本模式运行，没有窗体。于是，很多人以为不能用图形控件、甚至所有的VCL。这种想法不对。控制台程序只不过是一种特殊的窗口，系统把进程定位到这个窗口，将标准输入/输出/错误等文件句柄映射到控制台的读/写操作上。所有的应用程序都可以定位自己的控制台，反之，控制台程序自然也可以创建窗口。
基本输入/输出
要在Delphi中创建控制台程序，用 {$APPTYPE} 编译指示符通知Windows应用程序在控制台子系统中运行。（注意：不要在大括号和指示符之间加空格。）当然还有其它方法可以实现控制台程序，不过这个最简单方便。程序开始运行后，将会循序进行以下操作：
* 如果创建者进程（父进程）有自己的控制台，新进程（子进程）就继承这个控制台。否则，定为自己的控制台。
* 子进程的标准文件句柄（Delphi中的输入/输出）被映射到新控制台窗口的Read/Write操作。
Pascal函数Readln和Writeln把输入/输出句柄当作文件句柄。DOS下，文件句柄直接映射到键盘和屏幕缓冲区。而在Windows下，它们被映射到新控制台窗口的输入/输出缓冲区。可以在旧的DOS Pascal程序源代码中加上{$APPTYPE CONSOLE} 指示符，把它转换成控制台程序。唯一要注意的是，有些关于CRT或者BGI等等屏幕或者图形单元不能继续使用。而且，有些Pascal的低级库函数（输入/输出函数）在Win32保护模式中也不能使用。
在C语言中，控制台程序和GUI进程有区别。GUI进程入口点被命名为WinMain，而控制台程序进程则很简单--main。当然，在Delphi中，入口点总是存在于主dpr文件的未命名begin部分。但是，典型的Delphi应用总是简单调用Application.Run，从这个过程起，控制台程序可以写入所有的代码。你可以use其它单元，不过最简单的控制台程序往往在.dpr单元内实现多数、甚至所有功能代码。下面的代码展示了一个简单的例子，显示著名的"你好，世界"字样。
- {$APPTYPE CONSOLE}
- program HelloWorld;
- var
- sName: string;
- begin
- Write('你是谁？');
- Readln(sName);
- Writeln('你好', sName,'欢迎来到控制台程序世界！');
- Writeln('按 退出。');
- Readln;
- end.
在做比较小的控制台程序时，最好在IDE外部编辑、编译，这样比较方便些。调用Delphi的命令行编译器可以节省内存消耗，而且不会产生垃圾文件。编译操作很简单。首先，确保{$Delphi}/Bin目录在搜索路径中。你也可以做一个简单的批处理文件，在Windows中调用。右键点击任何一个MS-DOS快捷方式，输入批处理文件名，确保路径正确。调用dcc32程序，用要编译的.dpr文件作为参数：
C:/> DCC32 Listing1.dpr
上面这个命令产生了Listing1.exe文件。
高级I/O句柄：文件句柄
在讨论高级I/O句柄之前，我们先来简单看看什么是控制台句柄，以及如何利用控制台句柄。
前面讲过，创建新控制台时，或者新进程连接到父进程控制台时，操作系统自动创建三个"标准"文件句柄。在高级控制台编程中，用两个API函数控制这些句柄。
function GetStdHandle(nStdHandle: DWORD): THandle; stdcall;
function SetStdHandle(nStdHandle: DWORD; hHandle: THandle): BOOL; stdcall;
前者简单地返回当前标准文件句柄的一个拷贝，后者设置标准句柄为一个你提供的打开的文件句柄。三个标准文件句柄如下：
* STD_INPUT_HANDLE 对应Delphi的Input变量
* STD_OUTPUT_HANDLE 对应Delphi的Output变量
* STD_ERROR_HANDLE 标准输出（不用Delphi变量）
下面的例子展示了简单的应用。程序用一个stream对象向标准输出控制台窗口写数据，而没有使用Writeln。图一是运行结果的截屏。这是一个典型的GetStdHandle运用例子。GetStdHandle取得句柄，传递给另外一个需要得到文件句柄的Windows API调用。SetStdHandle则通常用来重定向子进程的标准文件句柄。
- {$APPTYPE CONSOLE}
- program FileOutput;
- uses Classes, Windows;
- var
- strmOut: THandleStream;
- hOutput: THandle;
- begin
- { 取得当前文件操作 }
- hOutput := GetStdHandle(STD_OUTPUT_HANDLE);
- { 创建新的操作流，用自己的流对象写入 }
- strmOut := THandleStream.Create(hOutput);
- strmOut.Write('控制台程序范例。'+ #13#10, 26);
- strmOut.Write('在控制台窗口以文本模式输出。' + #13#10, 36);
- strmOut.Free;
- Readln;
- end.
高级I/O操作：读输入事件
用基本I/O例程就可以读写控制台数据。不过，因为控制台只是一种特殊的窗口，我们可以用其它API调用来操作这个窗口，接收控制台输入（包括鼠标输入）。在这个部分，我们将讨论不用Readln，从较底层接收控制台键盘和鼠标输入。
Windows可以识别两种层次的控制台I/O。上面的部分已经看到"较高层次"的控制台I/O，这种类型的控制台输入API调用是：
function ReadFile(hFile: THandle; var Buffer; nNumberOfBytesToRead: DWORD;
var lpNumberOfBytesRead: DWORD; lpOverlapped: POverlapped): BOOL; stdcall;
function ReadConsole(hConsoleInput: THandle; lpBuffer: Pointer; nNumberOfCharsToRead: DWORD;
var lpNumberOfCharsRead: DWORD; lpReserved: Pointer):BOOL; stdcall;
在控制台窗口中使用上面两个函数效果基本一样。不同的是ReadConsole能从控制台读入Unicode字符，而ReadFile可以用于非控制台操作，比如可能重定向到标准输入的文件、内存操作。控制台根据当前代码页判断输入的是ANSI还是Unicode字符，这个问题我们稍后讨论。除非你需要读Unicode数据，否则就使用Readln。它映射到ReadFile，能够正确地操作重定向了的输入。
可以注意到，两个函数都需要文件句柄作为参数。可以用GetStdHandle从控制台得到参数句柄。实际上，所有这些API调用都需要传入控制台句柄，要么是输入缓冲句柄，要么是输出缓冲句柄。
为了更全面地控制控制台输入，也可以用"底层"输入的方法，这种方法在控制台事件队列中设置一个钩子。事件队列和Windows消息队列差不多，不过是接收输入事件，而非消息。在控制"底层"控制台输入时，可以用以下五个关键的API函数：
function ReadConsoleInput(hConsoleInput: THandle; var lpBuffer: TInputRecord; nLength: DWORD;
var lpNumberOfEventsRead: DWORD): BOOL; stdcall;
function WriteConsoleInput(hConsoleInput: THandle; const lpBuffer: TInputRecord; nLength: DWORD;
var lpNumberOfEventsWritten: DWORD): BOOL; stdcall;
function PeekConsoleInput(hConsoleInput: THandle; var lpBuffer: TInputRecord; nLength: DWORD;
var lpNumberOfEventsRead: DWORD): BOOL; stdcall;
function GetNumberOfConsoleInputEvents(hConsoleInput: THandle; var lpNumberOfEvents: DWORD):
BOOL; stdcall;
function FlushConsoleInputBuffer(hConsoleInput: THandle): BOOL; stdcall;
hConsoleInput参数是API调用的返回值。
GetStdHandle(STD_INPUT_HANDLE)
其它的参数可以见其名而知其意，不再赘述。唯一要注意的是TinputRecord类型。TinputRecord是INPUT_RECORD结构的Delphi别名。这个结构其实是五种输入事件类型的集合。第一个字段，EventType，指明后面跟着的是何种事件记录类型。在MSDN上有事件类型的详细信息。我们最关心的是鼠标和键盘事件。另外三种用得较少的事件类型是：
* WINDOW_BUFFER_SIZE_EVENT 屏幕大小改变时发出
* MENU_EVENT 用户使用控制台菜单或工具栏时发出
* FOCUS_EVENT 控制台得到输入焦点时发出
WINDOW_BUFFER_SIZE事件很不常用，因为一般而言用户不会主动去改变控制台窗口大小。WINDOW_BUFFER_SIZE事件之发生于某些特定的控制台模式，且常常用于重画屏幕。另外两个事件，MENU_EVENT和FOCUS_EVENT由Windows内部使用，基本找不到相关文档资料。微软甚至建议应该"忽略它们"。
如果控制台处在活动状态，当一个键被按下时，就激发KEY_EVENT事件。普通的字母、数字等可打印键和Shift/Ctrl、功能键等都是如此，类似于WM_KEYPRESS事件。在KEY_EVENT_RECORD类型中，可以包括以下数据：
* bKeyDown 如果有键被按下，则为真；被释放则为假。
* wRepeatCount 在一行里的击键次数。
* wVirtualKeyCode 按键的虚拟键码。
* wVirtualScanCode 键盘扫描码。
* UnicodeChar 按下的Unicode字符。
* AsciiChar 按下的ASCII字符。
* dwControlKeyState 控制键状态。
当控制台处于正确的模式（缺省状态），在屏幕缓冲上产生鼠标事件时，激发MOUSE_EVENT事件。接受到的数据记录包括以下信息：
* dwMousePosition 事件发生时鼠标的坐标。
* dwButtonState 按下的鼠标键的位掩码。
* dwControlKeyState 控制键状态。
* dwEventFlags 事件类型。
比较难以理解的是鼠标键位掩码。它包括了32个可按下的鼠标键位置。一般人不会用到32键鼠标，所以只有前五个键被预定义为常量。对于典型的三键鼠标，要用到的常量是：
* FROM_LEFT_1ST_BUTTON_PRESSED
* RIGHTMOST_BUTTON_PRESSED
* FROM_LEFT_2ND_BUTTON_PRESSED
这三个变量对应于三个DWORD值，循序分别为：左、右、左边第二个。
下面的代码段展示了如何截获键盘和鼠标事件。程序开始运行时，会发生一些很有意思的事。首先，注意[Ctrl][C]组合键，按下这两个键，程序会结束。Windows安装了一个内部击键句柄，[Ctrl][C]和[Ctrl][Break]都会导致程序结束。
- {$APPTYPE CONSOLE}
- program ConsoleInput;
- uses Windows;
- var
- hInput: THandle;
- arrInputRecs: array[0..9] of TInputRecord;
- dwCur, dwCount: DWORD;
- cCur: Char;
- coorCur: TCoord;
- begin
- hInput := GetStdHandle(STD_INPUT_HANDLE);
- while True do begin
- ReadConsoleInput(hInput, arrInputRecs[0], 10, dwCount);
- for dwCur := 0 to 10 - 1 do
- case arrInputRecs[dwCur].EventType of
- KEY_EVENT:
- with arrInputRecs[dwCur].Event.KeyEvent do begin
- cCur := AsciiChar;
- if cCur = '' then
- if bKeyDown then
- Writeln('按下了不可打印键。')
- else
- Writeln('松开了不可打印键。')
- //你也可以用wVirtualKeyCode取得功能键码，F1是112，以此类推。
- else
- if bKeyDown then
- Writeln('按下 ', cCur, ' ',
- wRepeatCount, ' 次。')
- else
- Writeln('松开 ', cCur, ' 键。');
- end;
- { 为避免与WINDOWS的mouse_event函数冲突，Delphi重命名了MOUSE_EVENT事件。}
- _MOUSE_EVENT:
- with arrInputRecs[dwCur].Event.MouseEvent do
- begin
- coorCur := dwMousePosition;
- if dwEventFlags = 0 then
- Writeln('鼠标键按下，坐标：', coorCur.X,
- ',', coorCur.Y);
- end;
- end; // case
- end; // while
- end.
在程序刚开始运行时，偶尔会看到"键"这个字符串显示出来。这是因为程序一开始运行，[Enter]键就被释放。字符串'松开了' + #13 + '键。' 被打印出来。
最后要注意的一点是，有关KEY_EVENT_RECORD类型的文档指出，按下/松开[Alt]键而没有同时按下其它键，不会引发输入事件。但是，我们的示例程序却表明文档资料不正确。按下[Alt]键同样会引发输入事件。
高级I/O：向输出缓冲写数据
用标准的运行是函数Write和Writeln可以实现简单输入，这是从较高层面进行控制台存取操作。下面是两个基本的高层次函数：
function WriteFile(hFile: THandle; const Buffer; nNumberOfBytesToWrite: DWORD;
var lpNumberOfBytesWritten: DWORD; lpOverlapped: POverlapped): BOOL; stdcall;
function WriteConsole(hConsoleOutput: THandle;const lpBuffer: Pointer; nNumberOfCharsToWrite: DWORD;
var lpNumberOfCharsWritten: DWORD; lpReserved: Pointer):BOOL; stdcall;
同样，Delphi把输入映射到WriteFile，而不是WriteConsole。此外，也可以用其它高层次函数来移动光标、改变输出字符的属性。控制台窗口缺省地支持ANSI字符集，而非IBM_ANSI字符控制序列。控制台实际上只是一个字符模式的GUI窗口，所以，可以使用其它Windows API调用来改变颜色、设置光标位置等等。以下是常用的API函数：
function SetConsoleCursorPosition(hConsoleOutput: THandle; dwCursorPosition: TCoord): BOOL; stdcall;
function SetConsoleTextAttribute(hConsoleOutput: THandle;wAttributes: Word): BOOL; stdcall;
function GetConsoleScreenBufferInfo(hConsoleOutput: THandle; var lpConsoleScreenBufferInfo:
TConsoleScreenBufferInfo): BOOL; stdcall;
最后一个函数非常强大。在这里，我们只想用它得到缺省的位置和颜色属性信息，然后保存。
SetConsoleTextAttribute影响所有向控制台写入的字符，包括缺省的字符回放动作和程序向控制台写入的文本。这里所说的字符颜色属性不是典型的Windows RGB颜色，而是IBM-ANSI 16色，由FOREGROUND_BLUE、FOREGROUND_GREEN、 FOREGROUND_RED、 FOREGROUND_INTENSITY、 BACKGROUND_BLUE、 BACKGROUND_GREEN、 BACKGROUND_RED、 and BACKGROUND_INTENSITY组合而成。
用Or操作符组合这八种属性，可以构成十六种基本ANSI颜色，用于前景和背景。（旧DOS程序员请注意，背景的高位设置背景颜色亮度，而非在ANSI.sys中定义的闪烁属性。）三种色组合到一起就是白色，一个都不用就是黑色，等等。
如下代码段展示了如何定位光标和改变颜色。在改变属性和坐标之前，我们保存了一下。在程序执行时，应该保存这些设置，以便恢复它。你的程序可能会关联到一个有父应用程序的控制台，在你的程序完成后，还会继续存在于屏幕上。对控制台所做的改变会继续有效，这可能会导致问题，至少会引起父进程中的配色变动，文字会不易辨识。
- {$APPTYPE CONSOLE}
- program ConsoleOutput;
- uses Windows;
- var
- hOutput: THandle;
- sbiAttributes: TConsoleScreenBufferInfo;
- wDefColors: WORD;
- coorCurrent, coorTopLeft: TCoord;
- const
- FOREGROUND_BRCYAN = FOREGROUND_GREEN or
- FOREGROUND_BLUE or FOREGROUND_INTENSITY;
- begin
- hOutput := GetStdHandle(STD_OUTPUT_HANDLE);
- coorTopLeft.X := 1;
- coorTopLeft.Y := 1;
- { 读缺省颜色 }
- GetConsoleScreenBufferInfo(hOutput, sbiAttributes);
- wDefColors := sbiAttributes.wAttributes;
- coorCurrent := sbiAttributes.dwCursorPosition;
- { 把输出颜色改为亮青色，移动光标到屏幕顶部 }
- Writeln('此测试用文字。');
- SetConsoleTextAttribute(hOutput, FOREGROUND_BRCYAN);
- SetConsoleCursorPosition(hOutput, coorTopLeft);
- { 写入文字 }
- Writeln('此测试用文字。');
- SetConsoleTextAttribute(hOutput, FOREGROUND_GREEN);
- Writeln('如这些文字所示。');
- Writeln('');
- SetConsoleTextAttribute(hOutput, FOREGROUND_red);
- Writeln('按 退出。');
- Readln;
- { 恢复缺省颜色 }
- SetConsoleTextAttribute(hOutput, wDefColors);
- SetConsoleCursorPosition(hOutput, coorCurrent);
- end.
改变控制台文字输出颜色
结语
本文只谈及控制台应用程序的冰山一角。控制台编程允许你把大部分DOS Pascal代码转移到Windows环境，而不用做很多修改。不过，如前面所谈到的，控制台窗口实际上是一个功能完备的用户界面，只不过使用字符来代替像素罢了。
控制台程序还有许多更高级的技术可供利用。在本文的第二部分，将详细讨论创建多个独立的输出窗口，并阐述如何重载控制台缺省行为。比如，取代缺省的[Ctrl][C]句柄处理，改变控制台模式、影响输入和输出函数行为等等。
此外，在后文中还将提及如何利用控制台窗口执行高级任务，包括如何在控制台程序中操作线程，如何在GUI程序中创建控制台，如何在控制台应用程序中创建GUI窗口和消息队列，以及如何重定向控制台应用程序的输入和输出句柄。最后，范例程序将开始模拟真实世界中使用的技术。