Silvaco仿真学习

基础结构：

平栅-LDMOS:【结构】

go atlas
# define mesh
mesh
x.m l=0.0 spac=0.3
x.m l=1.0 spac=0.018
x.m l=2.0 spac=0.018
x.m l=3.0 spac=0.3
y.m l=-0.02 spac=0.01
y.m l=0.0 spac=0.01
y.m l=0.3 spac=0.06
y.m l=1.0 spac=0.2
# define region
region num=1 y.min=0 silicon
region num=2 y.max=0 oxide
# define electrode
elect num=1 name=gate x.min=1.0 length=1 y.min=-0.02 y.max=-0.02
elect num=2 name=source left length=1 y.min=0.0 y.max=0.0
elect num=3 name=drain  right length=1 y.min=0.0 y.max=0.0
elect num=4 name=substrate substrate
# define doping
doping uniform p.type conc=2e16
doping gauss p.type conc=1e17 char=0.1
doping gauss n.type conc=1e20 x.right=1.0 junc=0.2 ratio=0.6
doping gauss n.type conc=1e20 x.left=2.0 junc=0.2 ratio=0.6
#define str
save outfile=nmos.str
tonyplot nmos.str
#define model
models srh cvt print
#define gate charge
contact name=gate n.poly
interface qf=3e10
#calculate Vg-Id
method newton
solve init
solve vgate=-5
log outf=nmos1_1.log
solve vdrain=-5 vstep=0.25 vfinal=0 name=gate
save outf=nmos1_1.str
#calculate output lines
log off
solve vgate=-5 outf=solve_tmp1
solve vgate=0   outf=solve_tmp2

load infile=solve_tmp1
log outf=nmos1_2.log
solve name=drain vdrain=-5 vstep=0.5 vfinal=0

load infile=solve_tmp2
log outf=nmos1_3.log
solve name=drain vdrain=-5 vstep=0.5 vfinal=0



quit

平栅-LDMOS:【工艺】

# (c) Silvaco Inc., 2015
go athena

#
line x loc=0.0 spac=0.1 
line x loc=0.2 spac=0.006
line x loc=0.4 spac=0.006
line x loc=0.6 spac=0.01 
#
line y loc=0.0 spac=0.002 
line y loc=0.2 spac=0.005
line y loc=0.5 spac=0.05
line y loc=0.8 spac=0.15 
#
init orientation=100 c.phos=1e14 space.mul=2

#pwell formation including masking off of the nwell
#
diffus time=30 temp=1000 dryo2 press=1.00 hcl=3
#
etch oxide thick=0.02
#
#P-well Implant
# 
implant boron dose=8e12 energy=100 pears 

#
diffus temp=950 time=100 weto2 hcl=3
#
#N-well implant not shown -
#
# welldrive starts here
diffus time=50 temp=1000 t.rate=4.000 dryo2 press=0.10 hcl=3
#
diffus time=220 temp=1200 nitro press=1
#
diffus time=90 temp=1200 t.rate=-4.444 nitro press=1
#
etch oxide all
#
#sacrificial "cleaning" oxide
diffus time=20 temp=1000 dryo2 press=1 hcl=3
#
etch oxide all
#
#gate oxide grown here:-
diffus time=11 temp=925 dryo2 press=1.00 hcl=3
#
# Extract a design parameter 
extract name="gateox" thickness oxide mat.occno=1 x.val=0.05

#
#vt adjust implant 
implant boron dose=9.5e11 energy=10 pearson 

#
depo poly thick=0.2 divi=10 
#
#from now on the situation is 2-D
#
etch poly left p1.x=0.35
#
method fermi compress
diffuse time=3 temp=900 weto2 press=1.0
#
implant phosphor dose=3.0e13 energy=20 pearson 
#
depo oxide thick=0.120 divisions=8
#
etch oxide dry thick=0.120
#
implant arsenic dose=5.0e15 energy=50 pearson 
#
method fermi compress
diffuse time=1 temp=900 nitro press=1.0
#

# pattern s/d contact metal
etch oxide left p1.x=0.2
deposit alumin thick=0.03 divi=2
etch alumin right p1.x=0.18

# Extract design parameters

# extract final S/D Xj
extract name="nxj" xj silicon mat.occno=1 x.val=0.1 junc.occno=1

# extract the N++ regions sheet resistance
extract name="n++ sheet rho" sheet.res material="Silicon" mat.occno=1 x.val=0.05 region.occno=1

# extract the sheet rho under the spacer, of the LDD region
extract name="ldd sheet rho" sheet.res material="Silicon" \
	mat.occno=1 x.val=0.3 region.occno=1

# extract the surface conc under the channel.
extract name="chan surf conc" surf.conc impurity="Net Doping" \
	material="Silicon" mat.occno=1 x.val=0.45

# extract a curve of conductance versus bias.
extract start material="Polysilicon" mat.occno=1 \
	bias=0.0 bias.step=0.2 bias.stop=2 x.val=0.45
extract done name="sheet cond v bias" \
	curve(bias,1dn.conduct material="Silicon" mat.occno=1  region.occno=1)\
	outfile="extract.dat"

# extract the long chan Vt
extract name="n1dvt" 1dvt ntype vb=0.0 qss=1e10 x.val=0.49


structure mirror right

electrode name=gate x=0.5 y=0.1
electrode name=source x=0.1
electrode name=drain x=1.1
electrode name=substrate backside

structure outfile=plain_nmos.str

# plot the structure
tonyplot  plain_nmos.str 

############# Vt Test : Returns Vt, Beta and Theta ################
go atlas

# set material models
models cvt srh print 

contact name=gate n.poly
interface qf=3e10

method newton
solve init

# Bias the drain 
solve vdrain=0.1 

# Ramp the gate
log outf=plain_nmos.log master
solve vgate=0 vstep=0.25 vfinal=3.0 name=gate
save outf=plain_nmos_VgId.str

# plot results

# extract device parameters
extract name="nvt" (xintercept(maxslope(curve(abs(v."gate"),abs(i."drain")))) \
	- abs(ave(v."drain"))/2.0)
extract name="nbeta" slope(maxslope(curve(abs(v."gate"),abs(i."drain")))) \
	* (1.0/abs(ave(v."drain")))
extract name="ntheta" ((max(abs(v."drain")) * $"nbeta")/max(abs(i."drain"))) \
	- (1.0 / (max(abs(v."gate")) - ($"nvt")))

quit