代码批量整理助手V1.1 (批处理配置AStyle)_20130725更新

依赖程序来源:  http://sourceforge.net/projects/astyle/files/astyle/

也就是短小精悍的AStyle

 AStyle.exe可直接由 Source Insight等编辑器调用,这里就不详细讨论了

 

 

=======================================

  
  

 

 

 
 
 
 

::   转换结果中提示Cannot convert to multi-byte string...可无视
::   依赖程序是短小精悍的 Astyle , 当前版本 Artistic Style 2.03
::   载地址 http://sourceforge.net/projects/astyle/files/astyle/
::参数用法
::想缩进4个空格的话,将 -s2 改成 -s4
::修改参数可直接不生成备份文件(也就不用删了)
::--------------------------------------------------------------------
@echo off
title 代码批量整理助手V1  by嘎子 
echo         文件支持类型c,h,cpp ,   支持4种工作方式
echo 1双击执行转换当前目录及子目录中文件
echo 2拖拽任意路径的单个文件
echo 3拖拽任意路径的目录
echo 4右键文件或目录发送到sendto
echo.

echo.
cd /d "%~dp1"
set filename=%~nx1
set pats=%~dp1
::首次使用,请修改下面的AsPath的路径!!!!!!!!!!!!!!!!!!!!!!!!!
set AsPath="D:\IDE\AStyle\AStyle.exe"
if /i "%~1"=="" goto :doubleClick 
IF EXIST "%~1\" GOTO :dir
if "%filename:~-4%"==".cpp" goto :single
if "%filename:~-2%"==".c"   goto :single
if "%filename:~-2%"==".h"   goto :single
cls
color 0a
ECHO %filename%
ECHO 是无效的后缀,当前支持的后缀类型是c,cpp,h ,要支持其他类型请修改参数
pause
exit
:single
echo --------------------singleFile mode----------------------
ECHO 转换的单个文件:%filename%
%AsPath% --style=ansi -f -X -U -Q -s2 -S -N -L -m0 -M40 --convert-tabs --suffix=.pre "%filename%"
::上句中的参数按需修改

REM 删除所有的备份文件
REM del *.pre /s /q
pause
exit
:dir
echo ---------------------dir mode-----------------------------
for /r "%~nx1" %%f in (*.cpp;*.c;*.h) do %AsPath% --style=ansi -f -X -U -Q -s2 -S -N -L -m0 -M40 --convert-tabs --suffix=.pre "%%f"
REM 删除所有的备份文件
REM for /r "%~nx1" %%a in (*.pre) do del "%%a"
pause
exit
:doubleClick
echo -------------------doubleClick mode--------------------------
for /r . %%f in (*.cpp;*.c;*.h) do %AsPath% --style=ansi -f -X -U -Q -s2 -S -N -L -m0 -M40 --convert-tabs --suffix=.pre "%%f"
REM 删除所有的备份文件
REM del *.pre /s /q
pause
exit

 

@echo off
if not exist "%~dp0AStyle.exe" echo 请把我与AStyle.exe放在同一目录下!&echo 请按任意键退出&pause>nul &exit
:start
cls
color 0E 
title=代码整理工具,右键菜单安装卸载程序 By:嘎子
echo　　　　　　　  ╭═══════════════════╮
echo　　　　　　　  ║　　　　　　　　　　　　　　　　　　  ║
echo　　　　╭═══┤代码整理      安装说明       xp下测试 ├═══╮
echo　　　　║　　  ║　　　　　　　　　　　　　　　　　　  ║　    ║
echo　　　　║　　  ╰═══════════════════╯　    ║
echo　　　　║　修改文件及目录右键菜单,也可右键发送到SendTo         ║
echo　　　　╟═══════════════════════════╢
echo　　　　║  输入1.安装　                                        ║
echo　　　　║  输入2.卸载　                                        ║
echo　　　　╟═══════════════════════════╢
echo　　　　╰───────────────────────────╯
set xz=
set /p xz=请选择或(1或2)：
if /i "%xz%"=="1" goto :ins
if /i "%xz%"=="2" goto :un
echo 输入不正确 请重新开始 & ping -n 3 127.1>nul & goto start
:ins
cd /d %~dp0
copy /y 代码整理.bat "C:\Documents and Settings\Administrator\SendTo\代码整理.bat"
set filePat=%~dp0
reg add "HKEY_CLASSES_ROOT\Directory\shell\AStyle" /v "" /d "&AS代码整理" /f 
reg add "HKEY_CLASSES_ROOT\Directory\shell\AStyle\command" /v "" /d "%filePat%代码整理.bat \"%%l%\"" /f
reg add "HKEY_CLASSES_ROOT\*\shell\AStyle" /v "" /d "&AS代码整理" /f 
reg add "HKEY_CLASSES_ROOT\*\shell\AStyle\command" /v "" /d "%filePat%代码整理.bat \"%%l%\"" /f
goto end
:un
del /q "C:\Documents and Settings\Administrator\SendTo\代码整理.bat"
reg delete "HKEY_CLASSES_ROOT\Directory\shell\AStyle" /f
reg delete "HKEY_CLASSES_ROOT\*\shell\AStyle" /f
goto end
:end
echo.
echo.                      看日出
echo.
echo                     ╭⌒╮¤　　　　　　 ╭══╮   牵着手
echo                     ╭╭ ⌒╮ ●╭○╮ ╭╯Diy ║
echo                     ╰ ----╯/█∨█\  ╰⊙═⊙╯       去海边
echo                     ~~~~~~~~~~∏~~∏~~~~~~~~~~~.
ping -n 10 127.1>nul
exit

 

 ==========================

20130725更新内容

代码整理助手V1.1.rar 

1.在if else 条件块后面的代码自动加上花括号 , 

   例如: 

if(a<0)a++;

else a--;

  整理后:

if(a<0)

{

   a++;

}

else

{

   a--;

}

 

2.for语句块前后不再自动加空一行