在上一篇文章类结构探究（三）-- cache分析中已经了解到，方法会保存到类的cache中，那么缓存的方法是如何查找并调用的呢，则便是本文的探究的目标--方法快速查找。
方法调用的实质
当我们使用clang编译.m文件，可以看到一个对象调用方法会被编译器转化为
((#返回类型# (*)(id, SEL))(void *)objc_msgSend)(#方法接收者#, sel_registerName("#方法名#"));
对象调用方法本质上是给对象放松一个方法名相同的消息，那么objc_msgSend内部是怎么走的呢？我们需要objc4-7.8.1源码中寻找答案。
objc_msgSend是
runtime提供的一个api，OC代码实质上会通过编译器转化C++代码，再通过runtime进行运行加载到内存中，runtime提供了三个方式供开发者调用
- Objective-C Code，例如 [person sayNB]
- Framework&Serivce，例如 isKindofClass
- Runtime API，例如 class_getInstanceSize
objc_msgSend实现探究
在objc4-7.8.1中全局搜索objc_msgSend，可以在objc-msg-arm.s、objc-msg-arm64.s、objc-msg-i386、objc-msg-simulartor.s等汇编文件中找到objc_msgSend实现，我们可以推断，objc_msgSend是有汇编代码参与的。而实际，方法查找时在缓存中查找这一过程是由汇编代码实现，使用汇编执行效率更高，而汇编实现的这一过程称为快速查找。
因为iPhone的系统架构是arm64，所以本文我们在objc-msg-arm64.s中探究快速查找流程。
首先看方法入口
ENTRY _objc_msgSend
// 无窗口
UNWIND _objc_msgSend, NoFrame
// p0，也就是第一个参数消息接收者与空进行比较
cmp p0, #0 // nil check and tagged pointer check
// 非空，支持taggedpointer的流程
#if SUPPORT_TAGGED_POINTERS
b.le LNilOrTagged // (MSB tagged pointer looks negative)
#else
//空值直接返回空
b.eq LReturnZero
#endif
// 根据对象拿到isa
// ldr ：从存储器中加载（Load）字到一个寄存器（Register）中
// 将对象x0指向的内容，也就是isa（对象内存前8个字节为isa），存入p13寄存器
ldr p13, [x0] // p13 = isa
// 通过计算（isa & ISA_MASK）得到isa的shiftcls信息，得到类地址，存入到p16寄存器
GetClassFromIsa_p16 p13 // p16 = class
LGetIsaDone:
// calls imp or objc_msgSend_uncached
// 获取类对象后在CacheLookup中开始缓存查找流程
CacheLookup NORMAL, _objc_msgSend
// 以下为小对象的执行流程
#if SUPPORT_TAGGED_POINTERS
LNilOrTagged:
b.eq LReturnZero // nil check
// tagged
adrp x10, _objc_debug_taggedpointer_classes@PAGE
add x10, x10, _objc_debug_taggedpointer_classes@PAGEOFF
ubfx x11, x0, #60, #4
ldr x16, [x10, x11, LSL #3]
adrp x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGE
add x10, x10, _OBJC_CLASS_$___NSUnrecognizedTaggedPointer@PAGEOFF
cmp x10, x16
b.ne LGetIsaDone
// ext tagged
adrp x10, _objc_debug_taggedpointer_ext_classes@PAGE
add x10, x10, _objc_debug_taggedpointer_ext_classes@PAGEOFF
ubfx x11, x0, #52, #8
ldr x16, [x10, x11, LSL #3]
b LGetIsaDone
// SUPPORT_TAGGED_POINTERS
#endif
// 返回空值处理
LReturnZero:
// x0 is already zero
mov x1, #0
movi d0, #0
movi d1, #0
movi d2, #0
movi d3, #0
ret
END_ENTRY _objc_msgSend
关于GetClassFromIsa_p16的流程如下
.macro GetClassFromIsa_p16 /* src */
#if SUPPORT_INDEXED_ISA
// Indexed isa
// 将isa存入p16寄存器
mov p16, $0 // optimistically set dst = src
tbz p16, #ISA_INDEX_IS_NPI_BIT, 1f // done if not non-pointer isa
// isa in p16 is indexed
adrp x10, _objc_indexed_classes@PAGE
add x10, x10, _objc_indexed_classes@PAGEOFF
ubfx p16, p16, #ISA_INDEX_SHIFT, #ISA_INDEX_BITS // extract index
ldr p16, [x10, p16, UXTP #PTRSHIFT] // load class from array
1:
#elif __LP64__ // 64位，真机会走这个流程
// 64-bit packed isa
// isa与上ISA_MASK得到shiftcls，存入p16寄存器
// # define ISA_MASK 0x0000000ffffffff8ULL
and p16, $0, #ISA_MASK
#else
// 32-bit raw isa
mov p16, $0
#endif
.endmacro
从以上代码，我们总结出以下流程。
- 进入
objc_msgSend后，会先对消息接收者进行判空，为空则直接返回空，结束方法查找流程。 - 如果消息接受者不为空且为taggedpointer类型，执行
LNilOrTagged流程 - 如果消息接收者不为空且为non-taggedpointer类型，执行
CacheLookup流程
CacheLookup流程分析
接下来便是整个查找过程的重点
.macro CacheLookup
//
// Restart protocol:
//
// As soon as we're past the LLookupStart$1 label we may have loaded
// an invalid cache pointer or mask.
//
// When task_restartable_ranges_synchronize() is called,
// (or when a signal hits us) before we're past LLookupEnd$1,
// then our PC will be reset to LLookupRecover$1 which forcefully
// jumps to the cache-miss codepath which have the following
// requirements:
//
// GETIMP:
// The cache-miss is just returning NULL (setting x0 to 0)
//
// NORMAL and LOOKUP:
// - x0 contains the receiver
// - x1 contains the selector
// - x16 contains the isa
// - other registers are set as per calling conventions
//
LLookupStart$1:
//CACHE = (2 * __SIZEOF_POINTER__) = 16个字节
// 通过p16的指针找到类，首地址偏移16个字节得到cache
// arm64下cache首个16字节空间为_maskAndBuckets，所以p11存入的值为_maskAndBuckets
// p1 = SEL, p16 = isa
ldr p11, [x16, #CACHE] // p11 = mask|buckets
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16 // 64位走这里
// 与上0x0000ffffffffffff得到buckets存入p10
// _maskAndBuckets中buckets存储在后48位
and p10, p11, #0x0000ffffffffffff // p10 = buckets
// p11(_maskAndBuckets) 右移48位得到mask
// p1为sel，与上mask得到缓存方法下标index，存入p12寄存器
and p12, p1, p11, LSR #48 // x12 = _cmd & mask
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4 // 32位走这里
and p10, p11, #~0xf // p10 = buckets
and p11, p11, #0xf // p11 = maskShift
mov p12, #0xffff
lsr p11, p12, p11 // p11 = mask = 0xffff >> p11
and p12, p1, p11 // x12 = _cmd & mask
#else
#error Unsupported cache mask storage for ARM64.
#endif
// PTRSHIFT = 3
// p12也就是index左移4位，本质就是index乘以16，因为cmd中sel占8个字节，imp占8个字节，总共16个字节，
// p10（buckets），加上index*inex*cmd大小，也就便宜到index对应的buckets，存入到p12寄存器
add p12, p10, p12, LSL #(1+PTRSHIFT)
// p12 = buckets + ((_cmd & mask) << (1+PTRSHIFT))
// 将p12的值分别存入p17和p9寄存器
// ldp: 是 ldr的衍生, 可以同时读/写两个寄存器, ldr只能读写一个
// bucket存放了imp和sel，所以p17存放imp，p9存放sel
ldp p17, p9, [x12] // {imp, sel} = *bucket
// 比较 p1（目标sel）和p9（index对应的sel）
1: cmp p9, p1 // if (bucket->sel != _cmd)
// 不匹配跳转到2流程
b.ne 2f // scan more
// 匹配执行CacheHit流程
CacheHit $0 // call or return imp
2: // not hit: p12 = not-hit bucket 没有命中执行该流程
// 执行CheckMiss流程,如果找到的bucket为空，说明缓存中没有，结束快速查找流程
CheckMiss $0 // miss if bucket->sel == 0
// 比较p12（目标方法）和p10(buckets首地址)是否相等
cmp p12, p10 // wrap if bucket == buckets
b.eq 3f // 如果匹配，即下标index位为首位，跳转3流程执行
// 不匹配，即index非首位，执行以下流程
// p12,也就是buckets中index对应的bucket，递减16个字节，向前查找
// BUCKET_SIZE = (2 * __SIZEOF_POINTER__) = 16
ldp p17, p9, [x12, #-BUCKET_SIZE]! // {imp, sel} = *--bucket
// 回到1流程循环
b 1b // loop
3: // wrap: p12 = first bucket, w11 = mask
#if CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_HIGH_16
// p11(_maskAndBuckets)右移48-4=44得到mask
// p11(mask)
// p12(目标方法，因为此前2中判断了index位于首位，所以此时p12为buckets首地址)
// p12(buckets首地址) + p11（mask）= buckets最后一位， 存入p12寄存器
add p12, p12, p11, LSR #(48 - (1+PTRSHIFT))
// p12 = buckets + (mask << 1+PTRSHIFT)
#elif CACHE_MASK_STORAGE == CACHE_MASK_STORAGE_LOW_4
add p12, p12, p11, LSL #(1+PTRSHIFT)
// p12 = buckets + (mask << 1+PTRSHIFT)
#else
#error Unsupported cache mask storage for ARM64.
#endif
// Clone scanning loop to miss instead of hang when cache is corrupt.
// The slow path may detect any corruption and halt later.
//将p12(buckets最后一位存入p17和p9寄存器)
// 此时p17 = imp， p9 = sel
ldp p17, p9, [x12] // {imp, sel} = *bucket
// 判断p9sel是否与目标方法一致
1: cmp p9, p1 // if (bucket->sel != _cmd)
// 不匹配跳转到2中执行
b.ne 2f // scan more
// 配置执行CacheHit
CacheHit $0 // call or return imp
2: // not hit: p12 = not-hit bucket
// 执行CheckMiss流程,如果找到的bucket为空，说明缓存中没有，结束快速查找流程
CheckMiss $0 // miss if bucket->sel == 0
// 比较 p12（此时p12为index对应的方法）和p10（buckets首地址）
cmp p12, p10 // wrap if bucket == buckets
// 如果一致，说明cache中已经走了一遍遍历都没有找到，跳转3流程执行
b.eq 3f
// 不一致说明没有遍历完成，递减向前遍历，重复1流程执行
ldp p17, p9, [x12, #-BUCKET_SIZE]! // {imp, sel} = *--bucket
b 1b // loop
LLookupEnd$1:
LLookupRecover$1:
3: // double wrap
// cache中都没有找到执行JumpMiss
JumpMiss $0
.endmacro
而CacheHit、CheckMiss和JumpMiss的定义如下，
// CacheHit: x17 = cached IMP, x12 = address of cached IMP, x1 = SEL, x16 = isa
.macro CacheHit
.if $0 == NORMAL
TailCallCachedImp x17, x12, x1, x16 // authenticate and call imp
.elseif $0 == GETIMP
mov p0, p17
cbz p0, 9f // don't ptrauth a nil imp
AuthAndResignAsIMP x0, x12, x1, x16 // authenticate imp and re-sign as IMP
9: ret // return IMP
.elseif $0 == LOOKUP
// No nil check for ptrauth: the caller would crash anyway when they
// jump to a nil IMP. We don't care if that jump also fails ptrauth.
AuthAndResignAsIMP x17, x12, x1, x16 // authenticate imp and re-sign as IMP
ret // return imp via x17
.else
.abort oops
.endif
.endmacro
.macro CheckMiss
// miss if bucket->sel == 0
.if $0 == GETIMP
cbz p9, LGetImpMiss
.elseif $0 == NORMAL // 会走这里
// 判断p9（查找到的方法）是否为0，为0执行__objc_msgSend_uncached方法
// cbz： 比较（Compare），如果结果为零（Zero）就转移（只能跳到后面的指令）
cbz p9, __objc_msgSend_uncached
.elseif $0 == LOOKUP
cbz p9, __objc_msgLookup_uncached
.else
.abort oops
.endif
.endmacro
.macro JumpMiss
.if $0 == GETIMP
b LGetImpMiss
.elseif $0 == NORMAL
b __objc_msgSend_uncached
.elseif $0 == LOOKUP
b __objc_msgLookup_uncached
.else
.abort oops
.endif
.endmacro
可以看到CacheHit将查找到的imp返回，而CheckMiss和JumpMiss则调用了__objc_msgSend_uncached继续流程执行。
CacheLookup的流程分析如下：
- 首先通过对象的
isa与上ISA_MASK得到对象的类，然后类地址偏移16个字节得到maskAndBuckets - 通过
maskAndBuckets得到buckets和mask - 需要查找的目标sel与上
mask得到方法的哈希值，即sel的下标 - 查找
buckets的下标对应存储的方法是否与目标一致 - 如果一致，缓存命中，执行
CacheHit返回IMP - 如果不一致，判断当前查找到的bucket是否为空，为空则执行
__objc_msgSend_uncached - 不为空继续快速查找流程，判断当前下表对应的方法是否为buckets第一个元素
- 如果是，定位到buckets最后一个元素往前遍历查找，如果在这个遍历过程中查找到方法，缓存命中
- 如果不是，从当前下标往前遍历，如果在这个遍历过程中查找到方法，缓存命中，返回结果；如果没有，定位到buckets最后一个元素从前往前再次遍历
- 如果便利了整个bucket都没有找到，执行
JumpMiss
__objc_msgSend_uncached执行流程
__objc_msgSend_uncached执行如下：
STATIC_ENTRY __objc_msgSend_uncached
UNWIND __objc_msgSend_uncached, FrameWithNoSaves
// THIS IS NOT A CALLABLE C FUNCTION
// Out-of-band p16 is the class to search
MethodTableLookup
TailCallFunctionPointer x17
END_ENTRY __objc_msgSend_uncached
继续查看MethodTableLookup
.macro MethodTableLookup
// push frame
SignLR
stp fp, lr, [sp, #-16]!
mov fp, sp
// save parameter registers: x0..x8, q0..q7
sub sp, sp, #(10*8 + 8*16)
stp q0, q1, [sp, #(0*16)]
stp q2, q3, [sp, #(2*16)]
stp q4, q5, [sp, #(4*16)]
stp q6, q7, [sp, #(6*16)]
stp x0, x1, [sp, #(8*16+0*8)]
stp x2, x3, [sp, #(8*16+2*8)]
stp x4, x5, [sp, #(8*16+4*8)]
stp x6, x7, [sp, #(8*16+6*8)]
str x8, [sp, #(8*16+8*8)]
// lookUpImpOrForward(obj, sel, cls, LOOKUP_INITIALIZE | LOOKUP_RESOLVER)
// receiver and selector already in x0 and x1
mov x2, x16
mov x3, #3
bl _lookUpImpOrForward
// IMP in x0
mov x17, x0
// restore registers and return
ldp q0, q1, [sp, #(0*16)]
ldp q2, q3, [sp, #(2*16)]
ldp q4, q5, [sp, #(4*16)]
ldp q6, q7, [sp, #(6*16)]
ldp x0, x1, [sp, #(8*16+0*8)]
ldp x2, x3, [sp, #(8*16+2*8)]
ldp x4, x5, [sp, #(8*16+4*8)]
ldp x6, x7, [sp, #(8*16+6*8)]
ldr x8, [sp, #(8*16+8*8)]
mov sp, fp
ldp fp, lr, [sp], #16
AuthenticateLR
.endmacro
可以看到方法中执行了_lookUpImpOrForward，而全局查找了这个方法都没有找到定义，实际上这个方法在objc-runtime-new.mm中实现，是由C++代码实现，所以到MethodTableLookup为止，objc_msgSend的快速查找流程已经结束，接下来进入到类的methodlist查找方法的慢速查找流程。
总结
objc_msgSend快速查找流程可以用下图描述：
快速查找流程.png