AutoLisp入门基础教程(2)

这是AutoLisp入门基础教程的第二部分。在教程的第一部分，我们掌握了如何在AutoCAD中加载一个AutoLisp程序，了解了如何使用defun来定义一个函数。在下面的内容中，我将结合一个实际工作中的简单需求并编写一个程序，以此来展示编程的思路，并重点讲述常用的AutoLisp函数。

工作中有什么需求

在海工结构中，一些房间的墙壁经常是由瓦楞板组成的。瓦楞板就是像瓦楞纸一样的钢板，如下图所示。

瓦楞板就是这样子的钢板

在设计制图阶段，我们常常用一个曲折的多段线来表示这个瓦楞板，如下图所示。图中的几个长度参数（x，y和h）决定了瓦楞板的形状。一般的，为了画一段长度的瓦楞板，需要确定该多段线的数十个的控制点。所以，若采用手工方法一个一个地确定控制点地位置来完成一个多段线，那么工作量是无比巨大的。正常人肯定不会这么干！在接触AutoLisp之前，我也不知道瓦楞板是怎么画的，但是又不得不画（不画就要被领导骂了），所以我就从别人的图纸中复制一个长长的瓦楞板多段线，然后裁剪成合适的大小。

瓦楞板示意图

复制别人图纸中的东西确实是一个不错的主意，但是如果瓦楞板的形状尺寸改变了，就有可能无图可抄了。我曾经思考过很久如何快速地画这样一个瓦楞板，有同事说可以设置自定义线型（但是他竟然忘了如何设置了）。接下来，我们尝试用AutoLisp编程来解决这个问题。

程序的构思

为了方便起见，先将瓦楞板的尺寸固定。程序的预期目标是，在输入瓦楞板中轴线的起点（ps）和瓦楞板中轴线的终点（pe）后自动画出一定长度的瓦楞板（即多段线）。从下图可以看出，瓦楞板是一个循环的线段，一个循环单元由四个控制点组成（如图中的 pa pb pc pd）。如何通过已知点（ps和pe）来确定这四个控制点的位置，是解决问题的关键。幸好，Autolisp语言提供了一些非常有用的函数，如下：

(polar pt angle distance)
; 此函数将返回在pt点的某个方向(angle)上距离长度为distance的点
; angle 是从 x 轴开始的角度，以逆时针方为正
(angle p1 p2)
; 返回从p1到p2的射线与x轴正方向的夹角，单位是弧度
(distance p1 p2)
；返回p1与p2之间的距离

例如，pa在ps的(alpha+pi/2)角度上，距离为h/2；pb在pa的alpha角度上，距离为x；p_temp在pb的(alpha-pi/2)角度上，距离为h；pc在p_temp的alpha角度上，距离为y；pd在pc的alpha角度上，距离为x。这四个关键点就全部确定了（p_temp是为了表示方便而构造的变量）。使用polar函数，把已上的陈述翻译为AutoLisp语言，如下：

(setq 
    pa (polar ps (+ alpha (/ pi 2)) (/ h 2))
    pb (polar pa alpha x)
    p_temp (polar pb (- alpha (/ pi 2)) h)
    pc (polar p_temp alpha y)
    pd (polar pc alpha x)
)

程序中变量示意图

如何AutoLisp中实现循环呢？方法之一是使用repeat函数

(repeat n exp...)
; n为正整数，为循环的次数。exp...为循环执行的表达式。

最终的程序

最后的程序，程序中的一些细节没有讲到。先写这么多吧。

(defun c:wlb ()
    
    ;定义瓦楞板的尺寸
    (setq x 255 y 66 h 66)
    (while
        (and 
            (setq ps (getpoint "\n请输瓦楞板的起点："))
            (setq pe (getpoint "\n请输瓦楞板的终点："))
        )

        (setq 
            alpha (angle ps pe)
            dstc (distance ps pe)
            dstc_e (+ x y x y)
        )
        (setq nn (1+ (fix (/ dstc dstc_e))))
        (setq pa (polar ps (+ alpha (/ pi 2)) (/ h 2)))
        (setq oldsnap (getvar "osmode"))
        (setvar "osmode" 0)
        (command "pline")
        (repeat nn
            (setq 
                pb (polar pa alpha x)
                p_temp (polar pb (- alpha (/ pi 2)) h)
                pc (polar p_temp alpha y)
                pd (polar pc alpha x)
            )
            (command pa pb pc pd)
            (setq pa (polar pa alpha dstc_e))
        )
        (command "")
        (setvar "osmode" oldsnap)
        (prin1)
    )
)

以后接着写吧。