synchronized的用法
在平常的编码过程中，使用synchronized一般有三种方法：
1、同步实例方法
2、同步静态方法
3、同步代码块
public class SynchronizedCode {
/**
* 同步方法块，锁实例对象
*/
public synchronized void synchronizedMethod() {}
/**
* 同步静态方法，锁类的class对象
*/
public synchronized static void synchronizedStaticMethod() {}
public final Object object = new Object();
public void synchronizedBlock() {
// 锁住class对象
synchronized (SynchronizedCode.class) {
// 锁住实例对象
synchronized (this) {
// 锁住object对象
synchronized (object) {
// TODO : something
}
}
}
}
}
通过javac编译出SynchronizedCode.class，使用javap -v SynchronizedCode.class查看内容：
Last modified 2020-7-7; size 694 bytes
MD5 checksum 500df057026d5b19a6994e0c822e6904
Compiled from "SynchronizedCode.java"
public class cn.com.rabi.kotlinkey.SynchronizedCode
// 主版本号52，次版本号0
minor version: 0
major version: 52
flags: ACC_PUBLIC, ACC_SUPER
// 常量池，主要存放两大类常量：
// 1、字面量（比较接近与java语言层面的常量）
// 2、符号引用（a.类和接口的全限定名，b.字段的名称和方法，c.方法的名称和描述符）
Constant pool:
// Methodref：类中方法的符号引用
// #2 Class：类或者接口的符号引用，指向#21 Utf8 "java/lang/Object" 字符串
// #20 NameAndType字段或方法的部分符号引用
// 指向#7#8，两个Utf8字符串""初始化 ，"()V"特殊类型void，表示无返回
#1 = Methodref #2.#20 // java/lang/Object."":()V
#2 = Class #21 // java/lang/Object
// Fieldref：字段的符号引用
// #4 "cn/com/rabi/kotlinkey/SynchronizedCode"字段对应的类引用
// #22 指向 #5#6，object:Ljava/lang/Object ，L表示对象类型
#3 = Fieldref #4.#22 // cn/com/rabi/kotlinkey/SynchronizedCode.object:Ljava/lang/Object;
#4 = Class #23 // cn/com/rabi/kotlinkey/SynchronizedCode
#5 = Utf8 object
#6 = Utf8 Ljava/lang/Object;
#7 = Utf8
#8 = Utf8 ()V
// Code 字段
#9 = Utf8 Code
// 行号表（直译）
#10 = Utf8 LineNumberTable
// synchronizedMethod方法
#11 = Utf8 synchronizedMethod
// synchronizedStaticMethod方法
#12 = Utf8 synchronizedStaticMethod
// synchronizedBlock方法
#13 = Utf8 synchronizedBlock
// 堆栈映射表（直译）
#14 = Utf8 StackMapTable
// 字段"cn/com/rabi/kotlinkey/SynchronizedCode"的类
#15 = Class #23 // cn/com/rabi/kotlinkey/SynchronizedCode
// 字段"java/lang/Object"的类
#16 = Class #21 // java/lang/Object
// 字段"java/lang/Throwable"的类
#17 = Class #24 // java/lang/Throwable
// 源码字段，在末尾表示"SynchronizedCode.java"
#18 = Utf8 SourceFile
#19 = Utf8 SynchronizedCode.java
#20 = NameAndType #7:#8 // "":()V
#21 = Utf8 java/lang/Object
#22 = NameAndType #5:#6 // object:Ljava/lang/Object;
#23 = Utf8 cn/com/rabi/kotlinkey/SynchronizedCode
#24 = Utf8 java/lang/Throwable
{
// 定义的Object对象，字段表（field_info）为ACC_PUBLIC（是否为public）， ACC_FINAL（是否final）
public final java.lang.Object object;
descriptor: Ljava/lang/Object;
flags: ACC_PUBLIC, ACC_FINAL
// SynchronizedCode默认的构造方法
public cn.com.rabi.kotlinkey.SynchronizedCode();
// void方法
descriptor: ()V
// public方法
flags: ACC_PUBLIC
Code:
stack=3, locals=1, args_size=1
// 从局部变量0中装载引用类型值入栈
0: aload_0
// invokespecial指令用于调用一些需要特殊处理的实例方法，包括实例初始化方法、私有方法和父类方法
// 这里是父类初始化
1: invokespecial #1 // Method java/lang/Object."":()V
4: aload_0
5: new #2 // class java/lang/Object
8: dup
// 这里是自己初始化？
9: invokespecial #1 // Method java/lang/Object."":()V
// 给对象字段赋值，这里是#3 "cn/com/rabi/kotlinkey/SynchronizedCode.object:Ljava/lang/Object"
12: putfield #3 // Field object:Ljava/lang/Object;
15: return
LineNumberTable:
line 9: 0
line 20: 4
// synchronizedMethod方法
public synchronized void synchronizedMethod();
descriptor: ()V
// 较synchronizedBlock方法，在方法表（method_info）中多出一个ACC_SYNCHRONIZED，代表synchronized修饰
flags: ACC_PUBLIC, ACC_SYNCHRONIZED
Code:
stack=0, locals=1, args_size=1
0: return
LineNumberTable:
line 13: 0
public static synchronized void synchronizedStaticMethod();
descriptor: ()V
// 较synchronizedMethod多出一个ACC_STATIC，静态方法
flags: ACC_PUBLIC, ACC_STATIC, ACC_SYNCHRONIZED
Code:
stack=0, locals=0, args_size=0
0: return
LineNumberTable:
line 18: 0
public void synchronizedBlock();
descriptor: ()V
flags: ACC_PUBLIC
Code:
stack=2, locals=7, args_size=1
// 常量池中的常量值（int, float, string reference, object reference）入栈
0: ldc #4 // class cn/com/rabi/kotlinkey/SynchronizedCode
// 复制栈顶一个字长的数据，将复制后的数据压栈
2: dup
// 将栈顶引用类型值保存到局部变量1中
3: astore_1
// 进入并获得对象监视器(1)
4: monitorenter
// 从局部变量0中装载引用类型值入栈
5: aload_0
// 复制栈顶一个字长的数据，将复制后的数据压栈
6: dup
// 将栈顶引用类型值保存到局部变量2中
7: astore_2
// 进入并获得对象监视器(2)
8: monitorenter
// 从局部变量0中装载引用类型值入栈
9: aload_0
// 获取对象字段的值，"object:Ljava/lang/Object"对象
10: getfield #3 // Field object:Ljava/lang/Object;
// 复制栈顶一个字长的数据，将复制后的数据压栈
13: dup
// 将栈顶引用类型值保存到局部变量3中
14: astore_3
// 进入并获得对象监视器(3)
15: monitorenter
// 从局部变量3中装载引用类型值入栈
16: aload_3
// 释放并退出对象监视器(3)
17: monitorexit
18: goto 28
// 将栈顶引用类型值保存到局部变量indexbyte中
21: astore 4
23: aload_3
24: monitorexit
// 从局部变量indexbyte中装载引用类型值入栈
25: aload 4
// 抛出异常
27: athrow
28: aload_2
// 释放并退出对象监视器(2)
29: monitorexit
30: goto 40
33: astore 5
35: aload_2
36: monitorexit
37: aload 5
39: athrow
40: aload_1
// 释放并退出对象监视器(1)
41: monitorexit
42: goto 52
45: astore 6
47: aload_1
48: monitorexit
49: aload 6
51: athrow
52: return
Exception table:
from to target type
16 18 21 any
21 25 21 any
9 30 33 any
33 37 33 any
5 42 45 any
45 49 45 any
LineNumberTable:
line 24: 0
line 26: 5
line 28: 9
line 30: 16
line 31: 28
line 32: 40
line 33: 52
StackMapTable: number_of_entries = 6
frame_type = 255 /* full_frame */
offset_delta = 21
locals = [ class cn/com/rabi/kotlinkey/SynchronizedCode, class java/lang/Object, class java/lang/Object, class java/lang/Object ]
stack = [ class java/lang/Throwable ]
frame_type = 250 /* chop */
offset_delta = 6
frame_type = 68 /* same_locals_1_stack_item */
stack = [ class java/lang/Throwable ]
frame_type = 250 /* chop */
offset_delta = 6
frame_type = 68 /* same_locals_1_stack_item */
stack = [ class java/lang/Throwable ]
frame_type = 250 /* chop */
offset_delta = 6
}
SourceFile: "SynchronizedCode.java"
上面部分添加了很多注释，有兴趣的同学可以耐心看过去。
synchronized修饰方法：同步方法不是通过monitorenter/monitorexit来控制的，它的实现在方法调用和返回操作中。调用指令会检查方法ACC_SYNCHRONIZED访问标志是否被设置，若设置了则执行线程需要持有管程(Monitor)才能运行方法，当方法完成(无论是否出现异常)时释放管程。
synchronized修饰代码块：synchronized在编译后会在同步块前后分别形成monitorenter和monitorexit两个字节码指令，每条monitorenter都必须执行其对应的monitorexit指令。为了保证方法异常完成时这两条指令依然能正确执行，编译器会自动产生一个异常处理器，其目的就是用来执行monitorexit指令(代码中21-27、33-39，45-51为异常流程)。
从上面可以看到，无论是那一种方法，本质都是对一个对象监视器(monitor)进行获取。
synchronized实现的锁是存储在Java对象头，在 JVM 中，对象在内存中分为这么三块区域：
1、对象头(Header)：由markOop或称为Mark Word和类元信息组成。
类元信息：对象指向它的类元数据的指针，虚拟机通过这个指针来确定这个对象是哪个类的实例。
Mark Word：默认存储对象的HashCode，分代年龄和锁标志位信息。它会根据对象的状态复用自己的存储空间，也就是说在运行期间Mark Word里存储的数据会随着锁标志位的变化而变化。源码如下：
class markOopDesc: public oopDesc {
private:
// Conversion
uintptr_t value() const { return (uintptr_t) this; }
public:
// Constants
enum {
age_bits = 4, //分代年龄
lock_bits = 2, //锁标识
biased_lock_bits = 1, //是否为偏向锁
max_hash_bits = BitsPerWord - age_bits - lock_bits - biased_lock_bits,
hash_bits = max_hash_bits > 31 ? 31 : max_hash_bits, //对象的hashcode
cms_bits = LP64_ONLY(1) NOT_LP64(0),
epoch_bits = 2 //偏向锁的时间戳
};
2、实例数据：这部分主要是存放类的数据信息，父类的信息
3、对齐填充
更深层次的源码分析，请参考文末的链接。（...没找到源码位置（￣□￣｜｜））
线程安全
当多个线程同时访问一个对象时，如果不用考虑这些线程在运行时环境下的调度和交替执行，也不需要进行额外的同步，或者在调用方进行任何其他的协调操作，调用这个对象的行为都可以获得正确的结果，那就称这个对象是线程安全的。
为了更深入地理解线程安全， 在这里我们可以不把线程安全当作一个非真即假的二元排他选项来
看待， 而是按照线程安全的“安全程度”由强至弱来排序， 我们可以将Java语言中各种操作共享的数据分为以下五类：
1、 不可变
2、 绝对线程安全
3、 相对线程安全
4、 线程兼容
5、 线程对立。
线程安全的实现方法
1、互斥同步：
是一种最常见也是最主要的并发正确性保障手段。同步是指在多个线程并发访问共享数据时，保证共享数据在同一个时刻只被一条（或者是一些，当使用信号量的时候）线程使用。
互斥是实现同步的一种手段，临界区（CriticalSection）、互斥量（Mutex）和信号量（Semaphore）都是常见的互斥实现方式。
在Java里面，最基本的互斥同步手段就是synchronized关键字，它是一种块结构（BlockStructured）的同步语法。synchronized关键字经过Javac编译之后，会在同步块的前后分别形成monitorenter和monitorexit这两个字节码指令。这两个字节码指令都需要一个reference类型的参数来指明要锁定和解锁的对象。如果Java源码中的synchronized明确指定了对象参数，那就以这个对象的引用作为reference；如果没有明确指定，那将根据synchronized修饰的方法类型（如实例方法或类方法），来决定是取代码所在的对象实例还是取类型对应的Class对象来作为线程要持有的锁。
在执行monitorenter指令时，首先要去尝试获取对象的锁。如果这个对象没被锁定，或者当前线程已经持有了那个对象的锁，就把锁的计数器的值增加一，而在执行monitorexit指令时会将锁计数器的值减一。一旦计数器的值为零，锁随即就被释放了。如果获取对象锁失败，那当前线程就应当被阻塞等待，直到请求锁定的对象被持有它的线程释放为止。
下面是两个关于synchronize的推论：
- 被synchronized修饰的同步块对同一条线程来说是可重入的。这意味着同一线程反复进入同步块也不会出现自己把自己锁死的情况。
- 被synchronized修饰的同步块在持有锁的线程执行完毕并释放锁之前，会无条件地阻塞后面其他线程的进入。这意味着无法像处理某些数据库中的锁那样，强制已获取锁的线程释放锁；也无法强制正在等待锁的线程中断等待或超时退出。
从执行成本的角度看，持有锁是一个重量级（Heavy-Weight）的操作。
在主流Java虚拟机实现中，Java的线程是映射到操作系统的原生内核线程之上的，如果要阻塞或唤醒一条线程，则需要操作系统来帮忙完成，这就不可避免地陷入用户态到核心态的转换中，进行这种状态转换需要耗费很多的处理器时间。尤其是对于代码特别简单的同步块（譬如被synchronized修饰的getter()或setter()方法），状态转换消耗的时间甚至会比用户代码本身执行的时间还要长。
上面的介绍中我们可以看到synchronized的局限性，除了synchronized关键字以外，自JDK5起，Java类库中新提供了java.util.concurrent包（下文称J.U.C包），其中的java.util.concurrent.locks.Lock接口便成了Java的另一种全新的互斥同步手段。基于Lock接口，用户能够以非块结构（Non-BlockStructured）来实现互斥同步，从而摆脱了语言特性的束缚，改为在类库层面去实现同步。
重入锁（ReentrantLock）是Lock接口最常见的一种实现，顾名思义，它与synchronized一样是可重入的。在基本用法上，ReentrantLock也与synchronized很相似，只是代码写法上稍有区别而已。不过，ReentrantLock与synchronized相比增加了一些高级功能，主要有以下三项：等待可中断、可实现公平锁及锁可以绑定多个条件。
- 等待可中断：是指当持有锁的线程长期不释放锁的时候，正在等待的线程可以选择放弃等待，改为处理其他事情。可中断特性对处理执行时间非常长的同步块很有帮助。
- 公平锁：是指多个线程在等待同一个锁时，必须按照申请锁的时间顺序来依次获得锁；而非公平锁则不保证这一点，在锁被释放时，任何一个等待锁的线程都有机会获得锁。synchronized中的锁是非公平的，ReentrantLock在默认情况下也是非公平的，但可以通过带布尔值的构造函数要求使用公平锁。不过一旦使用了公平锁，将会导致ReentrantLock的性能急剧下降，会明显影响吞吐量。
- 锁绑定多个条件：是指一个ReentrantLock对象可以同时绑定多个Condition对象。在synchronized中，锁对象的wait()跟它的notify()或者notifyAll()方法配合可以实现一个隐含的条件，如果要和多于一个的条件关联的时候，就不得不额外添加一个锁；而ReentrantLock则无须这样做，多次调用newCondition()方法即可。
2、非阻塞同步
互斥同步面临的主要问题是进行线程阻塞和唤醒所带来的性能开销，因此这种同步也被称为阻塞同步（Blocking Synchronization）。从解决问题的方式上看，互斥同步属于一种悲观的并发策略，其总是认为只要不去做正确的同步措施（例如加锁），那就肯定会出现问题，无论共享的数据是否真的会出现竞争，它都会进行加锁（这里讨论的是概念模型，实际上虚拟机会优化掉很大一部分不必要的加锁），这将会导致用户态到核心态转换、维护锁计数器和检查是否有被阻塞的线程需要被唤醒等开销。随着硬件指令集的发展，我们已经有了另外一个选择：基于冲突检测的乐观并发策略，通俗地说就是不管风险，先进行操作，如果没有其他线程争用共享数据，那操作就直接成功了；如果共享的数据的确被争用，产生了冲突，那再进行其他的补偿措施，最常用的补偿措施是不断地重试，直到出现没有竞争的共享数据为止。这种乐观并发策略的实现不再需要把线程阻塞挂起，因此这种同步操作被称为非阻塞同步（Non-Blocking Synchronization），使用这种措施的代码也常被称为无锁（Lock-Free）编程。
以CAS指令为例，CAS指令需要有三个操作数，分别是内存位置（在Java中可以简单地理解为变量的内存地址，用V表示）、旧的预期值（用A表示）和准备设置的新值（用B表示）。CAS指令执行时，当且仅当V符合A时，处理器才会用B更新V的值，否则它就不执行更新。但是，不管是否更新了V的值，都会返回V的旧值，上述的处理过程是一个原子操作，执行期间不会被其他线程中断。在JDK5之后，Java类库中才开始使用CAS操作，该操作由sun.misc.Unsafe类里面的compareAndSwapInt()和compareAndSwapLong()等几个方法包装提供。HotSpot虚拟机在内部对这些方法做了特殊处理，即时编译出来的结果就是一条平台相关的处理器CAS指令，没有方法调用的过程，或者可以认为是无条件内联进去了。
下面是一个简单是示例：
public void main() {
ExecutorService service = Executors.newFixedThreadPool(10);
for (int i = 0; i < 10; i++) {
service.execute(runnable);
}
try {
latch.await();
System.out.println(res.get());
} catch (InterruptedException e) {
e.printStackTrace();
}
}
private CountDownLatch latch = new CountDownLatch(10);
private AtomicInteger res = new AtomicInteger(0);
private Runnable runnable = new Runnable() {
@Override
public void run() {
for (int i = 0; i < 100; i++) {
res.incrementAndGet();
}
latch.countDown();
}
};
运行结果，输出为1000，复合预期。
管CAS看起来很美好，既简单又高效， 但显然这种操作无法涵盖互斥同步的所有使用场景， 并且CAS从语义上来说并不是真正完美的， 它存在一个逻辑漏洞： 如果一个变量V初次读取的时候是A值， 并且在准备赋值的时候检查到它仍然为A值， 那就能说明它的值没有被其他线程改变过了吗？ 这是不能的， 因为如果在这段期间它的值曾经被改成B， 后来又被改回为A， 那CAS操作就会误认为它从来没有被改变过。 这个漏洞称为CAS操作的“ABA问题”。
3、无同步方案
要保证线程安全，也并非一定要进行阻塞或非阻塞同步，同步与线程安全两者没有必然的联系。同步只是保障存在共享数据争用时正确性的手段，如果能让一个方法本来就不涉及共享数据，那它自然就不需要任何同步措施去保证其正确性，因此会有一些代码天生就是线程安全的。
可重入代码（ReentrantCode）：这种代码又称纯代码（PureCode），是指可以在代码执行的任何时刻中断它，转而去执行另外一段代码（包括递归调用它本身），而在控制权返回后，原来的程序不会出现任何错误，也不会对结果有所影响。在特指多线程的上下文语境里（不涉及信号量等因素），我们可以认为可重入代码是线程安全代码的一个真子集，这意味着相对线程安全来说，可重入性是更为基础的特性，它可以保证代码线程安全，即所有可重入的代码都是线程安全的，但并非所有的线程安全的代码都是可重入的。
可重入代码有一些共同的特征，例如，不依赖全局变量、存储在堆上的数据和公用的系统资源，用到的状态量都由参数中传入，不调用非可重入的方法等。我们可以通过一个比较简单的原则来判断代码是否具备可重入性：如果一个方法的返回结果是可以预测的，只要输入了相同的数据，就都能返回相同的结果，那它就满足可重入性的要求，当然也就是线程安全的。
线程本地存储（ThreadLocalStorage）：如果一段代码中所需要的数据必须与其他代码共享，那就看看这些共享数据的代码是否能保证在同一个线程中执行。如果能保证，我们就可以把共享数据的可见范围限制在同一个线程之内，这样，无须同步也能保证线程之间不出现数据争用的问题。符合这种特点的应用并不少见，大部分使用消费队列的架构模式（如“生产者-消费者”模式）都会将产品的消费过程限制在一个线程中消费完，其中最重要的一种应用实例就是经典Web交互模型中的“一个请求对应一个服务器线程”（Thread-per-Request）的处理方式，这种处理方式的广泛应用使得很多Web服务端应用都可以使用线程本地存储来解决线程安全问题。
Java语言中，如果一个变量要被多线程访问，可以使用volatile关键字将它声明为“易变的”；如果一个变量只要被某个线程独享，Java中就没有类似C++中__declspec(thread)[7]这样的关键字去修饰，不过我们还是可以通过java.lang.ThreadLocal类来实现线程本地存储的功能。每一个线程的Thread对象中都有一个ThreadLocalMap对象，这个对象存储了一组以ThreadLocal.threadLocalHashCode为键，以本地线程变量为值的K-V值对，ThreadLocal对象就是当前线程的ThreadLocalMap的访问入口，每一个ThreadLocal对象都包含了一个独一无二的threadLocalHashCode值，使用这个值就可以在线程K-V值对中找回对应的本地线程变量。
锁优化
为了在线程之间更高效地共享数据及解决竞争问题，从而提高程序的执行效率，HotSpot虚拟机开发团队在这个版本上花费了大量的资源去实现各种锁优化技术，如适应性自旋（AdaptiveSpinning）、锁消除（LockElimination）、锁膨胀（LockCoarsening）、轻量级锁（LightweightLocking）、偏向锁（BiasedLocking）等
自旋锁与自适应自旋
互斥同步对性能最大的影响是阻塞的实现，挂起线程和恢复线程的操作都需要转入内核态中完成，这些操作给Java虚拟机的并发性能带来了很大的压力。同时，虚拟机的开发团队也注意到在许多应用上，共享数据的锁定状态只会持续很短的一段时间，为了这段时间去挂起和恢复线程并不值得。现在绝大多数的个人电脑和服务器都是多路（核）处理器系统，如果物理机器有一个以上的处理器或者处理器核心，能让两个或以上的线程同时并行执行，我们就可以让后面请求锁的那个线程“稍等一会”，但不放弃处理器的执行时间，看看持有锁的线程是否很快就会释放锁。为了让线程等待，我们只须让线程执行一个忙循环（自旋），这项技术就是所谓的自旋锁。
自旋等待不能代替阻塞，且先不说对处理器数量的要求，自旋等待本身虽然避免了线程切换的开销，但它是要占用处理器时间的，所以如果锁被占用的时间很短，自旋等待的效果就会非常好，反之如果锁被占用的时间很长，那么自旋的线程只会白白消耗处理器资源，而不会做任何有价值的工作，这就会带来性能的浪费。因此自旋等待的时间必须有一定的限度，如果自旋超过了限定的次数仍然没有成功获得锁，就应当使用传统的方式去挂起线程。自旋的次数默认是十次。
不过无论是默认值还是用户指定的自旋次数，对整个Java虚拟机中所有的锁来说都是相同的。在JDK6中对自旋锁的优化，引入了自适应的自旋。自适应意味着自旋的时间不再是固定的了，而是由前一次在同一个锁上的自旋时间及锁的拥有者的状态来决定的。如果在同一个锁对象上，自旋等待刚刚成功获得过锁，并且持有锁的线程正在运行中，那么虚拟机就会认为这次自旋也很有可能再次成功，进而允许自旋等待持续相对更长的时间，比如持续100次忙循环。另一方面，如果对于某个锁，自旋很少成功获得过锁，那在以后要获取这个锁时将有可能直接省略掉自旋过程，以避免浪费处理器资源。有了自适应自旋，随着程序运行时间的增长及性能监控信息的不断完善，虚拟机对程序锁的状况预测就会越来越精准。
锁消除
锁消除是指虚拟机即时编译器在运行时，对一些代码要求同步，但是对被检测到不可能存在共享数据竞争的锁进行消除。锁消除的主要判定依据来源于逃逸分析的数据支持，如果判断到一段代码中，在堆上的所有数据都不会逃逸出去被其他线程访问到，那就可以把它们当作栈上数据对待，认为它们是线程私有的，同步加锁自然就无须再进行。
锁粗化
如果一系列的连续操作都对同一个对象反复加锁和解锁，甚至加锁操作是出现在循环体之中的，那即使没有线程竞争，频繁地进行互斥同步操作也会导致不必要的性能损耗。虚拟机探测到有这样一串零碎的操作都对同一个对象加锁，将会把加锁同步的范围扩展（粗化）到整个操作序列的外部。
轻量级锁
在介绍轻量级锁的概念之前，回顾Java的对象头中有一个lock_bits，其状态分为：未锁定（01）、轻量级锁定（00）、重量级锁定（10）、GC标记（11）。
接下来介绍轻量级锁的工作过程：
在代码即将进入同步块的时候，如果此同步对象没有被锁定（01），虚拟机首先在当前线程的栈帧中建立一个名为锁记录（Lock Record）的空间，用于存储锁对象目前的Mark Word（对象头中用于存储对象自身的运行时数据的部分）的拷贝。
然后，虚拟机将使用CAS操作尝试把对象的Mark Word更新为指向锁记录的指针，如果更新动作成功了，代表该线程拥有了这个对象的锁，并且对象Mark Lock的锁标志位将转变为"00"，表示对象处于轻量级锁定状态。
如果这个更新操作失败了，那就意味着至少存在一条线程与当前线程竞争获取该对象的锁。虚拟机首先会检查对象的MarkWord是否指向当前线程的栈帧，如果是，说明当前线程已经拥有了这个对象的锁，那直接进入同步块继续执行就可以了，否则就说明这个锁对象已经被其他线程抢占了。如果出现两条以上的线程争用同一个锁的情况，那轻量级锁就不再有效，必须要膨胀为重量级锁，锁标志的状态值变为“10”，此时MarkWord中存储的就是指向重量级锁（互斥量）的指针，后面等待锁的线程也必须进入阻塞状态。
上面描述的是轻量级锁的加锁过程，它的解锁过程也同样是通过CAS操作来进行的，如果对象的MarkWord仍然指向线程的锁记录，那就用CAS操作把对象当前的MarkWord和线程中复制的DisplacedMarkWord替换回来。假如能够成功替换，那整个同步过程就顺利完成了；如果替换失败，则说明有其他线程尝试过获取该锁，就要在释放锁的同时，唤醒被挂起的线程。
轻量级锁能提升程序同步性能的依据是“对于绝大部分的锁，在整个同步周期内都是不存在竞争的”这一经验法则。如果没有竞争，轻量级锁便通过CAS操作成功避免了使用互斥量的开销；但如果确实存在锁竞争，除了互斥量的本身开销外，还额外发生了CAS操作的开销。因此在有竞争的情况下，轻量级锁反而会比传统的重量级锁更慢。
偏向锁
偏向锁也是JDK6中引入的一项锁优化措施，它的目的是消除数据在无竞争情况下的同步原语，进一步提高程序的运行性能。如果说轻量级锁是在无竞争的情况下使用CAS操作去消除同步使用的互斥量，那偏向锁就是在无竞争的情况下把整个同步都消除掉，连CAS操作都不去做了。
偏向锁中的“偏”，就是偏心的“偏”、偏袒的“偏”。它的意思是这个锁会偏向于第一个获得它的线程，如果在接下来的执行过程中，该锁一直没有被其他的线程获取，则持有偏向锁的线程将永远不需要再进行同步。
待完善。
参考文献
深入理解Java虚拟机：Java高级特性与最佳实践（第3版）第六章、第十二章、第十三章——周志明
Java并发——关键字synchronized解析
JVM源码分析之synchronized实现
深入理解synchronized底层源码