Unity Shader:基础光照

本文同时发布在我的个人博客上：https://dragon_boy.gitee.io

标准光照模型

进入到摄像机内的光线分为四部分：

• 自发光，用表示。用于描述当给定一个方向时，一个表面本身会向该方向发射多少辐射量。如果不使用全局光照技术，自发光并不会照亮周围的物体，只是本身看上去更亮而已。

• 高光反射，用表示。用于描述当光线从光源照射到模型表面时，该表面会在完全镜面反射方向散射多少辐射量。

• 漫反射，用表示。用于描述当光线从光源照射到模型表面，该表面会向各个方向散射多少辐射量。

• 环境光，用表示。用于描述其它所有的间接光照。

环境光

在标准光照模型中，往往使用一个全局变量来表示环境光照，即场景中所有的物体都使用全局光照：

自发光

这里不考虑全局光照，直接使用材质的自发光颜色来代表自发光光照：

漫反射

漫反射光照符合兰伯特定律：反射光线的强度与表面法线和光源方向之间的夹角的余弦值成正比。漫反射部分计算如下：

时表面法线， 是指向光源的单位矢量，是材质的漫反射颜色，是光源颜色。我们要防止法线和光源方向的夹角不大于90度，以免位于物体后面的光源也能照亮物体。

高光反射

针对高光反射有两种模型，一是Phong模型，而是Blinn-Phong模型。

计算高光反射我们需要表面法线，视角方向，光源方向，反射方向等。

由上面的信息，Phong模型的高光反射部分如下：

其中是材质的光泽度，可以用来控制高光区域的亮点由多宽，越大，亮点越小。是材质的高光反射颜色，是光源颜色。同样也要保证的结果不为负数。

与Phong模型相比，Blinn-Phong模型不使用反射方向，而是引入一个中间矢量:

然后计算和之间的夹角，而非和之间的夹角。公式如下：

逐顶点和逐像素

在片元着色器中计算的光照称为逐像素光照，在顶点着色器中计算的光照称为逐顶点光照。

在逐像素光照中，我们以每个像素为基础得到法线（对顶点法线插值或从法线贴图采样），然后进行光照模型的计算。

在逐顶点光照中，我们在每个顶点上计算光照，然后在渲染图元内部进行线性插值，最后输出成像素颜色。但逐顶点光照对高光的显示会不正确（因为高光反射为非线性的计算）。顶点数一定小于像素数，所以逐顶点光照会快于逐像素光照。

Unity中的环境光和自发光

环境光的颜色在Lighting面板中控制即可，在Shader编写时，可以使用内置变量UNITY_LIGHTMODEL_AMBIENT来获取环境光的颜色和强度信息(rgba)。

对于自发光，将自定义的自发光颜色添加到最终输出颜色即可。

Unity中实现漫反射光照模型

逐顶点光照

Shader代码：

Shader "Unlit/DiffuseVertex"
{
    Properties
    {
        _Diffuse("Diffuse", Color) = (1, 1, 1, 1)
    }
    SubShader
    {
        Pass {
            Tags {"LightMode" = "ForwardBase"}

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"
            fixed4 _Diffuse;
            
            struct a2v {

                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f {
                float4 pos : SV_POSITION;
                fixed3 color : COLOR;
            };

            v2f vert(a2v v) {
                v2f o;
                // 顶点坐标空间变化
                o.pos = UnityObjectToClipPos(v.vertex);

                // ambient
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                //  法线空间变换
                fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));

                // 灯光方向
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                // 计算漫反射
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));

                o.color = ambient + diffuse;

                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET{
                return fixed4(i.color, 1.0);
            }

            ENDCG
        }
    }

    Fallback "Diffuse"
}

ForwardBase标签代表使用前置渲染。

将法线从模型空间转换到世界空间的变换矩阵在之前讲过，使用逆变换矩阵的转置。这里右乘逆矩阵，相当于左乘逆矩阵的转置。

saturate函数将结果截取在[0,1]内。

效果如下：

逐像素光照

Shader代码：

Shader "Unlit/DiffuseFragment"
{
    Properties
    {
        _Diffuse("Diffuse", Color) = (1, 1, 1, 1)
    }
        SubShader
    {
        Pass {
            Tags {"LightMode" = "ForwardBase"}

            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"
            fixed4 _Diffuse;

            struct a2v {

                float4 vertex : POSITION;
                float3 normal : NORMAL;
            };

            struct v2f {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
            };

            v2f vert(a2v v) {
                v2f o;
                // 顶点坐标空间变化
                o.pos = UnityObjectToClipPos(v.vertex);

                //  法线空间变换
                o.worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));

                return o;
            }

            fixed4 frag(v2f i) : SV_TARGET{
                // ambient
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                // 获取法线
                fixed3 worldNormal = normalize(i.worldNormal);

                // 灯光方向
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                // 计算漫反射
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));

                fixed3 color = ambient + diffuse;

                return fixed4(color, 1.0);
            }

            ENDCG
        }
    }

        Fallback "Diffuse"
}

效果如下：

可以看到背面的物体较黑，失去了一些细节，V社提出了半兰伯特模型来改善这一现象。

半兰伯特模型

