UnityShader17：光照属性与阴影
前置：UnityShader16：点光源和聚光灯
一、一些重要的光照、阴影属性
一个一个来（绿色的部分暂时可以不用了解）：
- Type：光照类型，除了常用的3个，还有一个面光源
- Color：光照颜色
- Mode：光照模式：实时光照/混合/烘培光照
- Intensity：光照强度
- Indirect Multiplier：在计算该灯光所产生的间接光照时的强度倍乘
- Shadow Type：阴影类型：无阴影/硬阴影/软阴影
- Cookie：用于光照投影的纹理
- Cookie Size：Cookie 贴图大小倍数，只有平行光可以设置
- Draw Halo：灯光是否显示辉光，一般用于模拟光晕效果
- Flare：辉光贴图，一般为黑白图
- Render Mode：光照渲染模式，是否为重要光照，这个在这一章有详细介绍
- Culling Mask：选择哪些层受光源的影响，如果不勾选对应层，那么在这个层的物体将不会受到光照影响
其中对于点光源还有一个A半径属性，对于聚光灯还有一个B张角属性
关于阴影部分：
- Baked Shadow Angle：只有为平行光软阴影时才可设置，一般用来在阴影的边缘增加人造软化，让阴影看起来更自然
- Realtime Shadows Strength：实时阴影强度
- Resolution：阴影贴图分辨率，较高的分辨率能增加阴影的保真度，但会消耗更多的GPU时间和存储空间
- Bias：阴影偏移，也是阴影被推离光线的距离，范围为0到2，默认值为0.5，一般用于避免人工物体自阴影的错误
- Normal Bias：法线偏移，也是投射阴影的表面相对于周围正常表面的下沉效果，范围为0到3，默认值为0.4，一般用于避免人工物体自阴影的错误
- Near Plane：阴影最近剪切平面，与摄影机距离小于这个距离的场景物体将不产生阴影
关于物体是否接受阴影的设置：
其中将 Cast Shadows 设置为 Two Sided 后，对应物体的所有面都会计算阴影信息
二、阴影的实现原理
可以参考 OpenGL 的部分教程：
- 阴影映射：https://blog.csdn.net/Jaihk662/article/details/108367739 & https://blog.csdn.net/Jaihk662/article/details/108404130
- 点光源阴影：https://blog.csdn.net/Jaihk662/article/details/108455092
一个好消息是，关于阴影的计算 Unity 已经帮我们写好了，如不是需要特殊定制，不需要写太多的代码
在新版本的 Unity 里，其采用了屏幕空间阴影映射技术(Screenspace Shadow Map)来计算阴影，这也是原先延迟渲染中产生阴影的方法，不过对于部分显卡不支持 MRT 的平台可能就不支持这种特性
三、阴影的实现
只需要在之前的基础上更改3个地方就可以了：
1)：内置宏 SHADOW_COORDS() 或 LIGHTING_COORDS(,)：
struct vert2frag
{
float4 pos: SV_POSITION;
float3 wPos: TEXCOORD0;
float3 wNormal: TEXCOORD1;
float2 uv: TEXCOORD2;
SHADOW_COORDS(3)
};内置宏的参数需要一个可用的插值寄存器索引值，它的作用就是声明一个用于阴影纹理采样坐标 _ShadowCoord
而对于 LIGHTING_COORDS 宏，它同时声明了用于阴影纹理采样坐标 _ShadowCoord 和用于衰减纹理采样坐标 _LightCoord
2)：内置宏 TRANSFER_SHADOW 或 TRANSFER_VERTEX_TO_FRAGMENT：
vert2frag vert(_2vert v)
{
vert2frag o;
//……
TRANSFER_SHADOW(o);
return o;
}该宏的展开为一段计算阴影纹理坐标的代码，它会使用 v.vertex 或 v.pos 来计算坐标 _ShadowCoord，因此你需要保证这两个变量名要与宏内的代码相匹配，除此之外，顶点着色器的输入参数变量名也必须为 v
而对于 TRANSFER_VERTEX_TO_FRAGMENT 宏，它同时计算了 _ShadowCoord 和用于衰减纹理采样坐标 _LightCoord 坐标
如果当前平台可以使用屏幕空间阴影映射技术（通过判断是否定义了 UNITY_NO_SCREENSPACE_SHADOWS 来得到），那么 TRANSFER_SHADOW 就会调用内置的 ComputeScreenPos 来计算 _ShadowCoord
3)：内置宏 SHADOW_ATTENUATION() 或 LIGHT_ATTENUATION(i)：
fixed4 frag(vert2frag i): SV_Target
{
//……
fixed shadow = SHADOW_ATTENUATION(i);
return fixed4((diffuse + specular) * atten * shadow, 1.0);
}
ENDCG该宏的展开为计算阴影值，就和衰减值一样，其范围为 [0, 1]，使用 LIGHT_ATTENUATION 宏可以同时计算阴影值和衰减值，它当然要和 LIGHTING_COORDS(,) 宏与 TRANSFER_VERTEX_TO_FRAGMENT 宏对应
最后得到的效果如下：
其它的点：
- 上面的3个宏都可以在 AutoLight.cginc 中找到具体的实现
- 如果关闭了阴影，SHADOW_ COORDS 和 TRANSFER_SHADOW 就不会有任何作用，SHADOW_ATTENUATION 的值等同于数值1
- 对于 BasePass 和 AddPass 处理方式一样，不过 BasePass 中渲染的平行光默认是支持阴影的，而 AddPass 中渲染的光源在默认情况下是没有阴影效果的，即使在它的 Light 组件中设置了有阴影的 Shadow Type，但我们可以在 AddPass 中用 #pragma multi_compile_fwdadd_fullshadows 代替 #pragma multi_compile_fwdadd 编译指令，为点光源和聚光灯开启阴影效果，这需要 Unity 在内部使用更多的 Shader 变种
上面的内容都是为了实现让物体接收阴影，而让物体投射阴影不需要我们进行任何处理，只需要设置 Fallback 语义为 Specular 就可以了：
FallBack "Specular"这是因为对于内置的 Specular，它的 Fallback 又调用了 VertexLit，对于这个内置的 Shader：VertexLit，它的里面实现了 LightMode 为 ShadowCaster 的 Pass，这个 Pass 的主要目的是把深度信息写入渲染目标中，这个渲染目标可以是阴影映射纹理，或是摄像机的深度纹理
如果开启了透明度测试，需要设置 Fallback 为 Transparent/Cutout/VertexLit（这个 ShadowCaster Pass 也同时计算了透明度测试），并且必须提供 _Cutoff 属性、设置物体的 CastShadow 属性为 Two Sided
四、完整的着色器代码
4)：内置宏 UNITY_LIGHT_ATTENUATION(atten, i, worldPos)：
其中第一个参数为衰减值（充当输出），第二个参数为片段着色器输入 v2f，第三个参数为顶点时间空间坐标，这个宏直接帮我们同时计算了光照衰减和阴影，有了它之后就不需要根据光源的类型来写判断自己算衰减了
当然了，这个宏现在已经基本不用了，既然要 Unity 帮我们同时计算阴影值和衰减值，上面的 LIGHT_ATTENUATION(i) 宏会是一个更好的选择
Unity 针对不同的光源类型、是否启用 cookie 等多种情况声明了多个版本的 UNITY_LIGHT_ATTENUATION
// Upgrade NOTE: replaced '_LightMatrix0' with 'unity_WorldToLight'
Shader "Jaihk662/AllInOne1"
{
Properties
{
_DiffuseColor ("DiffuseColor", Color) = (1.0, 1.0, 1.0, 1.0)
_SpecularColor ("SpecularColor", Color) = (1.0, 1.0, 1.0, 1.0)
_MainTex ("MainTex", 2D) = "white" {}
_NormalMap ("NormalMap", 2D) = "bump" {}
_NormalScale ("NormalScale", float) = 1.0 //控制法线贴图展现的凹凸效果，0~1
_SpecularMask ("SpecularMask", 2D) = "white" {}
_SpecularMaskScale ("SpecularMaskScale", float) = 1.0
_Gloss ("Gloss", Range(8.0, 256)) = 20
}
SubShader
{
LOD 200
Tags { "RenderType" = "Opaque" "Queue" = "Geometry" }
//如果场景中包含了多个平行光，Unity会选择最亮的那个传递给BasePass进行逐像素处理，其它平行光按照逐顶点或在AddPass中按逐像素处理（没有平行光默认全黑）
PASS
{
Tags { "LightMode" = "ForwardBase" }
CGPROGRAM
#pragma vertex vert
#pragma multi_compile_fwdbase
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _DiffuseColor;
fixed4 _SpecularColor;
sampler2D _MainTex;
sampler2D _NormalMap;
float _Gloss;
float _NormalScale;
sampler2D _SpecularMask;
float _SpecularMaskScale;
float4 _MainTex_ST;
struct _2vert
{
float4 vertex: POSITION; //这个名字vertex不可修改，不然Unity内置宏就无法识别到
float3 normal: NORMAL;
float4 tangent: TANGENT;
float4 texcoord: TEXCOORD0;
};
struct vert2frag
{
float4 pos: SV_POSITION; //这个名字pos不可修改
float2 uv: TEXCOORD0;
float4 TtoW1 : TEXCOORD1; //世界空间中的顶点坐标wPos放在了这3个float4的第四维里
float4 TtoW2 : TEXCOORD2;
float4 TtoW3 : TEXCOORD3;
SHADOW_COORDS(4)
};
vert2frag vert(_2vert v) //这个输入参数v不可修改
{
vert2frag o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
TANGENT_SPACE_ROTATION;
float3 wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 wNormal = UnityObjectToWorldNormal(v.normal);
fixed3 wTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 wBinormal = cross(wNormal, wTangent) * v.tangent.w;
o.TtoW1 = float4(wTangent.x, wBinormal.x, wNormal.x, wPos.x);
o.TtoW2 = float4(wTangent.y, wBinormal.y, wNormal.y, wPos.y);
o.TtoW3 = float4(wTangent.z, wBinormal.z, wNormal.z, wPos.z);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(vert2frag i): SV_Target
{
float3 wPos = float3(i.TtoW1.w, i.TtoW2.w, i.TtoW3.w);
fixed3 normal = UnpackNormal(tex2D(_NormalMap, i.uv)); //内置函数UnpackNormal自动帮我们将法线向量由[0,1]映射到[-1,1]
normal.xy *= _NormalScale;
normal.z = sqrt(1.0 - saturate(dot(normal.xy, normal.xy))); //反正是标准化过的单位向量，可以自己由xy算出z的值
normal = normalize(half3(dot(i.TtoW1.xyz, normal), dot(i.TtoW2.xyz, normal), dot(i.TtoW3.xyz, normal)));
fixed3 wLightDir = normalize(UnityWorldSpaceLightDir(wPos));
fixed3 wViewDir = normalize(UnityWorldSpaceViewDir(wPos));
fixed3 albedo = tex2D(_MainTex, i.uv) * _DiffuseColor.rgb;
fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(normal, wLightDir));
fixed3 reflectDir = normalize(reflect(-wLightDir, normal));
fixed specularMask = tex2D(_SpecularMask, i.uv).g * _SpecularMaskScale;
fixed3 specular = specularMask * _LightColor0.rgb * _SpecularColor.rgb * pow(saturate(dot(reflectDir, wViewDir)), _Gloss);
UNITY_LIGHT_ATTENUATION(atten, i, wPos);
return fixed4(ambient + (diffuse + specular) * atten, 1.0);
}
ENDCG
}
PASS
{
Tags { "LightMode" = "ForwardAdd" }
Blend One One
CGPROGRAM
#pragma vertex vert
#pragma multi_compile_fwdadd_fullshadows //使用此编译指令就能确保在 AddPass 中生成阴影
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "AutoLight.cginc"
fixed4 _DiffuseColor;
fixed4 _SpecularColor;
sampler2D _MainTex;
sampler2D _NormalMap;
float _Gloss;
float _NormalScale;
sampler2D _SpecularMask;
float _SpecularMaskScale;
float4 _MainTex_ST;
struct _2vert
{
float4 vertex: POSITION; //这个名字vertex不可修改，不然Unity内置宏就无法识别到
float3 normal: NORMAL;
float4 tangent: TANGENT;
float4 texcoord: TEXCOORD0;
};
struct vert2frag
{
float4 pos: SV_POSITION; //这个名字pos不可修改
float2 uv: TEXCOORD0;
float4 TtoW1 : TEXCOORD1; //世界空间中的顶点坐标wPos放在了这3个float4的第四维里
float4 TtoW2 : TEXCOORD2;
float4 TtoW3 : TEXCOORD3;
SHADOW_COORDS(4)
};
vert2frag vert(_2vert v) //这个输入参数v不可修改
{
vert2frag o;
o.pos = UnityObjectToClipPos(v.vertex);
o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
TANGENT_SPACE_ROTATION;
float3 wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
fixed3 wNormal = UnityObjectToWorldNormal(v.normal);
fixed3 wTangent = UnityObjectToWorldDir(v.tangent.xyz);
fixed3 wBinormal = cross(wNormal, wTangent) * v.tangent.w;
o.TtoW1 = float4(wTangent.x, wBinormal.x, wNormal.x, wPos.x);
o.TtoW2 = float4(wTangent.y, wBinormal.y, wNormal.y, wPos.y);
o.TtoW3 = float4(wTangent.z, wBinormal.z, wNormal.z, wPos.z);
TRANSFER_SHADOW(o);
return o;
}
fixed4 frag(vert2frag i): SV_Target
{
float3 wPos = float3(i.TtoW1.w, i.TtoW2.w, i.TtoW3.w);
fixed3 normal = UnpackNormal(tex2D(_NormalMap, i.uv)); //内置函数UnpackNormal自动帮我们将法线向量由[0,1]映射到[-1,1]
normal.xy *= _NormalScale;
normal.z = sqrt(1.0 - saturate(dot(normal.xy, normal.xy))); //反正是标准化过的单位向量，可以自己由xy算出z的值
normal = normalize(half3(dot(i.TtoW1.xyz, normal), dot(i.TtoW2.xyz, normal), dot(i.TtoW3.xyz, normal)));
fixed3 wLightDir = normalize(UnityWorldSpaceLightDir(wPos));
fixed3 wViewDir = normalize(UnityWorldSpaceViewDir(wPos));
fixed3 albedo = tex2D(_MainTex, i.uv) * _DiffuseColor.rgb;
fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(normal, wLightDir));
fixed3 reflectDir = normalize(reflect(-wLightDir, normal));
fixed specularMask = tex2D(_SpecularMask, i.uv).g * _SpecularMaskScale;
fixed3 specular = specularMask * _LightColor0.rgb * _SpecularColor.rgb * pow(saturate(dot(reflectDir, wViewDir)), _Gloss);
UNITY_LIGHT_ATTENUATION(atten, i, wPos);
return fixed4((diffuse + specular) * atten, 1.0);
}
ENDCG
}
}
FallBack "Specular"
}上面的代码同时也考虑了法线贴图
打开 FrameDebug 也可以看到阴影的渲染过程，总计的渲染步骤多出了不少，但是可以大致分为4个步骤：
- UpdateDepthTexture：更新摄像机的深度纹理
- RenderShadowMap：渲染得到平行光的阴影映射纹理
- CollectShadows：即根据深度纹理和阴影映射纹理得到屏幕空间的阴影图
- DrawCall：绘制渲染结果
五、关于半透明物体的阴影
对于透明度混合：如果想要半透明物体也得到正确的阴影，其实是一件非常困难的事，不但对于每个光源都要给出合理的渲染顺序，而且就算按照一般的方法渲染得到了正确的阴影，也不会是完全正确的，因为半透明物体的阴影并不只是简单的“衰减”，还需要额外考虑其材质的散射光学特性
想要实现一个非常不错的半透明阴影效果，可能需要去参考专攻的论文，并且就算能实现，其性能消耗也难以接受，所以一般对于半透明物体，直接不去计算阴影