iOS底层原理03-- alloc & init & new源码分析

在源码分析前，我们先来看看如下的代码：

    LGPerson *p1 = [LGPerson alloc];
    LGPerson *p2 = [p1 init];
    LGPerson *p3 = [p1 init];
    LGNSLog(@"对象内容：%@ - 内存地址：%p - 指针地址：%p",p1,p1,&p1);
    LGNSLog(@"对象内容：%@ - 内存地址：%p - 指针地址：%p",p2,p2,&p2);
    LGNSLog(@"对象内容：%@ - 内存地址：%p - 指针地址：%p",p3,p3,&p3);

运行输出：

对象内容： - 内存地址：0x6000038b0260 - 指针地址：0x7ffee4ddb058
对象内容： - 内存地址：0x6000038b0260 - 指针地址：0x7ffee4ddb050
对象内容： - 内存地址：0x6000038b0260 - 指针地址：0x7ffee4ddb048

通过上面的运行结果可以得出结论：
3个对象指向同一个内存空间，所以内容和内存地址是相同的，但是对象的指针地址是不同的。

那么我们就要思考了，在初始化过程中，alloc做了什么？init做了什么？

• 下载源码，编译源码，可参考https://www.jianshu.com/p/e74299043f23

alloc源码探索

alloc + init 整体源码的探索流程如下：

• 【第一步】首先根据main函数中的LGPerson类的alloc方法进入alloc方法的源码实现（即源码分析开始）

+ (id)alloc {
    return _objc_rootAlloc(self);
}

• 【第二步】跳转至_objc_rootAlloc的源码实现

id
_objc_rootAlloc(Class cls)
{
    return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}

• 【第三步】跳转至callAlloc的源码实现

static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false)
{
#if __OBJC2__
    if (slowpath(checkNil && !cls)) return nil;
    if (fastpath(!cls->ISA()->hasCustomAWZ())) {
        return _objc_rootAllocWithZone(cls, nil);
    }
#endif

    // No shortcuts available.
    if (allocWithZone) {
        return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
    }
    return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

如上所示，在calloc方法中，当我们无法确定实现走到哪部时，可以通过断点调试，判断执行走哪部分逻辑。这里是执行到_objc_rootAllocWithZone
slowpath & fastpath
其中关于slowpath和fastpath这里需要简要说明下，这两个都是objc源码中定义的宏，其定义如下：

#define fastpath(x) (__builtin_expect(bool(x), 1))
#define slowpath(x) (__builtin_expect(bool(x), 0))

其中的__builtin_expect指令是由gcc引入的，
1、目的：编译器可以对代码进行优化，以减少指令跳转带来的性能下降。即性能优化
2、作用：允许程序员将最有可能执行的分支告诉编译器。
3、指令的写法为：__builtin_expect(EXP, N)。表示 EXP==N的概率很大。
4、fastpath定义中__builtin_expect((x),1)表示 x 的值为真的可能性更大；即 执行if 里面语句的机会更大
5、slowpath定义中的__builtin_expect((x),0)表示 x 的值为假的可能性更大。即执行 else 里面语句的机会更大
6、在日常的开发中，也可以通过设置来优化编译器，达到性能优化的目的，设置的路径为：Build Setting --> Optimization Level --> Debug --> 将None 改为 fastest 或者 smallest

cls->ISA()->hasCustomAWZ()

其中fastpath中的 cls->ISA()->hasCustomAWZ() 表示判断一个类是否有自定义的 +allocWithZone 实现，这里通过断点调试，是没有自定义的实现，所以会执行到 if 里面的代码，即走到_objc_rootAllocWithZone

• 【第四步】跳转至_objc_rootAllocWithZone

id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused)
{
    // allocWithZone under __OBJC2__ ignores the zone parameter
    return _class_createInstanceFromZone(cls, 0, nil,
                                         OBJECT_CONSTRUCT_CALL_BADALLOC);
}

• 【第五步】跳转至_class_createInstanceFromZone的源码实现，这部分是alloc源码的核心操作，由下面的流程图及源码可知，该方法的实现主要分为三部分
  cls->instanceSize：计算需要开辟的内存空间大小
  calloc：申请内存，返回地址指针
  obj->initInstanceIsa：将 类 与 isa 关联

