记一次在以太坊主网上被钓鱼合约受骗的整个过程

序

2018.04.18上午, 当时无聊在ethscan上在看verified contract, 主要是想学习一下优秀的源代码和做一些代码审计的工作。
在看到了名为GIFT_1_ETH的合约时，刚开始以为只是一个无聊的人做的猜谜游戏,试着猜了几下。后来发现原来代码有漏洞，虽然刚开始警惕的测试了整个流程，但还是嫩了点，最后毫不犹豫的跳了坑。
以此篇日记警惕后人吧。

钓鱼代码

contract GIFT_1_ETH
{
    bytes32 public hashPass;
    bool closed = false;
    address sender;
    uint unlockTime;
    
    function SetPass(bytes32 hash)
    public
    payable
    {
        if( (!closed&&(msg.value > 1 ether)) || hashPass==0x0 )
        {
            hashPass = hash;
            sender = msg.sender;
            unlockTime = now;
        }
    }
    function GetGift(bytes pass)
    external
    payable
    canOpen
    {
        if(hashPass == keccak256(pass))
        {
            msg.sender.transfer(this.balance);
        }
    }
    
    
    function PassHasBeenSet(bytes32 hash)
    public
    {
        if(hash==hashPass&&msg.sender==sender)
        {
           closed=true;
        }
    }
    
    modifier canOpen
    {
        require(now>unlockTime);
        _;
    }
    
    function() public payable{}
    
}

钓鱼机制

!!############受害者至少会损失1ETH.

实施整个攻击一共有4个账户,分别是N_A(普通账户), N_B(普通账户),C_A(合约账户, 也是钓鱼代码的账户),C_B(合约账户)

• 第一步, N_A发起一项交易，创建C_A, 即上面的合约代码.注意! 此时sender 不是 N_A!!!
• 第二步, N_B 调用 C_B的函数,再通过message call调用C_A的SetPass函数，设置pass, 成为真正的sender!! 而不用花费任何ether.
• 第三步, N_B调用C_B的函数, 再通过message call调用C_A的PassHasBeenSet函数，设置closed为true.
• 第四步, 注意了!! 关键一步!! N_A发起一项交易，调用C_A的SetPass函数，并附带1ETH. 假装自己是做最开始的设置密码的步骤, 让别人觉得他是sender!! 其实调用并未成功设置pass。

所有步骤结束后，C_A界面的TX界面显示如下:

所有步骤完成后C_A页面显示的所有交易

至此，钓鱼的准备过程结束了，后面的就是等待了！一旦受害者调用SetPass妄想得到gift就会失去他所发送的1ETHER, 然后N_B通过C_B就能够转走C_A的余额.

为什么会成功?

1. 我蠢

2. 很隐蔽，如果你是新手的话。

   • 第二步和第三步的tx，你在C_A的页面是看不到这些交易详情的.

   Internal transactions, despite the name (which isn't part of the yellowpaper; it's a convention people have settled on) aren't actual transactions, and aren't included directly in the blockchain; they're value transfers that were initiated by executing a contract.

   • C_A的tx 只有 N_A发起的两项交易记录，让你误认为 sender是N_A, closed值为false.
   • 如果你不懂EVM的storage的优化的话,你使用web3.eth.getStorgeAt得到closed的值时候，可能会迷惑。因为不是0或者1，而是 0x0000000000000000000000663e50e33de1ab627453a88d845757c5fa2c16d201.

钓鱼流程图

钓鱼流程图

之后N_B就可以通过C_B转走C_A所有的钱了.

教训

• 当你需要付出与你能够免费得到的结果相当的代价时， 三思。
• 一定要debug!!! 如果我在发送之前debug这个tx，根本不会上当。
• 好好学习底层知识。

后记

本来是想做审计的，结果把自己搭了进去。警惕心不够，对EVM不够了解，对ethereum不够了解，以后切记浮躁。
虽然损失了东西，但是发现了好多之前没有认真思考过的东西，比如说EVM字节码。之后我去专注于ethereum的安全，包括代码审计。
还有，我要誓死跟主网上的钓鱼合约做斗争。我会建一个git仓库，里面会存放钓鱼代码地址和攻击原理。

最后要打赏的客官这边: 0x003be5df5fef651ef0c59cd175c73ca1415f53ea