Unity Shade 渐变纹理(十二)

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果：

使用不同的渐变纹理控制漫反射光照

贴图1

贴图2

Shader代码：

// 渐变纹理
Shader "Custom/Texture/RampTexture"
{
    Properties
    {
        _Color ("Color", Color) = (1, 1, 1, 1)
        // 渐变纹理
        _RampTex ("RampTex", 2D) = "white" { }
        // 高光反射颜色
        _Specular ("Specular", Color) = (1, 1, 1, 1)
        // 高光区域大小
        _Gloss ("Gloss", Range(8, 256)) = 20
    }
    
    SubShader
    {
        Tags { "RenderType" = "Opaque" }
        LOD 100
        Cull Off
        
        pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM
            
            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"
            
            fixed4 _Color;
            sampler2D _RampTex;
            float4 _RampTex_ST;
            fixed4 _Specular;
            float _Gloss;
            
            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION;
                float3 normal: NORMAL;
                float4 texcoord: TEXCOORD0;
            };
            
            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION;
                float3 worldNormal: TEXCOORD0;
                float3 worldPos: TEXCOORD1;
                float2 uv: TEXCOORD2;
            };
            
            // 顶点着色器
            v2f vert(a2v v)
            {
                v2f o;
                // 将顶点坐标从模型空间变换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_VP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);
                
                // 将法线从模型空间
                // 等价于o.worldNormal = normalize(mul(v.normal, (float3x3)unity_WorldToObject));
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                
                // 将顶点坐标从模型空间变换到世界空间
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);
                
                // 计算平铺和平移后的纹理坐标
                // 等价于o.uv = v.texcoord.xy * _RampTex_ST.xy + _RampTex_ST.zw;
                o.uv = TRANSFORM_TEX(v.texcoord, _RampTex);

                return o;
            }
            
            fixed4 frag(v2f i): SV_TARGET
            {
                // 获得世界光线向量
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                
                // 获得环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
                
                // 获得半兰伯特光照光
                fixed halfLambert = dot(i.worldNormal, worldLightDir) * 0.5 + 0.5;
                // 使用halfLambert构建纹理坐标，获得漫反射颜色
                fixed3 diffuseColor = tex2D(_RampTex, float2(halfLambert, halfLambert)).rgb * _Color.rgb;
                // 获得漫反射光
                fixed3 diffuse = _LightColor0.rgb * diffuseColor;
                
                // 获得世界空间下观察向量
                fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
                
                // 获得Blinn-Phong高光反射半角向量
                fixed3 halfDir = normalize(worldLightDir + viewDir);
                fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(saturate(dot(i.worldNormal, halfDir)), _Gloss);
                
                return fixed4(ambient + diffuse + specular, 1.0);
            }
            
            ENDCG
            
        }
    }
}