Unity Shader 立方体纹理的反射效果

Unity Shader系列文章：Unity Shader目录-初级篇

Unity Shader系列文章：Unity Shader目录-中级篇

效果：

原理：

通过入射光线方向和表面法线向量来计算反射方向，再使用反射方向对立方体纹理采样(如何制作立方体纹理)。

shader代码：

// 反射
Shader "Custom/Reflection"
{
    Properties
    {
        _Color ("Color Tint", Color) = (1, 1, 1, 1)
        _ReflectColor ("Reflect Color", Color) = (1, 1, 1, 1) // 反射颜色
        _ReflectAmount ("Reflect Amount", Range(0, 1)) = 1 // 反射系数，为1时，全反射
        _Cubemap ("Reflection Cubemap", Cube) = "_Skybox" { }// 立方体纹理
    }

    SubShader
    {
        Tags { "RenderType" = "Opaque" "Queue" = "Geometry" }

        pass
        {
            Tags { "LightMode" = "ForwardBase" }
            
            CGPROGRAM

            // 编译指令，保证在pass中得到正确的光照变量
            #pragma multi_compile_fwdbase

            #pragma vertex vert
            #pragma fragment frag

            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            fixed4 _Color;
            fixed4 _ReflectColor;
            fixed _ReflectAmount;
            samplerCUBE _Cubemap;

            // 应用传递给顶点着色器的数据
            struct a2v
            {
                float4 vertex: POSITION; // 语义：顶点坐标
                float3 normal: NORMAL; // 语义：法线
            };

            // 顶点着色器传递给片元着色器的数据
            struct v2f
            {
                float4 pos: SV_POSITION; // 语义：裁剪空间顶点坐标
                float3 worldPos: TEXCOORD0;
                float3 worldNormal: TEXCOORD1;
                fixed3 worldViewDir: TEXCOORD2;
                fixed3 worldRefl: TEXCOORD3;
                SHADOW_COORDS(4) // 声明一个用于对阴影纹理采样的坐标 (这个宏参数需要是下一个可用的插值寄存器的索引值，这里是4)
            };

            // 顶点着色器函数
            v2f vert(a2v v)
            {
                v2f o;

                // 将顶点坐标从模型空间变换到裁剪空间
                // 等价于o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
                o.pos = UnityObjectToClipPos(v.vertex);

                // 将顶点坐标从模型空间变换到世界空间
                o.worldPos = mul(unity_ObjectToWorld, v.vertex);

                // 将法线从模型空间变换到世界空间
                // 等价于o.worldNormal = mul(v.normal, (float3x3)unity_ObjectToWorld);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);

                // 观察向量
                o.worldViewDir = UnityWorldSpaceViewDir(o.worldPos);

                // 反射向量
                o.worldRefl = reflect(-o.worldViewDir, o.worldNormal);

                // 计算声明的阴影纹理坐标
                TRANSFER_SHADOW(o);
                
                return o;
            }

            fixed4 frag(v2f i): SV_TARGET
            {
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldViewDir = normalize(i.worldViewDir);
                // 单位光向量
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));

                // 环境光
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;

                // 漫反射
                fixed3 diffuse = _LightColor0.rbg * _Color.rgb * saturate(dot(worldNormal, worldLightDir));

                // 反射，对立方体纹理进行采样，此处并没有对worldRefl进行归一化，因为texCUBE参数仅仅只需要反射的方向
                fixed3 reflection = texCUBE(_Cubemap, i.worldRefl).rgb * _ReflectColor.rgb;

                // 计算光照衰减和阴影
                UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);

                fixed3 color = ambient + lerp(diffuse, reflection, _ReflectAmount) * atten;

                return fixed4(color, 1);
            }
            
            ENDCG

        }
    }
}