1. 操作系统内核实验之运行环境

前言

操作系统的实现非常复杂，我们通过自己动手完成一个操作系统内核，以此加深对软件运行原理的理解。

平台&工具

操作系统：Windows 10
虚拟机：Virtual Box
编译工具：nasm
软盘映像工具：WinImage

引导扇区

计算机上电之后，会进行一系列的硬件初始化和检测，待自检完成，BIOS开始查找可引导设备，一旦查找到正确的引导设备，BIOS即将该设备的引导扇区加载至内存地址为7c00h的位置，然后跳转至该地址处，并开始执行引导程序。

扇区
软盘的每个面由若干条磁道组成，磁道是面上的同心圆环；每条磁道又被划分为若干个区域，这些区域即称为扇区，通常一个扇区的大小是512字节(bytes)。

引导扇区
引导扇区就是由BIOS加载，用于引导(加载、执行跳转)操作系统内核的扇区。如果对所有扇区按顺序从0开始进行编号的话，那么引导扇区是第0个扇区。

以下为一段显示字符串的代码：

;文件名 hos.asm
org 7C00h

jmp START

message     db  "Hello, my os world!", 0

; 输出字符
; al    字符
printChar:
    mov ah, 0eh                 ; 设置功能号
    mov cx, 1
    int 10h                     ; 第10h号中断调用
    ret

START:      
    lea si, [message]           ; 将字符串首地址赋给寄存器si
    jmp LBE_ISNULL
LBE_PRINTC:
    call printChar              ; 调用PrintChar函数输出字符
    inc si
LBE_ISNULL:
    mov al, [si]                ; 将si所指内存的值赋给al
    test al, al                 ; 检查al是否为0
    jnz LBE_PRINTC
    hlt

    times 510 - ($ - $$) db 0   ; 将当前位置至510之间的字节都初始化为0
    dw 0xaa55                   ; 将第一扇区的最后两个字节初始化为0xaa55

org 7c00h
org指令指定了程序的偏移地址。因为BIOS会将引导扇区加载至内存地址为7c00h的位置，如果不通过该指令设置程序的起始地址，那么在运行时以“段地址:偏移”的方式来寻址就会得到：
```
ds * 10h + 文件偏移 = 0 * 10h + 文件偏移
```
显然，这是错误的。而在使用org指令指定偏移地址后，得到正确的地址应该是：
```
ds * 10h + (文件偏移 + 7c00h)
```
int 10h
int即interrupt(中断)的简写，int 10h就是第10h号中断调用。虽然语法不同，但它的作用就和其它高级语言的函数(Function)或者方法(Method)一样，由BIOS进行设置，系统开发者调用以实现各种功能。而第10h号中断则提供了非常有用的视频输出服务，包括视频模式设置、图形输出、文本输出等。参考 INT 10H(维基百科)
times
times前缀不属于x86指令集，类似的还有db、dw、resb、resw等。对于这类指令，NASM中有一个专业的术语 —— 伪指令(Pseudo Instructions)。times的作用是重复执行某个操作，例如：
```
times 512 db 0  ; 将 db 0 重复执行512次，也就是将512个字节初始化为0
```
$和$$
$符号指示当前行首在代码中的位置，$$指示当前节区(SECTION)头在代码中的位置，$ - $$ 则表示当前行至节区头的偏移。
0xaa55
引导扇区标识，BIOS根据此标识来确定该扇区是否为引导扇区。

节区(SECTION)也称为段(SEGMENT)

运行环境

1. 使用NASM编译

nasm hos.asm -o hos.bin
-o 参数指定输出的文件名

数据和指令
在计算机中存储的一切都是数据，.mp3文件内容是数据、.txt文件是数据、.exe文件也是数据，在磁盘中是数据、在内存中也是数据。只有当数据用于执行时，才将其称之为指令。

2. 创建软盘映像

使用WinImage创建软盘映像，选择1.44MB格式.

1_1 新建软盘镜像.png

将其另存为IMA格式，命名为hos;
将编译好的"hos.bin"文件写入"hos.IMA"映像的第0扇区，即文件偏移0x0000 -0x01FF处；

3. 创建一个专属虚拟机系统;

1_4 新建虚拟机.png

因为我们的“操作系统”目前还没有人知道，当然，“VirtualBox”的工程师们也不会知道，所以系统类型还是选择“Other(其它)”吧！至此，虚拟机也已经创建完成。大家是不是都有点迫不及待的想看看运行结果了呢？不过先等一下，我们还要把“操作系统”添加到虚拟机上才算是大功告成。

4. 添加软盘映像；

1_5 添加软盘映像.png

5. 运行;

1_6 运行.png

附注

在VirtualBox和VMware中，引导扇区以0xaa55和0x55aa结束似乎都是可以的。
NASM编译输出的文件可以是任意类型，例如"MYOS.bin"、"HOS.os"、"OS.abc"等，因为不管是什么类型的文件，它的(指令)数据(在二进制编辑器中查看)都是一样的。我们并不需要根据类型来解析此文件，而仅是将其原样复制到映像文件的第一个扇区。
软盘映像也可以另存为img格式，直接输入”hos.img”，然后保存即可。
写一个复制引导扇区的程序！