OpenGL ES 3. 光照-镜面光

大家好，接下来将为大家介绍OpenGL ES 3. 光照-镜面光。

OpenGL ES 3.0 中采用的光照模型相对现实世界进行了很大的简化，将光照分成了 3 种组成元素(也可以称为 3 个通道)，包括环境光、散射光 以及 镜面光。

1、镜面光介绍

        现实世界中，当光滑表面被照射时会有方向很集中的反射光。这就是镜面光(Specular)。

        与散射光最终强度仅依赖于入射光与被照射点法向量的夹角不同，镜面光的最终强度还依赖于观察者的位置。也就是说，如果从摄像机到被照射点的向量不在反射光方向集中的范围内，观察者将不会看到镜面光。如下图所示。

        镜面光的计算模型比前面的两种光都要复杂一些，具体公式如下。

       镜面光照射结果 = 材质的反射系数 * 镜面光强度 * max( 0, ( cos(半向量与法向量的夹角) ^ 粗糙度 )。

 

2、在前述“绘制球体”的基础上，进行镜面光的渲染        

顶点着色器，引入了镜面光specular：

#version 300 es
uniform mat4 uMVPMatrix; 	//总变换矩阵
uniform mat4 uMMatrix; 		//变换矩阵
uniform vec3 uLightLocation;	//光源位置
uniform vec3 uCamera;		//摄像机位置
in vec3 aPosition;  	
in vec3 aNormal;   	    
out vec3 vPosition;		//用于传递给片元着色器的顶点位置
out vec4 vSpecular;		//用于传递给片元着色器的镜面光最终强度
void pointLight(				//定位光光照计算的方法
  in vec3 normal,			//法向量
  inout vec4 specular,		//镜面光最终强度
  in vec3 lightLocation,		//光源位置
  in vec4 lightSpecular		//镜面光强度
){ 
  vec3 normalTarget=aPosition+normal; 	//计算变换后的法向量
  vec3 newNormal=(uMMatrix*vec4(normalTarget,1)).xyz-(uMMatrix*vec4(aPosition,1)).xyz;
  newNormal=normalize(newNormal);  	//对法向量规格化
  //计算从表面点到摄像机的向量
  vec3 eye= normalize(uCamera-(uMMatrix*vec4(aPosition,1)).xyz);  
  //计算从表面点到光源位置的向量vp
  vec3 vp= normalize(lightLocation-(uMMatrix*vec4(aPosition,1)).xyz);  
  vp=normalize(vp);//格式化vp
  vec3 halfVector=normalize(vp+eye);	//求视线与光线的半向量  
  float shininess=50.0;				//粗糙度，越小越光滑    
  float nDotViewHalfVector=dot(newNormal,halfVector);			//法线与半向量的点积 
  float powerFactor=max(0.0,pow(nDotViewHalfVector,shininess)); 	//镜面反射光强度因子
  specular=lightSpecular*powerFactor;    //最终的镜面光强度
}
void main()  {                        		
   gl_Position = uMVPMatrix * vec4(aPosition,1); //根据总变换矩阵计算此次绘制此顶点的位置      
   vec4 specularTemp=vec4(0.0,0.0,0.0,0.0);   
   pointLight(normalize(aNormal), specularTemp, uLightLocation, 
              vec4(0.7,0.7,0.7,1.0));//计算镜面光  
   vSpecular = specularTemp;	//将最终镜面光强度传给片元着色器   
   vPosition = aPosition; 		//将顶点的位置传给片元着色器
} 

#version 300 es
precision mediump float;
uniform float uR;
in vec3 vPosition;//接收从顶点着色器过来的顶点位置
in vec4 vSpecular;//接收从顶点着色器过来的镜面反射光最终强度
out vec4 fragColor;
void main()                         
{
   vec3 color;
   float n = 8.0;//一个坐标分量分的总份数
   float span = 2.0*uR/n;//每一份的长度
   //每一维在立方体内的行列数
   int i = int((vPosition.x + uR)/span);
   int j = int((vPosition.y + uR)/span);
   int k = int((vPosition.z + uR)/span);
   //计算当点应位于白色块还是黑色块中
   int whichColor = int(mod(float(i+j+k),2.0));
   if(whichColor == 1) {//奇数时为红色
   		color = vec3(0.678,0.231,0.129);//红色
   }
   else {//偶数时为白色
   		color = vec3(1.0,1.0,1.0);//白色
   }
   //最终颜色
   vec4 finalColor=vec4(color,0);
	//根据镜面光最终强度计算片元的最终颜色值
   fragColor=finalColor*vSpecular;
}     

 

3、渲染结果示例：

 

从左右两侧运行效果图的对比中可以看出，引入镜面光之后，层次感明显增强了许多。

 

最后，欢迎大家一起交流学习：微信：liaosy666 ； QQ：2209115372 。