static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
                              int construct_flags = OBJECT_CONSTRUCT_NONE,
                              bool cxxConstruct = true,
                              size_t *outAllocatedSize = nil)
{
    ASSERT(cls->isRealized());

    // Read class's info bits all at once for performance
    bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
    bool hasCxxDtor = cls->hasCxxDtor();
    bool fast = cls->canAllocNonpointer();
    size_t size;

    size = cls->instanceSize(extraBytes);
    if (outAllocatedSize) *outAllocatedSize = size;

    id obj;
    if (zone) {
        obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
    } else {
        obj = (id)calloc(1, size);
    }
    if (slowpath(!obj)) {
        if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
            return _objc_callBadAllocHandler(cls);
        }
        return nil;
    }

    if (!zone && fast) {
        obj->initInstanceIsa(cls, hasCxxDtor);
    } else {
        // Use raw pointer isa on the assumption that they might be
        // doing something weird with the zone or RR.
        obj->initIsa(cls);
    }

    if (fastpath(!hasCxxCtor)) {
        return obj;
    }

    construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
    return object_cxxConstructFromClass(obj, cls, construct_flags);
}

根据源码分析，得出其实现流程如下所示：

cls->instanceSize：计算需要开辟的内存空间大小

size_t instanceSize(size_t extraBytes) const {
        if (fastpath(cache.hasFastInstanceSize(extraBytes))) {
            return cache.fastInstanceSize(extraBytes);
        }

        size_t size = alignedInstanceSize() + extraBytes;
        // CF requires all objects be at least 16 bytes.
        if (size < 16) size = 16;
        return size;
    }

align16源码：

static inline size_t align16(size_t x) {
    return (x + size_t(15)) & ~size_t(15);
}

流程如下

calloc：申请内存，返回地址指针

通过instanceSize计算的内存大小，向内存中申请大小为size的内存，并赋值给obj，因此obj是指向内存地址的指针

obj = (id)calloc(1, size);

这里我们可以通过断点来印证上述的说法，在未执行calloc时，po obj为nil，执行后，再po obj法线，返回了一个16进制的地址

在平常的开发中，一般一个对象的打印的格式都是类似于这样的（是一个指针）。为什么这里不是呢？

• 主要是因为objc 地址 还没有与传入 的 cls进行关联，
• 同时印证了 alloc的根本作用就是 开辟内存

obj->initInstanceIsa：类与isa关联

经过calloc可知，内存已经申请好了，类也已经传入进来了，接下来就需要将 类与 地址指针 即isa指针进行关联，其关联的流程图如下所示

主要过程就是初始化一个isa指针，并将isa指针指向申请的内存地址，在将指针与cls类进行关联

同样也可以通过断点调试来印证上面的说法，在执行完initInstanceIsa后，在通过po obj可以得出一个对象指针

总结:

• 通过对alloc源码的分析，可以得知alloc的主要目的就是开辟内存，而且开辟的内存需要使用16字节对齐算法，现在开辟的内存的大小基本上都是16的整数倍
• 开辟内存的核心步骤有3步：计算 -- 申请 -- 关联

init源码探索

类方法 init：

+ (id)init {
    return (id)self;
}

这里的init是一个构造方法 ，是通过工厂设计（工厂方法模式）,主要是用于给用户提供构造方法入口。这里能使用id强转的原因，主要还是因为内存字节对齐后，可以使用类型强转为你所需的类型

实例方法 init：

通过以下代码进行探索实例方法 init

LGPerson *objc = [[LGPerson alloc] init];

通过main中的init跳转至init的源码实现:

- (id)init {
    return _objc_rootInit(self);
}
--------------
id
_objc_rootInit(id obj)
{
    // In practice, it will be hard to rely on this function.
    // Many classes do not properly chain -init calls.
    return obj;
}

有上述代码可以证明，返回的是传入的self本身。

new源码探索

一般在开发中，初始化除了init，还可以使用new，两者本质上并没有什么区别，以下是objc中new的源码实现，通过源码可以得知，new函数中直接调用了callAlloc函数（即alloc中分析的函数），且调用了init函数，所以可以得出new 其实就等价于 [alloc init]的结论

+ (id)new {
    return [callAlloc(self, false/*checkNil*/) init];
}