桥梁结构的ANSYS参数化分析
桥梁是现代建筑中最重要的结构形式之一，它对一个区域的政治、经济、文化有着重要的影响，现代桥梁正向着长距离、大跨度方向发展；目前的大跨度桥梁主要有斜拉桥以及悬索桥两种形式；例如，法国于1995年建成的Normandie大桥就是大跨度斜拉桥，有184根拉索，主跨长度达到864m，桥面高度为51m，使用了1万9千吨钢材，7万立方米的混凝土。
现代桥梁设计的一个重要特点就是需要采用精确的有限元方法对桥梁的静力、振动、风载、地震、四季温差等状况进行分析，并提出优化方案，并且还要就桥梁施工过程中因结构变化的各种受力状态进行细致的分析，从而确定出可行的施工方案，可以毫不夸张地说，有限元分析在现代结构的设计和分析中正发挥着不可替代的作用。
下面以一个简单桁架桥梁为例，以展示有限元分析的全过程；背景素材选自位于密执安的"Old North Park Bridge" (1904-1988)，见图(1)；该桁架桥由型钢组成，顶梁及侧梁，桥身弦杆，底梁分别采用三种不同型号的型钢，结构参数见表(1)。桥长L=32m,桥高H=5.5m。桥身由8段桁架组成，每段长4m。该桥梁可以通行卡车，若这里仅考虑卡车位于桥梁中间位置，假设卡车的质量为4000kg，若取一半的模型，可以将卡车对桥梁的作用力简化为P1 ，P2 ，P3 ，其中P1= P3=5000 N, P2=10000N，见图(2)。
下面，在Ansys平台上，以命令流的方式进行求解。
//命令流文件：HengJiaQiao.mac
!Ansys算例，桁架桥梁
!注意，命令流中的符号$，可将多行命令流写成一行
/PREP7 !进入前处理
/PLOPTS,DATE,0 !设置不显示日期和时间
!=== 设置单元和材料
ET,1,BEAM3 !定义单元类型
R,1,2.19e-3,3.83e-6,,,,, !定义1号实常数用于顶梁侧梁
R,2,1.18e-3,1.87e-6,0,0,0,0 !定义2号实常数用于弦杆
R,3,3.03e-3,8.47e-6,0,0,0,0 !定义3号实常数用于底梁
MP,EX,1,2.1e11 !定义材料弹性模量
MP,PRXY,1,0.30 !定义材料泊松比
MP,DENS,1,,7800 !定义材料密度
!---定义几何关键点
K,1,0,0,, $K,2,4,0,, $K,3,8,0,, $K,4,12,0,, $K,5,16,0,, $K,6,20,0,, $K,7,24,0,, $K,8,28,0,, $K,9,32,0,, $K,10,4,5.5,,
$K,11,8,5.5,, $K,12,12,5.5,, $K,13,16,5.5,, $K,14,20,5.5,,, $K,15,24,5.5,, $K,16,28,5.5,,
!---通过几何点生成桥底梁的线
L,1,2 $L,2,3 $L,3,4 $L,4,5 $L,5,6 $L,6,7 $L,7,8 $L,8,9
!---生成桥顶梁和侧梁的线
L,9,16 $L,15,16 $L,14,15 $L,13,14 $L,12,13 $L,11,12 $L,10,11 $L,1,10
!---生成桥身弦杆的线
L,2,10 $L,3,10 $L,3,11 $L,4,11 $L,4,12 $L,4,13 $L,5,13 $L,6,13 $L,6,14 $L,6,15 $L,7,15 $L,7,16 $L,8,16
!---选择桥顶梁和侧梁指定单元属性
LSEL,S,,,9,16,1,
LATT,1,1,1,,,,
!---选择桥身弦杆指定单元属性
LSEL,S,,,17,16,1,
LATT,1,2,1,,,,
!---选择桥底梁指定单元属性
LSEL,S,,,1,8,1,
LATT,1,3,1,,,,
!---划分网格
ALLSEL,ALL !再恢复选择所有对象
LESIZE,ALL,,,1,,,,,1 !对所有对象进行单元划分前的分段设置
LMESH,ALL !对所有几何线进行单元划分
!=== 在求解模块中，施加位移约束、外力，进行求解
/SOLU
NSEL,S,LOC,X,0 !根据几何位置选择节点
D,ALL,,,,,,ALL,,,,, !对所选择的节点施加位移约束
ALLSEL,ALL !再恢复选择所有对象
NSEL,S,LOC,X,32 !根据几何位置选择节点
D,ALL,,,,,,,UY,,,, !对所有节点在y方向上，施加位移约束
ALLSEL,ALL !再恢复选择所有对象
!---基于几何关键点施加载荷
FK,4,FY,-5000 $FK,6,FY,-5000 $FK,5,FY,-10000
/REPLOT !重画图形
ALLSEL,ALL !选择所有信息(包括所有节点，单元，载荷等)
SOLVE !求解
!=== 进入一般的或处理模块
/POST1 !后处理
PLNSOL,U,Y,0,1.0 !显示Y方向位移
PLNSOL,U,X,0,1.0 !显示X方向位移
!---显示单元轴力
ETABLE,bar_I,SMISC,1
ETABLE,bar_J,SMISC,1
PLLS,BAR_I,BAR_J,0.5,1 !画出轴力图
FINISH !结束
!%%%%
结构显示：
1、显示Y方向的位移UY
Ansys Main Menu: General Postproc --> Plot Results --> Deformed shape --> Def shape only --> OK(返回到Plot Results ) --> Contour Plot --> Nodal Solu --> DOF Solution ,Y-Component of Displacement --> OK，如图(3)所示：
2、画出线性单元的受力图
2.1)定义线性单元I节点的轴力
Ansys Main Menu: General Postproc --> Element Talbe --> Add --> Lab: [bar_I], By sequence num: [SMISC,1] --> OK --> Close
2.2)定义线性单元J节点的轴力
Ansys Main Menu: General Postproc --> Element Talbe --> Add --> Lab: [bar_J], By sequence num: [SMISC,1] --> OK --> Close
2.3)画出线性单元的受力图
Ansys Main Menu: General Postproc --> Plot Results --> Contour Plot --> Line Elem Res --> LabI: [bar_I] , LabJ: [bar_J], Fact:[1] --> OK，如图（4）设置：
其实，步骤2.1）、2.2）可以省略，因为命令流HengJiaQiao.mac有GUI操作对应的等价的命令，只需要GUI操作步骤2.3）即可。