半兰伯特模型漫反射光照模型如下：

绝大多数情况下，和均为0.5，这样的话，位于[-1,1]范围的被映射到[0,1]，这样的话，模型的背光面的值不会被直接截断掉，而是被映射到0附近，所以背光处也有明暗变化。

将逐像素光照的片元着色器函数进行修改：

          fixed4 frag(v2f i) : SV_TARGET{
                // ambient
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                // 获取法线
                fixed3 worldNormal = normalize(i.worldNormal);

                // 灯光方向
                fixed3 worldLight = normalize(_WorldSpaceLightPos0.xyz);

                // 计算漫反射
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * (0.5 * dot(worldNormal, worldLight) + 0.5);
                //fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, worldLight));

                fixed3 color = ambient + diffuse;

                return fixed4(color, 1.0);
            }

效果如下：

Unity中实现高光反射模型

逐顶点光照

Shader代码如下：

Shader "Unlit/SpecularVertex"
{
    Properties
    {
       _Diffuse ("Diffuse", Color) = (1,1,1,1)
       _Specular ("Specular", Color) = (1,1,1,1)
       _Gloss ("Gloss", Range(8.0,256)) = 20
    }
    SubShader
    {
        Tags { "LightMode" = "ForwardBase" }
       
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed3 color : COLOR;
            };

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            v2f vert (appdata v)
            {
                v2f o;
                
                // 将顶点坐标转化到切割空间
                o.pos = UnityObjectToClipPos(v.vertex);

                // ambient
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                // 将顶点法线转化到世界空间
                fixed3 worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));

                // 获取光源方向
                fixed3 lightDir = normalize(_WorldSpaceLightPos0.xyz);

                // diffuse
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, lightDir));

                // 获取反射光线方向
                fixed3 reflectLightDir = normalize(reflect(-lightDir, worldNormal));

                // 观察方向
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - mul(unity_ObjectToWorld, v.vertex).xyz);

                // specular
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectLightDir, viewDir)), _Gloss);

                o.color = ambient + diffuse + specular;

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                fixed4 color = fixed4(i.color, 1.0);
                return color;
            }
            ENDCG
        }
    }
        Fallback "Specular"
}

反射光线方向用内置的reflect(i,n)函数来获取，i为入射方向(要求指向入射点)，n为法线方向。

效果如下：

逐像素光照

Shader代码如下：

Shader "Unlit/SpecularFragment"
{
    Properties
    {
       _Diffuse("Diffuse", Color) = (1,1,1,1)
       _Specular("Specular", Color) = (1,1,1,1)
       _Gloss("Gloss", Range(8.0,256)) = 20
    }
        SubShader
    {
        Tags { "LightMode" = "ForwardBase" }

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 normal : NORMAL;
            };

            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
            };

            fixed4 _Diffuse;
            fixed4 _Specular;
            float _Gloss;

            v2f vert(appdata v)
            {
                v2f o;

                // 将顶点坐标转化到切割空间
                o.pos = UnityObjectToClipPos(v.vertex);

                // 将顶点法线转化到世界空间
                o.worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));

                // 获取顶点世界空间位置
                o.worldPos = mul(unity_ObjectToWorld, v.vertex.xyz);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
                // ambient
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                //法线
                fixed3 worldNormal = normalize(i.worldNormal);
            
                // 获取光源方向
                fixed3 lightDir = normalize(_WorldSpaceLightPos0.xyz);

                // diffuse
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, lightDir));

                //// 获取反射光线方向
                fixed3 reflectLightDir = normalize(reflect(-lightDir, worldNormal));

                // 观察方向
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);

                // 中间向量
                //fixed3 halfDir = normalize(lightDir + viewDir);

                // specular
                //fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal, halfDir)), _Gloss);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectLightDir , viewDir)), _Gloss);

                fixed3 color = ambient + diffuse + specular;

                return fixed4(color, 1.0);
            }
            ENDCG
        }
    }
        Fallback "Specular"
}

Blinn-Phong

将上述逐像素光照的片元着色器修改：

            fixed4 frag(v2f i) : SV_Target
            {
                // ambient
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                //法线
                fixed3 worldNormal = normalize(i.worldNormal);
            
                // 获取光源方向
                fixed3 lightDir = normalize(_WorldSpaceLightPos0.xyz);

                // diffuse
                fixed3 diffuse = _LightColor0.rgb * _Diffuse.rgb * saturate(dot(worldNormal, lightDir));

                //// 获取反射光线方向
                //fixed3 reflectLightDir = normalize(reflect(-lightDir, worldNormal));

                // 观察方向
                fixed3 viewDir = normalize(_WorldSpaceCameraPos.xyz - i.worldPos.xyz);

                // 中间向量
                fixed3 halfDir = normalize(lightDir + viewDir);

                // specular
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(worldNormal, halfDir)), _Gloss);
                //fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(reflectLightDir , viewDir)), _Gloss);

                fixed3 color = ambient + diffuse + specular;

                return fixed4(color, 1.0);
            }

效果如下：

Unity内置函数

在大多数情况下，并不需要我们手动计算光源方向，视角方向等，使用内置函数即可：
https://docs.unity3d.com/Manual/SL-BuiltinFunctions.html